/[MITgcm]/MITgcm/tools/genmake
ViewVC logotype

Contents of /MITgcm/tools/genmake

Parent Directory Parent Directory | Revision Log Revision Log | View Revision Graph Revision Graph


Revision 1.56.6.3 - (show annotations) (download)
Sun Jul 10 19:43:13 2005 UTC (16 years, 6 months ago) by dimitri
Branch: release1_coupled
Changes since 1.56.6.2: +12 -1 lines
preparing verification/coupled_ucla for columbia

1 #!/bin/csh -f
2 #
3 # $Header: /u/gcmpack/MITgcm/tools/Attic/genmake,v 1.56.6.2 2005/07/10 01:37:45 dimitri Exp $
4 # $Name: release1_coupled $
5 #
6 # Makefile generator for MITgcm UV codes
7 # created by cnh 03/98
8 # adapted by aja 06/98
9 # modified by aja 01/00
10
11 # Default lists
12 set DISABLE = ( aim autodiff cal cost ctrl ecco exf grdchk )
13 set DEFINES = ( )
14 set ENABLE = ( )
15 set MODS = ( )
16
17 # Grab variables/lists from .genmakerc
18 if (-r .genmakerc) source .genmakerc
19
20 # Process command-line arguments
21 set allargs=( $argv )
22 while ($#allargs)
23 set arg = $allargs[1]
24 switch ($arg)
25 case -makefile:
26 set mfile = ( Makefile )
27 breaksw
28 case -makefile=*:
29 set mfile = ( `echo $arg | sed 's/-makefile=//' `)
30 breaksw
31 case -platform:
32 case -platform=:
33 echo "To change platform you must specify one with -platform="
34 echo "eg. -platform=sparc or -platform=mips"
35 exit
36 breaksw
37 case -platform*:
38 if ($?platform) then
39 echo Option -platform=dir can only be specified once.; exit 1
40 endif
41 set platform = ( `echo $arg | sed 's/-platform=//' `)
42 breaksw
43 case -rootdir:
44 case -rootdir=:
45 echo "To specify root directory you must specify one with -rootdir=dir"
46 echo "with NO space eg. -rootdir=../../.. or -rootdir=/usr/people/joe/src"
47 exit
48 breaksw
49 case -rootdir=*:
50 if ($?ROOTDIR) then
51 echo "***" Warning: variable \$ROOTDIR is already set to $ROOTDIR
52 echo "***" Command line \"$arg\" will override this.
53 endif
54 set ROOTDIR = ( `echo $arg | sed 's/-rootdir=//' `)
55 breaksw
56 case -mods:
57 case -mods=:
58 echo "To specify an additional source directory you must specify one with -mods=dir"
59 echo "with NO space eg. -mods=../code or -mods=/usr/people/joe/src"
60 exit
61 breaksw
62 case -mods=*:
63 set MODS = ( $MODS `echo $arg | sed 's/-mods=//' | sed 's/,/ /g' `)
64 breaksw
65 case -disable:
66 case -disable=:
67 echo "To disable packages from compilation use -disable=pkg1,pkg2"
68 echo "with NO spaces eg. -disable=kpp,gmredi or -disable=all (to enable all packages)"
69 exit
70 breaksw
71 case -disable=*:
72 set DISABLE = ( $DISABLE `echo $arg | sed 's/-disable=//' | sed 's/,/ /g' `)
73 breaksw
74 case -enable:
75 case -enable=:
76 echo "To enable packages from compilation use -enable=pkg1,pkg2"
77 echo "with NO spaces eg. -enable=aim or -enable=all (to enable all packages)"
78 echo "-enable overrides -disable, ie. a package listed in both is enabled"
79 exit
80 breaksw
81 case -ieee:
82 set IEEE
83 breaksw
84 case -enable=*:
85 set ENABLE = ( $ENABLE `echo $arg | sed 's/-enable=//' | sed 's/,/ /g' `)
86 breaksw
87 case -mpi:
88 echo "Enabling MPI options"
89 set USEMPI
90 breaksw
91 case -jam:
92 set include_jam_libs
93 echo "Including paths to JAM libraries"
94 breaksw
95 case -help:
96 echo "usage: $0 [-help] [-makefile[=...]] [-platform=...] [-mpi] [-jam] [-disable=pkg1[,pkg2,...]] [-enable=pkg1[,pkg2,...]] [-mods=dir1[,dir2,...]] [-rootdir=dir]"
97 cat << EOF
98
99 $0 is used to generate the Makefile in the current directory.
100
101 Typical invocations are:
102 o from "bin": ../tools/genmake
103 o from "verification/expt/code": ../../../tools/genmake
104 o from "verification/expt/input": ../../../tools/genmake -mods=../code
105 o from a scratch directory: ~/mitgcm/tools/genmake -rootdir=~/mitgcm
106 or ~/mitgcm/tools/genmake -rootdir=~/mitgcm -mods=~/mymods
107
108 Packages (collected modules of code) can be disabled to avoid unnecessary
109 compilation of unused code. For instance if you know you will not
110 use GM/Redi, KPP and OBCS and they are appropriate turned-off in the
111 configuration:
112 .../tools/genmake -disable=gmredi,kpp,obcs
113
114 If you add some source files you can re-call the previous instance of
115 genmake with "make makefile".
116
117 genmake also reads the file .genmakerc which can be used to configure
118 options (primarily the command-line options above) for particular experiments.
119 EOF
120 exit
121 breaksw
122 default:
123 echo "Unknown command-line option: " $arg
124 echo $0 "-help to show usage"
125 exit
126 breaksw
127 endsw
128 shift allargs
129 end
130
131 # Default actions/options
132
133 # If platform wasn't specified then determine platform type of the host
134 if (! $?platform) then
135 set platform = (`uname`)
136 # This let's us distinguish between different Linux platforms
137 if ($platform == Linux) then
138 set machine = (`uname -m`)
139 set platform = ($platform'-'$machine)
140 endif
141 endif
142 # If name of makefile wasn't specified then use default "Makefile"
143 if (! $?mfile) set mfile = ( Makefile )
144
145 set mach = ( `uname -a` )
146 echo Operating system: $mach
147
148 # Directories for source, includes, binaries and executables
149 #
150 # If -rootdir wasn't specified then assume script is being run from bin
151 # but if it was supplied then we should place the executable in the build dir
152 if (! $?ROOTDIR) then
153 set pwd=`pwd`
154 if ($pwd:t == bin & -d ../model & -d ../eesupp & -d ../pkg) then
155 set ROOTDIR = ( .. )
156 endif
157 endif
158 # Scan for logical ROOTDIR
159 if (! $?ROOTDIR) then
160 foreach dr (. .. ../.. ../../.. ../../../.. ../../../../..)
161 if (-d $dr/model & -d $dr/eesupp & -d $dr/pkg) then
162 set ROOTDIR = $dr
163 echo ROOTDIR was not specified. Setting ROOTDIR = \"$ROOTDIR\"
164 break
165 endif
166 end
167 endif
168 if (! $?ROOTDIR) then
169 echo Root directory was not specified and could not be determined.
170 echo Specify the root location of the model source with -rootdir=dir
171 exit 1
172 endif
173 if (! -d $ROOTDIR) then
174 echo Root directory $ROOTDIR not found.;exit 1
175 endif
176 # If -mods wasn't specified then we will assume that we can find all the
177 # source code in the standard directories
178 if (! $?MODS) then
179 set SOURCEDIRS = ( )
180 set INCLUDEDIRS = ( )
181 else
182 set SOURCEDIRS = ( $MODS )
183 set INCLUDEDIRS = ( $MODS )
184 endif
185 if (! $?BUILDDIR) set BUILDDIR = ( . )
186 if (! -d $BUILDDIR) then
187 echo Build directory $BUILDDIR not found.;exit 1
188 endif
189 if (! $?EXEDIR) then
190 set pwd=`pwd`
191 if ($pwd:t == bin & -d ../exe & $ROOTDIR == ..) then
192 set EXEDIR = ( ../exe )
193 else
194 set EXEDIR = ( . )
195 endif
196 endif
197 if (! -d $EXEDIR) then
198 echo Executable directory $EXEDIR not found.;exit 1
199 endif
200 if (! $?TOOLSDIR) set TOOLSDIR = ( $ROOTDIR/tools )
201 if (! -d $TOOLSDIR) then
202 echo Tools directory $TOOLSDIR not found.;exit 1
203 endif
204 if (! $?EXECUTABLE) set EXECUTABLE = ( mitgcmuv )
205
206 # We have a special set of source files in eesupp/src which
207 # are generated from some template source files. We'll make them
208 # first so the appear as regular source code
209 if (-r $ROOTDIR/eesupp/src/Makefile) then
210 echo Making source files in eesupp from templates...
211 (cd $ROOTDIR/eesupp/src/; make) >& make_eesupp.errs
212 if ($status == 0) then
213 rm -f make_eesupp.errs
214 else
215 cat make_eesupp.errs
216 exit 2
217 endif
218 endif
219
220 # Now scan the standard source code tree
221 foreach dr ($SOURCEDIRS)
222 set adr=$dr
223 if (! -d $adr) then
224 echo mods directory $adr not found.; exit 1
225 endif
226 echo Adding mods dir: $adr
227 end
228 if (! $?PACKAGES) then
229 set PACKAGES=()
230 foreach pkg (`cd $ROOTDIR/pkg; find . -type d | grep -v CVS | sed 's:\./::' | grep -v "\." | sort`)
231 if (-d $ROOTDIR/pkg/$pkg) set PACKAGES=($PACKAGES $pkg)
232 end
233 endif
234 foreach dr ($PACKAGES)
235 set enable
236 foreach p ($DISABLE)
237 if ($p != 'all' & ! -d $ROOTDIR/pkg/$p) then
238 echo Specified package \"$p\" does not exist.
239 exit 1
240 endif
241 if ($dr == $p) unset enable
242 if ($p == 'all') unset enable
243 # The following allows entire trees to be disabled
244 if ($dr:h == $p) unset enable
245 if ($dr:h:h == $p) unset enable
246 if ($dr:h:h:h == $p) unset enable
247 if ($dr:h:h:h:h == $p) unset enable
248 end
249 foreach p ($ENABLE)
250 if ($dr == $p) set enable
251 end
252 if ($?enable) then
253 set adr=$ROOTDIR/pkg/$dr
254 if (! -d $adr) then
255 echo Source directory $adr not found.; exit 1
256 endif
257 echo Adding pkg dir: $adr
258 set SOURCEDIRS = ($SOURCEDIRS $adr)
259 set INCLUDEDIRS = ($INCLUDEDIRS $adr)
260 else
261 echo " *" Package \"$dr\" NOT enabled.
262 switch ($dr)
263 case mom_fluxform:
264 set DEFINES = ($DEFINES '-DDISABLE_MOM_FLUXFORM'); breaksw
265 case mom_vecinv:
266 set DEFINES = ($DEFINES '-DDISABLE_MOM_VECINV'); breaksw
267 case generic_advdiff:
268 set DEFINES = ($DEFINES '-DDISABLE_GENERIC_ADVDIFF'); breaksw
269 default:
270 breaksw
271 endsw
272 endif
273 end
274 if (! $?STANDARDDIRS) set STANDARDDIRS=(eesupp model)
275 foreach dr ($STANDARDDIRS)
276 set adr=$ROOTDIR/$dr/src
277 if (! -d $adr) then
278 echo Source directory $adr not found.; exit 1
279 endif
280 echo Adding src dir: $adr
281 set SOURCEDIRS = ($SOURCEDIRS $adr)
282 set idr = `echo $adr | sed 's/src/inc/'`
283 set INCLUDEDIRS = ($INCLUDEDIRS $idr)
284 end
285
286 # This is the generic configuration.
287 # Platform specific options are chosen below
288 set LN = ( 'ln -s' )
289 set CPP = ( '/lib/cpp -P' )
290 set S64 = ( '$(TOOLSDIR)/set64bitConst.sh' )
291 set KPP = ( )
292 set FC = ( 'f77' )
293 set LINK = ( 'f77' )
294 set INCLUDES = ( -I. )
295 set FFLAGS = ( )
296 set FOPTIM = ( )
297 set CFLAGS = ( )
298 set KFLAGS1 = ( )
299 set KFLAGS2 = ( )
300 set LIBS = ( )
301 set KPPFILES = ( )
302 set NOOPTFILES = ( )
303 set NOOPTFLAGS = ( )
304 set RMFILES = ( )
305
306 # We often want to use different compile/link options is using MPI
307 if ($?USEMPI) then
308 set USEMPI = ( '+mpi' )
309 set DEFINES = ( ${DEFINES} '-DALLOW_USE_MPI -DALWAYS_USE_MPI' )
310 else
311 set USEMPI
312 # set DEFINES = ( ${DEFINES} '-UALLOW_USE_MPI -UALWAYS_USE_MPI' )
313 endif
314
315 # Platform specific options
316 switch ($platform$USEMPI)
317 case OSF1+mpi:
318 echo "Configuring for DEC Alpha with MPI"
319 set LIBS = ( '-lfmpi -lmpi -lkmp_osfp10 -pthread' )
320 case OSF1:
321 echo "Configuring for DEC Alpha"
322 set CPP = ( '/usr/bin/cpp -P' )
323 set DEFINES = ( ${DEFINES} '-DTARGET_DEC -DWORDLENGTH=1' )
324 set KPP = ( )
325 set KPPFILES = ( )
326 set KFLAGS1 = ( )
327 set FC = ( 'f77' )
328 set FFLAGS = ( '-convert big_endian -r8 -extend_source -automatic -call_shared -notransform_loops -align dcommons' )
329 set FOPTIM = ( '-O5 -fast -tune host -inline all' )
330 set NOOPTFLAGS = ( '-O0' )
331 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
332 set RMFILES = ( '*.p.out' )
333 breaksw
334 case IRIX64+mpi:
335 echo "Configuring for SGI Mips with MPI"
336 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
337 set INCLUDES = ( '-I/usr/local/mpi/include' )
338 set FC = ( 'mpif77' )
339 set LINK = ( 'mpif77' )
340 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
341 set FOPTIM = ( '-O3' )
342 set RMFILES = ( 'rii_files' )
343 breaksw
344 case IRIX64:
345 echo "Configuring for SGI Mips"
346 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
347 set INCLUDES = ( '-I/usr/local/mpi/include' )
348 set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4 -r8 -static' )
349 set FOPTIM = ( '-O3' )
350 # set NOOPTFLAGS = ( '-O0' )
351 # set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
352 # 'external_fields_load.F' )
353 set RMFILES = ( 'rii_files' )
354 breaksw
355 case o2:
356 case IRIX:
357 echo "Configuring for SGI O2 running IRIX 6.5"
358 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
359 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
360 set FOPTIM = ( '-O2' )
361 set NOOPTFLAGS = ( '-O0' )
362 breaksw
363 case o2+mpi:
364 case IRIX+mpi:
365 echo "Configuring for SGI O2 running IRIX 6.5 with MPI"
366 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
367 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
368 set FOPTIM = ( '-O2' )
369 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F' )
370 set NOOPTFLAGS = ( '-O0' )
371 set LIBS = ( '-lmpi' )
372 breaksw
373 case o2k+mpi:
374 echo "Configuring for SGI Origin2000 running IRIX 6.5"
375 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
376 set INCLUDES = ( '-I/usr/include' )
377 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
378 set FOPTIM = ( '-O2' )
379 set NOOPTFILES = ( 'calc_mom_rhs.F' )
380 set NOOPTFLAGS = ( '-O1' )
381 set LIBS = ( '-lmpi -lscs' )
382 breaksw
383 case ames_dbg+mpi:
384 echo "Configuring for SGI Origin2000 running IRIX 6.5"
385 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
386 set INCLUDES = ( '-I/usr/include -I/opt/mpt/mpt/usr/include' )
387 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
388 set LIBS = ( '-lmpi -lscs' )
389 set FC = ( 'f90' )
390 set LINK = ( 'f90' )
391 breaksw
392 case ames_opt+mpi:
393 echo "Configuring for SGI Origin2000 running IRIX 6.5"
394 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
395 set INCLUDES = ( '-I/usr/include -I/opt/mpt/mpt/usr/include' )
396 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
397 set FOPTIM = ( '-O3 -OPT:Olimit=0:roundoff=3:div_split=ON:alias=typed' )
398 set LIBS = ( '-lmpi -lscs' )
399 set FC = ( 'f90' )
400 set LINK = ( 'f90' )
401 breaksw
402 case columbia+mpi:
403 echo "Configuring for Columbia"
404 set CPP = ( '/lib/cpp -traditional -P' )
405 set FFLAGS = ( '-mp -132 -r8 -i4 -w95 -W0 -WB -convert big_endian -assume byterecl' )
406 set FOPTIM = ( '-O3 -align' )
407 set LIBS = ( '-L/opt/sgi/mpt/1.11-85/lib -lmpi' )
408 set FC = ( 'ifort' )
409 set LINK = ( 'ifort' )
410 set DEFINES = ( '-DWORDLENGTH=4' )
411 set INCLUDES = ( '-I/opt/sgi/mpt/1.11-85/include' )
412 breaksw
413 case onyx:
414 case onyx+mpi:
415 echo "Configuring for SGI ONYX running IRIX64"
416 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
417 set FFLAGS = ( '-extend_source -bytereclen -r10000 -64' )
418 set FOPTIM = ( '-O2' )
419 set NOOPTFLAGS = ( '-O0' )
420 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F' )
421 set LIBS = ( '-lmpi' )
422 breaksw
423 case SunOS:
424 set LN = ( '/usr/bin/ln -s' )
425 set CPP = ( '/usr/ccs/lib/cpp -P' )
426 set S64 = ( cat )
427 set DEFINES = ( ${DEFINES} '-DTARGET_SUN -DWORDLENGTH=4 -D_d=E' )
428 set FFLAGS = ( '-stackvar -explicitpar -vpara -e -u -noautopar -r8 -i4 -fsimple=0' )
429 set FOPTIM = ( '-dalign -O3 -xarch=v9' )
430 set CFLAGS = ( '-dalign -O3 -xarch=v9' )
431 set NOOPTFLAGS = ( '-dalign -O0 -xarch=v9' )
432 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F ini_vertical_grid.F ini_spherical_polar_grid.F ini_cori.F mon_printstats_rl.F mon_printstats_rs.F aim_aim2dyn.F aim_dyn2aim.F aim_aim2dyn_exchanges.F aim_external_fields_load.F aim_calc_diags.F aim_external_forcing.F aim_do_atmos_physics.F aim_write_diags.F aim_do_inphys.F ')
433 breaksw
434 case SunOS+mpi:
435 set LN = ( '/usr/bin/ln -s' )
436 set CPP = ( '/usr/ccs/lib/cpp -P' )
437 set S64 = ( cat )
438 set DEFINES = ( ${DEFINES} '-DTARGET_SUN -DWORDLENGTH=4 -D_d=E' )
439 set INCLUDES = ( '-I/usr/local/mpi/include' )
440 set LIBS = ( '-L/usr/local/mpi/lib/solaris/ch_shmem -lmpi -lthread' \
441 set FFLAGS = ( '-stackvar -explicitpar -vpara -e -u -noautopar -r8 -i4 -fsimple=0' )
442 set FOPTIM = ( '-dalign -O3 -xarch=v9' )
443 set NOOPTFLAGS = ( '-dalign -O0 -xarch=v9' )
444 '-lsocket -lnsl' )
445 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F ini_vertical_grid.F ini_spherical_polar_grid.F ini_cori.F mon_printstats_rl.F mon_printstats_rs.F')
446 breaksw
447 case IRIX32:
448 echo "Configuring for SGI ONYX running IRIX64"
449 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
450 set INCLUDES = ( '-I/usr/include' )
451 set FFLAGS = ( '-extend_source -bytereclen -r10000 -64' )
452 set FOPTIM = ( '-O2' )
453 set NOOPTFLAGS = ( '-O0' )
454 set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
455 'external_fields_load.F' )
456 set LIBS = ( '-lmpi' )
457 breaksw
458 case HP-UX+mpi:
459 set FC = ( 'mpif77' )
460 set LINK = ( 'mpif77' )
461 set INCLUDES = ( '-I/opt/mpi/include' )
462 case HP-UX:
463 echo "Configuring for HP Exemplar"
464 set CPP = ( '/usr/ccs/lbin/cpp -P' )
465 set DEFINES = ( ${DEFINES} '-DTARGET_HP -DWORDLENGTH=4' )
466 set FFLAGS = ( '+es +U77 +Onoautopar +Oexemplar_model' \
467 '+Okernel_threads' )
468 set FOPTIM = ( '+O2' )
469 set NOOPTFLAGS = ( '+O0' )
470 set NOOPTFILES = ( 'barrier.F different_multiple.F' \
471 'external_fields_load.F' )
472 breaksw
473 case Linux-alpha+mpi:
474 echo "Configuring with MPI"
475 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
476 set INCLUDES = ( '-I/usr/local/include' )
477 case Linux-alpha:
478 echo "Configuring for " $platform
479 set LN = ( '/bin/ln -s' )
480 set CPP = ( '/lib/cpp -traditional -P' )
481 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
482 set FC = ( 'g77' )
483 set FFLAGS = ( ' ' )
484 if ($?IEEE) set FFLAGS = ( $FFLAGS '-ffloat-store' )
485 set FOPTIM = ( '-ffast-math -fexpensive-optimizations -fomit-frame-pointer -O3' )
486 set LINK = ( 'g77' )
487 breaksw
488 case Linux*+pgi+mpi:
489 if ($?include_jam_libs) then
490 set INCLUDES = ( '-I/usr/local/mpich-1.2.1/pgi_fortran_binding/include' )
491 set LIBS = ( '-L/usr/local/mpich-1.2.1/pgi_fortran_binding/lib/ -lfmpich -lmpich' )
492 else
493 set INCLUDES = ( '-I/usr/local/include' )
494 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
495 endif
496 case Linux*+pgi:
497 echo "Configuring for " $platform
498 set LN = ( '/bin/ln -s' )
499 set CPP = ( '/lib/cpp -traditional -P' )
500 set DEFINES = ( ${DEFINES} '-DWORDLENGTH=4' )
501 set FC = ( 'pgf77' )
502 set FFLAGS = ( '-byteswapio -r8 -Mnodclchk -Mextend' )
503 set FOPTIM = ( '-tp p6 -v -O2 -Munroll -Mvect=cachesize:512000,transform -Kieee' )
504 set LINK = ( 'pgf77' )
505 breaksw
506 case Linux*+mpi:
507 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
508 set INCLUDES = ( '-I/usr/local/include' )
509 case Linux*:
510 echo "Configuring for " $platform
511 set LN = ( '/bin/ln -s' )
512 set CPP = ( '/lib/cpp -traditional -P' )
513 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
514 set FC = ( 'g77' )
515 set FFLAGS = ( '-Wimplicit -Wunused -Wuninitialized' )
516 if ($?IEEE) set FFLAGS = ( $FFLAGS '-ffloat-store' )
517 set FOPTIM = ( '-O3 -malign-double -funroll-loops' )
518 set LINK = ( 'g77' )
519 breaksw
520 case T3E:
521 case sn6312:
522 echo "Configuring for T3E"
523 set CPP = ( '/opt/ctl/bin/cpp -P')
524 set DEFINES = ( ${DEFINES} '-DTARGET_T3E -DWORDLENGTH=4' )
525 set FC = ( 'f90' )
526 set LINK = ( 'f90' )
527 set FFLAGS = ( '-O 2,fusion' )
528 breaksw
529 case T90:
530 case sn7113:
531 echo "Configuring for T90"
532 set FC = ( 'f90' )
533 set LINK = ( 'f90' )
534 set LN = ( '/bin/ln -s' )
535 set CPP = ( '/opt/ctl/bin/cpp -N -P' )
536 set DEFINES = ( ${DEFINES} '-DTARGET_CRAY_VECTOR -DWORDLENGTH=4' )
537 set FFLAGS = ( '-m3 -Rabc -N 132')
538 set FOPTIM = ( '-O0' )
539 set NOOPTFLAGS = ( '-O0' )
540 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
541 breaksw
542 case SV1:
543 case sn3002:
544 set FC = ( 'f90' )
545 set LINK = ( 'f90' )
546 set LN = ( '/bin/ln -s' )
547 set CPP = ( '/opt/ctl/bin/cpp -N -P' )
548 set DEFINES = ( ${DEFINES} '-DTARGET_CRAY_VECTOR -DWORDLENGTH=4' )
549 set FFLAGS = ( '-m3 -Rabc -ei -eI -s cf77types -N 132')
550 set FOPTIM = ( '-O0' )
551 set NOOPTFLAGS = ( '-O0' )
552 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
553 breaksw
554 default:
555 echo "Error: platform not recognized: uname -p = " $platform$USEMPI
556 exit
557 breaksw
558 endsw
559
560 ###############################################################################
561 ## ##
562 ## Everything below here should not need to be changed. Platform specific ##
563 ## changes and code specific changes should be configured above this line. ##
564 ## ##
565 ###############################################################################
566
567 # Convert lists of directories into command-line options
568 foreach inc ($INCLUDEDIRS)
569 set INCLUDES = ($INCLUDES -I$inc)
570 end
571
572 # Search for source code
573 rm -rf .links.tmp;mkdir .links.tmp
574 echo "# This section creates symbolic links" > srclinks.tmp
575 echo "" >> srclinks.tmp
576 echo -n 'SRCFILES = ' > srclist.inc
577 echo -n 'CSRCFILES = ' > csrclist.inc
578 echo -n 'HEADERFILES = ' > hlist.inc
579 foreach dr ($SOURCEDIRS $INCLUDEDIRS .)
580 set deplist=( )
581 foreach srcfile (`cd $dr; ls *.[hcF]`)
582 if (! -r .links.tmp/$srcfile) then
583 if (-f $dr/$srcfile) then
584 switch ($srcfile:e)
585 case F:
586 touch .links.tmp/$srcfile
587 set deplist=($deplist $srcfile)
588 echo ' \' >> srclist.inc
589 echo -n " " $srcfile >> srclist.inc
590 breaksw
591 case c:
592 touch .links.tmp/$srcfile
593 set deplist=($deplist $srcfile)
594 echo ' \' >> csrclist.inc
595 echo -n " " $srcfile >> csrclist.inc
596 breaksw
597 case h:
598 touch .links.tmp/$srcfile
599 set deplist=($deplist $srcfile)
600 echo ' \' >> hlist.inc
601 echo -n " " $srcfile >> hlist.inc
602 breaksw
603 endsw
604 endif
605 endif
606 end
607 if ($#deplist != 0) then
608 echo "# These files are linked from $dr" >> srclinks.tmp
609 echo $deplist':' >> srclinks.tmp
610 echo ' $(LN) '$dr'/$@ $@' >> srclinks.tmp
611 endif
612 end
613 rm -rf .links.tmp
614 echo "" >> srclist.inc
615 echo "" >> csrclist.inc
616 echo "" >> hlist.inc
617
618 set THISHOSTNAME = ( `hostname` )
619 set THISCWD = ( `pwd` )
620 set THISDATE = ( `date` )
621
622 if (-r $mfile) mv -f $mfile $mfile.bak
623 ###########################################
624 ## This is the template for the makefile ##
625 ###########################################
626 echo Creating makefile: $mfile
627 echo "# Multithreaded + multi-processing makefile for $mach" > ${mfile}
628 echo "# This makefile was generated automatically on" >> ${mfile}
629 echo "# $THISDATE" >> ${mfile}
630 echo "# by the command:" >> ${mfile}
631 echo "# ${0} $argv" >> ${mfile}
632 echo "# executed by:" >> ${mfile}
633 echo "# $USER@${THISHOSTNAME}:${THISCWD}" >> ${mfile}
634 cat >> ${mfile} <<EOF
635 #
636 # BUILDDIR : Directory where object files are written
637 # SOURCEDIRS : Directories containing the source (.F) files
638 # INCLUDEDIRS : Directories containing the header-source (.h) files
639 # EXEDIR : Directory where executable that is generated is written
640 # EXECUTABLE : Full path of executable binary
641 #
642 # CPP : C-preprocessor command
643 # INCLUDES : Directories searched for header files
644 # DEFINES : Macro definitions for CPP
645 # KPP : Special preprocessor command (specific to platform)
646 # KFLAGS : Flags for KPP
647 # FC : Fortran compiler command
648 # FFLAGS : Configuration/debugging options for FC
649 # FOPTIM : Optimization options for FC
650 # LINK : Command for link editor program
651 # LIBS : Library flags /or/ additional optimization/debugging flags
652
653 ROOTDIR = ${ROOTDIR}
654 BUILDDIR = ${BUILDDIR}
655 SOURCEDIRS = ${SOURCEDIRS}
656 INCLUDEDIRS = ${INCLUDEDIRS}
657 EXEDIR = ${EXEDIR}
658 EXECUTABLE = \$(EXEDIR)/${EXECUTABLE}
659 TOOLSDIR = ${TOOLSDIR}
660
661 EOF
662
663
664 # JAM libraries on Hyades
665 if ($?include_jam_libs) then
666 cat >> ${mfile} <<EOF
667 # extra stuff for Hyades ............................................
668 HYADES_DIR = /u/u0/cnh/jam-lib/software
669 HYADES_DIR = /u/u0/cnh/jam-lib-twoproc
670 HYADES_DIR = /usr/local/jamlib/current/dual_proc
671 WORK_DIR = \$(HYADES_DIR)
672 DEPOSIT_DIR = linux_bin
673
674 STARTXOBJDIR = startx_util/\$(DEPOSIT_DIR)
675 STARTXOBJ = \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/startx_timer.o \
676 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/startx_util.o \
677 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/client.o \
678 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/csutil.o
679
680 JAMOBJDIR = jam/\$(DEPOSIT_DIR)
681 JAMOBJ = \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_init.o \
682 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_kernel.o \
683 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_malloc.o \
684 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_vmalloc.o \
685 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_mutex.o
686
687 JAMCOBJDIR = jam_collective/\$(DEPOSIT_DIR)
688 JAMCOBJ = \$(WORK_DIR)/jam_collective/\$(DEPOSIT_DIR)/jam_collective.o
689
690 XLIBS = \$(STARTXOBJ) \$(JAMOBJ) \$(JAMCOBJ)
691
692 # ..................................................................
693
694 EOF
695 endif
696
697
698 cat >> ${mfile} <<EOF
699 # Unix ln (link)
700 LN = ${LN}
701 # C preprocessor
702 CPP = cat \$< | ${S64} | ${CPP}
703 # Special preprocessor (KAP on DECs, FPP on Crays)
704 KPP = ${KPP}
705 # Fortran compiler
706 FC = ${FC}
707 # Link editor
708 LINK = ${LINK}
709
710 # Defines for CPP
711 DEFINES = ${DEFINES}
712 # Includes for CPP
713 INCLUDES = ${INCLUDES}
714 # Flags for KPP
715 KFLAGS1 = ${KFLAGS1}
716 KFLAGS2 = ${KFLAGS2}
717 # Optim./debug for FC
718 FFLAGS = ${FFLAGS}
719 FOPTIM = ${FOPTIM}
720 # Flags for CC
721 CFLAGS = ${CFLAGS}
722 # Files that should not be optimized
723 NOOPTFILES = ${NOOPTFILES}
724 NOOPTFLAGS = ${NOOPTFLAGS}
725 # Flags and libraries needed for linking
726 LIBS = ${LIBS} \$(XLIBS)
727
728 EOF
729
730 cat srclist.inc >> ${mfile}
731 cat csrclist.inc >> ${mfile}
732 cat hlist.inc >> ${mfile}
733 echo 'F77FILES = $(SRCFILES:.F=.f)' >> ${mfile}
734 echo 'OBJFILES = $(SRCFILES:.F=.o) $(CSRCFILES:.c=.o)' >> ${mfile}
735
736 rm -f srclist.inc csrclist.inc hlist.inc flist.tmp clist.tmp
737
738 cat >> ${mfile} <<EOF
739
740 .SUFFIXES:
741 .SUFFIXES: .o .f .p .F .c
742
743 all: \$(EXECUTABLE)
744 \$(EXECUTABLE): \$(OBJFILES)
745 \$(LINK) -o \$@ \$(FFLAGS) \$(FOPTIM) \$(OBJFILES) \$(LIBS)
746 depend:
747 @make links
748 makedepend -o .f \$(DEFINES) \$(INCLUDES) \$(SRCFILES)
749
750 links: \$(SRCFILES) \$(CSRCFILES) \$(HEADERFILES)
751
752 small_f: \$(F77FILES)
753
754 output.txt: \$(EXECUTABLE)
755 @printf 'running ... '
756 @\$(EXECUTABLE) > \$@
757
758 clean:
759 -rm -rf *.o *.f *.p ${RMFILES}
760 Clean:
761 @make clean
762 @make cleanlinks
763 -rm -f Makefile.bak
764 CLEAN:
765 @make Clean
766 -find \$(EXEDIR) -name "*.meta" -exec rm {} \;
767 -find \$(EXEDIR) -name "*.data" -exec rm {} \;
768 -rm -f \$(EXECUTABLE)
769
770 makefile:
771 ${0} $argv
772 cleanlinks:
773 -find . -type l -exec rm {} \;
774
775 # The normal chain of rules is ( .F - .f - .o )
776 .F.f:
777 \$(CPP) \$(DEFINES) \$(INCLUDES) > \$@
778 .f.o:
779 \$(FC) \$(FFLAGS) \$(FOPTIM) -c \$<
780 .c.o:
781 \$(CC) \$(CFLAGS) -c \$<
782
783 # Special exceptions that use the ( .F - .p - .f - .o ) rule-chain
784 .F.p:
785 \$(CPP) \$(DEFINES) \$(INCLUDES) > \$@
786 .p.f:
787 \$(KPP) \$(KFLAGS1)\$@ \$(KFLAGS2) \$<
788 EOF
789
790 # Make list of "exceptions" that need ".p" files
791 foreach sf ($KPPFILES)
792 set fname=( ${sf:t} )
793 echo "${fname:r}.f: ${fname:r}.p" >> ${mfile}
794 end
795 foreach sf ($NOOPTFILES)
796 set fname=( ${sf:t} )
797 echo "${fname:r}.o: ${fname:r}.f" >> ${mfile}
798 echo ' $(FC) $(FFLAGS) $(NOOPTFLAGS) -c $<' >> ${mfile}
799 end
800 echo "" >> ${mfile}
801
802 # Add rules for links
803 cat srclinks.tmp >> ${mfile}
804 rm -f srclinks.tmp
805
806 echo "" >> ${mfile}
807 echo "# DO NOT DELETE" >> ${mfile}
808
809 exit

  ViewVC Help
Powered by ViewVC 1.1.22