/[MITgcm]/MITgcm/tools/genmake
ViewVC logotype

Contents of /MITgcm/tools/genmake

Parent Directory Parent Directory | Revision Log Revision Log | View Revision Graph Revision Graph


Revision 1.87 - (show annotations) (download)
Mon Oct 6 20:38:40 2003 UTC (16 years, 6 months ago) by stephd
Branch: MAIN
CVS Tags: checkpoint51k_post, checkpoint51j_post, checkpoint51i_post, checkpoint51l_pre, checkpoint51h_pre, checkpoint51i_pre
Branch point for: tg2-branch
Changes since 1.86: +2 -2 lines
disable pkg/cfc

1 #!/bin/csh -f
2 #
3 # $Header: /u/gcmpack/MITgcm/tools/genmake,v 1.86 2003/10/03 14:09:51 heimbach Exp $
4 # $Name: $
5 #
6 # Makefile generator for MITgcm UV codes
7 # created by cnh 03/98
8 # adapted by aja 06/98
9 # modified by aja 01/00
10
11 # Default lists
12 if (! $?DISABLE) set DISABLE = ( aim aim_v23 autodiff cal cost ctrl ecco exf grdchk flt land ptracers seaice therm_seaice bulk_force dic gchem cfc )
13 if (! $?ENABLE) set ENABLE = ( )
14 if (! $?DEFINES) set DEFINES = ( )
15 if (! $?MODS) set MODS = ( )
16
17 # Grab variables/lists from .genmakerc
18 if (-r .genmakerc) source .genmakerc
19
20 # Process command-line arguments
21 set allargs=( $argv )
22 while ($#allargs)
23 set arg = $allargs[1]
24 switch ($arg)
25 case -makefile:
26 set mfile = ( Makefile )
27 breaksw
28 case -makefile=*:
29 set mfile = ( `echo $arg | sed 's/-makefile=//' `)
30 breaksw
31 case -platform:
32 case -platform=:
33 echo "To change platform you must specify one with -platform="
34 echo "eg. -platform=sparc or -platform=mips"
35 exit
36 breaksw
37 case -platform*:
38 if ($?platform) then
39 echo Option -platform=dir can only be specified once.; exit 1
40 endif
41 set platform = ( `echo $arg | sed 's/-platform=//' `)
42 breaksw
43 case -rootdir:
44 case -rootdir=:
45 echo "To specify root directory you must specify one with -rootdir=dir"
46 echo "with NO space eg. -rootdir=../../.. or -rootdir=/usr/people/joe/src"
47 exit
48 breaksw
49 case -rootdir=*:
50 if ($?ROOTDIR) then
51 echo "***" Warning: variable \$ROOTDIR is already set to $ROOTDIR
52 echo "***" Command line \"$arg\" will override this.
53 endif
54 set ROOTDIR = ( `echo $arg | sed 's/-rootdir=//' `)
55 breaksw
56 case -mods:
57 case -mods=:
58 echo "To specify an additional source directory you must specify one with -mods=dir"
59 echo "with NO space eg. -mods=../code or -mods=/usr/people/joe/src"
60 exit
61 breaksw
62 case -mods=*:
63 set MODS = ( $MODS `echo $arg | sed 's/-mods=//' | sed 's/,/ /g' `)
64 breaksw
65 case -disable:
66 case -disable=:
67 echo "To disable packages from compilation use -disable=pkg1,pkg2"
68 echo "with NO spaces eg. -disable=kpp,gmredi or -disable=all (to enable all packages)"
69 exit
70 breaksw
71 case -disable=*:
72 set DISABLE = ( $DISABLE `echo $arg | sed 's/-disable=//' | sed 's/,/ /g' `)
73 breaksw
74 case -enable:
75 case -enable=:
76 echo "To enable packages from compilation use -enable=pkg1,pkg2"
77 echo "with NO spaces eg. -enable=aim or -enable=all (to enable all packages)"
78 echo "-enable overrides -disable, ie. a package listed in both is enabled"
79 exit
80 breaksw
81 case -enable=*:
82 set ENABLE = ( $ENABLE `echo $arg | sed 's/-enable=//' | sed 's/,/ /g' `)
83 breaksw
84 case -cpp:
85 case -cpp=:
86 echo "To define CPP macros use -cpp=arg"
87 exit
88 breaksw
89 case -cpp=*:
90 set DEFINES = ( $DEFINES `echo $arg | sed 's/-cpp=//' | sed 's/,/ /g' `)
91 breaksw
92 case -ieee:
93 set IEEE
94 breaksw
95 case -mpi:
96 echo "Enabling MPI options"
97 set USEMPI
98 breaksw
99 case -jam:
100 set include_jam_libs
101 echo "Including paths to JAM libraries"
102 breaksw
103 case -arpack:
104 echo "Enabling ARPACK libraries"
105 set USEARPACK
106 breaksw
107 case -fc:
108 case -fc=:
109 echo "To change the compiler (\$FC) you must specify one with -fc="
110 echo "eg. -fc=f90 or -fc=g77"
111 exit
112 breaksw
113 case -fc*:
114 if ($?FC) then
115 echo Option -fc=... can only be specified once.; exit 1
116 endif
117 set FC = ( `echo $arg | sed 's/-fc=//' `)
118 breaksw
119 case -help:
120 echo "usage: $0 [-help] [-makefile[=...]] [-platform=...] [-mpi] [-jam] [-arpack] [-disable=pkg1[,pkg2,...]] [-enable=pkg1[,pkg2,...]] [-mods=dir1[,dir2,...]] [-rootdir=dir]"
121 cat << EOF
122
123 $0 is used to generate the Makefile in the current directory.
124
125 Typical invocations are:
126 o from "bin": ../tools/genmake
127 o from "verification/expt/code": ../../../tools/genmake
128 o from "verification/expt/input": ../../../tools/genmake -mods=../code
129 o from a scratch directory: ~/mitgcm/tools/genmake -rootdir=~/mitgcm
130 or ~/mitgcm/tools/genmake -rootdir=~/mitgcm -mods=~/mymods
131
132 Packages (collected modules of code) can be disabled to avoid unnecessary
133 compilation of unused code. For instance if you know you will not
134 use GM/Redi, KPP and OBCS and they are appropriate turned-off in the
135 configuration:
136 .../tools/genmake -disable=gmredi,kpp,obcs
137
138 If you add some source files you can re-call the previous instance of
139 genmake with "make makefile".
140
141 genmake also reads the file .genmakerc which can be used to configure
142 options (primarily the command-line options above) for particular experiments.
143 EOF
144 exit
145 breaksw
146 default:
147 echo "Unknown command-line option: " $arg
148 echo $0 "-help to show usage"
149 exit
150 breaksw
151 endsw
152 shift allargs
153 end
154
155 # Default actions/options
156
157 # If platform wasn't specified then determine platform type of the host
158 if (! $?platform) then
159 set platform = (`uname`)
160 # This let's us distinguish between different Linux platforms
161 if ($platform == Linux) then
162 set machine = (`uname -m`)
163 set platform = ($platform'-'$machine)
164 endif
165 endif
166 # If name of makefile wasn't specified then use default "Makefile"
167 if (! $?mfile) set mfile = ( Makefile )
168
169 set mach = ( `uname -a` )
170 echo Operating system: $mach
171
172 # Directories for source, includes, binaries and executables
173 #
174 # If -rootdir wasn't specified then assume script is being run from bin
175 # but if it was supplied then we should place the executable in the build dir
176 if (! $?ROOTDIR) then
177 set pwd=`pwd`
178 if ($pwd:t == bin & -d ../model & -d ../eesupp & -d ../pkg) then
179 set ROOTDIR = ( .. )
180 endif
181 endif
182 # Scan for logical ROOTDIR
183 if (! $?ROOTDIR) then
184 foreach dr (. .. ../.. ../../.. ../../../.. ../../../../..)
185 if (-d $dr/model & -d $dr/eesupp & -d $dr/pkg) then
186 set ROOTDIR = $dr
187 echo ROOTDIR was not specified. Setting ROOTDIR = \"$ROOTDIR\"
188 break
189 endif
190 end
191 endif
192 if (! $?ROOTDIR) then
193 echo Root directory was not specified and could not be determined.
194 echo Specify the root location of the model source with -rootdir=dir
195 exit 1
196 endif
197 if (! -d $ROOTDIR) then
198 echo Root directory $ROOTDIR not found.;exit 1
199 endif
200 # If -mods wasn't specified then we will assume that we can find all the
201 # source code in the standard directories
202 if (! $?MODS) then
203 set SOURCEDIRS = ( )
204 set INCLUDEDIRS = ( )
205 else
206 set SOURCEDIRS = ( $MODS )
207 set INCLUDEDIRS = ( $MODS )
208 endif
209 if (! $?BUILDDIR) set BUILDDIR = ( . )
210 if (! -d $BUILDDIR) then
211 echo Build directory $BUILDDIR not found.;exit 1
212 endif
213 if (! $?EXEDIR) then
214 set pwd=`pwd`
215 if ($pwd:t == bin & -d ../exe & $ROOTDIR == ..) then
216 set EXEDIR = ( ../exe )
217 else
218 set EXEDIR = ( . )
219 endif
220 endif
221 if (! -d $EXEDIR) then
222 echo Executable directory $EXEDIR not found.;exit 1
223 endif
224 if (! $?TOOLSDIR) set TOOLSDIR = ( $ROOTDIR/tools )
225 if (! -d $TOOLSDIR) then
226 echo Tools directory $TOOLSDIR not found.;exit 1
227 endif
228 if (! $?EXECUTABLE) set EXECUTABLE = ( mitgcmuv )
229
230 # We have a special set of source files in eesupp/src which
231 # are generated from some template source files. We'll make them
232 # first so the appear as regular source code
233 if (-r $ROOTDIR/eesupp/src/Makefile) then
234 echo Making source files in eesupp from templates...
235 (cd $ROOTDIR/eesupp/src/; make) >& make_eesupp.errs
236 if ($status == 0) then
237 rm -f make_eesupp.errs
238 else
239 cat make_eesupp.errs
240 exit 2
241 endif
242 endif
243
244 # Now scan the standard source code tree
245 foreach dr ($SOURCEDIRS)
246 set adr=$dr
247 if (! -d $adr) then
248 echo mods directory $adr not found.; exit 1
249 endif
250 echo Adding mods dir: $adr
251 end
252 if (! $?PACKAGES) then
253 set PACKAGES=()
254 foreach pkg (`cd $ROOTDIR/pkg; find . -type d -print | grep -v CVS | sed 's:\./::' | grep -v "\." | sort`)
255 if (-d $ROOTDIR/pkg/$pkg) set PACKAGES=($PACKAGES $pkg)
256 end
257 endif
258 foreach dr ($PACKAGES)
259 set enable
260 foreach p ($DISABLE)
261 if ($p != 'all' & ! -d $ROOTDIR/pkg/$p) then
262 echo Specified package \"$p\" does not exist.
263 exit 1
264 endif
265 if ($dr == $p) unset enable
266 if ($p == 'all') unset enable
267 # The following allows entire trees to be disabled
268 if ($dr:h == $p) unset enable
269 if ($dr:h:h == $p) unset enable
270 if ($dr:h:h:h == $p) unset enable
271 if ($dr:h:h:h:h == $p) unset enable
272 end
273 foreach p ($ENABLE)
274 if ($dr == $p) set enable
275 end
276 if ($?enable) then
277 set adr=$ROOTDIR/pkg/$dr
278 if (! -d $adr) then
279 echo Source directory $adr not found.; exit 1
280 endif
281 echo Adding pkg dir: $adr
282 set SOURCEDIRS = ($SOURCEDIRS $adr)
283 set INCLUDEDIRS = ($INCLUDEDIRS $adr)
284 switch ($dr)
285 case ptracers:
286 set DEFINES = ($DEFINES '-DALLOW_PTRACERS'); breaksw
287 default:
288 breaksw
289 endsw
290 else
291 echo " *" Package \"$dr\" NOT enabled.
292 switch ($dr)
293 case mom_fluxform:
294 set DEFINES = ($DEFINES '-DDISABLE_MOM_FLUXFORM'); breaksw
295 case mom_vecinv:
296 set DEFINES = ($DEFINES '-DDISABLE_MOM_VECINV'); breaksw
297 case generic_advdiff:
298 set DEFINES = ($DEFINES '-DDISABLE_GENERIC_ADVDIFF'); breaksw
299 case debug:
300 set DEFINES = ($DEFINES '-DDISABLE_DEBUGMODE'); breaksw
301 default:
302 breaksw
303 endsw
304 endif
305 end
306 if (! $?STANDARDDIRS) set STANDARDDIRS=(eesupp model)
307 foreach dr ($STANDARDDIRS)
308 set adr=$ROOTDIR/$dr/src
309 if (! -d $adr) then
310 echo Source directory $adr not found.; exit 1
311 endif
312 echo Adding src dir: $adr
313 set SOURCEDIRS = ($SOURCEDIRS $adr)
314 set idr = `echo $adr | sed 's/src/inc/'`
315 set INCLUDEDIRS = ($INCLUDEDIRS $idr)
316 end
317
318 # Find possible compilers
319 if ($?FC) then
320 echo "$FC was specified as the compiler"
321 else
322 echo " "
323 switch ($platform)
324 case Linux*:
325 set likelysuspects=(g77 ifc pgf77 f77 f90 f95)
326 breaksw
327 default:
328 set likelysuspects=(f77)
329 breaksw
330 endsw
331 foreach fc ($likelysuspects)
332 set foundfc=`which $fc |& cat - `
333 if (-x $foundfc[1]) then
334 if ($?possiblefc) then
335 set possiblefc=($possiblefc $fc)
336 else
337 set possiblefc=$fc
338 endif
339 endif
340 end
341 if ($?possiblefc) then
342 set FC=$possiblefc[1]
343 echo Found these compilers: $possiblefc. Using \"$FC\" as the compiler
344 else
345 echo "No compiler found\!"
346 echo I tried looking for \"$likelysuspects\" in your \$PATH but found none
347 echo I will continue anyway and see what happens.
348 set FC = ( 'f77' )
349 # exit 13
350 endif
351 endif
352
353 # This is the generic configuration.
354 # Platform specific options are chosen below
355 set LN = ( 'ln -s' )
356 set CPP = ( '/lib/cpp -P' )
357 set S64 = ( '$(TOOLSDIR)/set64bitConst.sh' )
358 set KPP = ( )
359 #set FC = ( 'f77' )
360 set LINK = $FC
361 set MAKEDEPEND = ( 'makedepend' )
362 set INCLUDES = ( -I. )
363 set FFLAGS = ( )
364 set FOPTIM = ( )
365 set CFLAGS = ( )
366 set KFLAGS1 = ( )
367 set KFLAGS2 = ( )
368 set LIBS = ( )
369 set KPPFILES = ( )
370 if (! $?NOOPTFILES ) set NOOPTFILES = ( )
371 if (! $?NOOPTFLAGS ) set NOOPTFLAGS = ( )
372 set RMFILES = ( )
373
374 # We often want to use different compile/link options is using MPI
375 if ($?USEMPI) then
376 set USEMPI = ( '+mpi' )
377 set DEFINES = ( ${DEFINES} '-DALLOW_USE_MPI -DALWAYS_USE_MPI' )
378 else
379 set USEMPI
380 # set DEFINES = ( ${DEFINES} '-UALLOW_USE_MPI -UALWAYS_USE_MPI' )
381 endif
382
383 if ($?USEARPACK) then
384 set USEARPACK = ( '+arpack' )
385 set LIBS = ( '-L/usr/lib -larpack -llapack' )
386 else
387 set USEARPACK
388 endif
389
390 # Platform specific options
391 switch ($platform$USEMPI$USEARPACK)
392 case OSF1+mpi:
393 #ph: e.g. halem.gsfc.nasa.gov
394 echo "Configuring for DEC Alpha with MPI"
395 set LIBS = ( '-lfmpi -lmpi -lkmp_osfp10 -pthread' )
396 #ph: -lkmp_osfp10 not needed on some/many platforms
397 case OSF1:
398 echo "Configuring for DEC Alpha"
399 set CPP = ( '/usr/bin/cpp -P' )
400 set DEFINES = ( ${DEFINES} '-DTARGET_DEC -DWORDLENGTH=1' )
401 set MAKEDEPEND = ( mkdep -f depend.out )
402 #ph: makedepend not available on some/many DEC Alpha's; use mkdep instead
403 set KPP = ( )
404 set KPPFILES = ( )
405 set KFLAGS1 = ( )
406 set FC = ( 'f77' )
407 set FFLAGS = ( '-convert big_endian -r8 -extend_source -automatic -call_shared -notransform_loops -align dcommons' )
408 set FOPTIM = ( '-O5 -fast -tune host -inline all' )
409 #ph: -O5 probably too aggressive in conjunction with adjoint code
410 set NOOPTFLAGS = ( '-O0' )
411 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
412 set RMFILES = ( '*.p.out' )
413 breaksw
414 case IRIX64+mpi:
415 echo "Configuring for SGI Mips with MPI"
416 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
417 set INCLUDES = ( '-I/usr/local/mpi/include' )
418 set FC = ( 'mpif77' )
419 set LINK = ( 'mpif77' )
420 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
421 set FOPTIM = ( '-O3' )
422 set RMFILES = ( 'rii_files' )
423 breaksw
424 case IRIX64:
425 echo "Configuring for SGI Mips"
426 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
427 set INCLUDES = ( '-I/usr/local/mpi/include' )
428 set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4 -r8 -static' )
429 set FOPTIM = ( '-O3' )
430 if ($?IEEE) set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4 -static' )
431 if ($?IEEE) set FOPTIM = ( '-O0 -OPT:IEEE_arithmetic=1 -OPT:IEEE_NaN_inf=ON' )
432 set RMFILES = ( 'rii_files' )
433 breaksw
434 case o2:
435 case IRIX:
436 echo "Configuring for SGI O2 running IRIX 6.5"
437 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
438 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
439 set FOPTIM = ( '-O2' )
440 set NOOPTFLAGS = ( '-O0' )
441 breaksw
442 case o2+mpi:
443 case IRIX+mpi:
444 echo "Configuring for SGI O2 running IRIX 6.5 with MPI"
445 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
446 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
447 set FOPTIM = ( '-O2' )
448 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F' )
449 set NOOPTFLAGS = ( '-O0' )
450 set LIBS = ( '-lmpi' )
451 breaksw
452 case o2k+mpi:
453 echo "Configuring for SGI Origin2000 running IRIX 6.5"
454 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
455 set INCLUDES = ( '-I/usr/include' )
456 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
457 set FOPTIM = ( '-O3 -OPT:Olimit=0:roundoff=3:div_split=ON:alias=typed' )
458 set LIBS = ( '-lmpi -lscs' )
459 breaksw
460 case o2k_noopt:
461 case o2k_noopt+mpi:
462 echo "Configuring for SGI Origin2000 running IRIX 6.5"
463 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
464 set INCLUDES = ( '-I/usr/include' )
465 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
466 set FOPTIM = ( '-O0' )
467 set LIBS = ( '-lmpi' )
468 breaksw
469 case ames_dbg+mpi:
470 echo "Configuring for SGI Origin2000 running IRIX 6.5"
471 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
472 set INCLUDES = ( '-I/usr/include -I/opt/mpt/1.6.1.beta/usr/include' )
473 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
474 set LIBS = ( '-lmpi -lscs' )
475 set FC = ( 'f90' )
476 set LINK = ( 'f90' )
477 breaksw
478 case ames_opt+mpi:
479 echo "Configuring for SGI Origin2000 running IRIX 6.5"
480 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
481 set INCLUDES = ( '-I/usr/include -I/opt/mpt/1.6.1.beta/usr/include' )
482 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
483 set FOPTIM = ( '-O3 -OPT:Olimit=0:roundoff=3:div_split=ON:alias=typed' )
484 set LIBS = ( '-lmpi -lscs' )
485 set FC = ( 'f90' )
486 set LINK = ( 'f90' )
487 breaksw
488 case onyx:
489 case onyx+mpi:
490 echo "Configuring for SGI ONYX running IRIX64"
491 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
492 set FFLAGS = ( '-extend_source -bytereclen -r10000 -64' )
493 set FOPTIM = ( '-O2' )
494 set NOOPTFLAGS = ( '-O0' )
495 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F' )
496 set LIBS = ( '-lmpi' )
497 breaksw
498 case SunOS:
499 set LN = ( '/usr/bin/ln -s' )
500 set CPP = ( '/usr/ccs/lib/cpp -P' )
501 set MAKEDEPEND = ( ${TOOLSDIR}/xmakedepend )
502 set DEFINES = ( ${DEFINES} '-DTARGET_SUN -DWORDLENGTH=4 -D_d=E' )
503 set FFLAGS = ( '-stackvar -explicitpar -vpara -e -u -noautopar -xtypemap=real:64,double:64,integer:32 -fsimple=0' )
504 set FOPTIM = ( '-dalign -O3 -xarch=v9' )
505 set CFLAGS = ( '-dalign -O3 -xarch=v9' )
506 set NOOPTFLAGS = ( '-dalign -O0 -xarch=v9' )
507 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F ini_vertical_grid.F ini_spherical_polar_grid.F ini_cori.F mon_printstats_rl.F mon_printstats_rs.F aim_aim2dyn.F aim_dyn2aim.F aim_aim2dyn_exchanges.F aim_external_fields_load.F aim_calc_diags.F aim_external_forcing.F aim_do_atmos_physics.F aim_write_diags.F aim_do_inphys.F ')
508 breaksw
509 case SunOS+mpi:
510 set LN = ( '/usr/bin/ln -s' )
511 set CPP = ( '/usr/ccs/lib/cpp -P' )
512 set DEFINES = ( ${DEFINES} '-DTARGET_SUN -DWORDLENGTH=4 -D_d=E' )
513 set INCLUDES = ( '-I/usr/local/mpi/include' )
514 set LIBS = ( '-L/usr/local/mpi/lib/solaris/ch_shmem -lmpi -lthread' \
515 set FFLAGS = ( '-stackvar -explicitpar -vpara -e -u -noautopar -xtypemap=real:64,double:64,integer:32 -fsimple=0' )
516 set FOPTIM = ( '-dalign -O3 -xarch=v9' )
517 set NOOPTFLAGS = ( '-dalign -O0 -xarch=v9' )
518 '-lsocket -lnsl' )
519 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F ini_vertical_grid.F ini_spherical_polar_grid.F ini_cori.F mon_printstats_rl.F mon_printstats_rs.F')
520 breaksw
521 case SunFire+mpi:
522 set FC = ( 'mpf77' )
523 set LINK = ( 'mpf77' )
524 set LN = ( '/usr/bin/ln -s' )
525 set CPP = ( '/usr/ccs/lib/cpp -P' )
526 set MAKEDEPEND = ( ${TOOLSDIR}/xmakedepend )
527 set DEFINES = ( ${DEFINES} '-DTARGET_SUN -DWORDLENGTH=4' )
528 set INCLUDES = ( '-I/opt/SUNWhpc/include' )
529 set LIBS = ( '-lmpi -lthread -lsocket -lnsl' )
530 set FFLAGS = ( '-e -u -noautopar ' \
531 '-xtypemap=real:64,double:64,integer:32 -fsimple=0' )
532 set FOPTIM = ( '-dalign -O4 -xarch=native' )
533 set CFLAGS = ( '-dalign -xO4 -xarch=native' )
534 set NOOPTFLAGS = ( '-dalign -O0 -xarch=native' )
535 breaksw
536 case IRIX32:
537 echo "Configuring for SGI ONYX running IRIX64"
538 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
539 set INCLUDES = ( '-I/usr/include' )
540 set FFLAGS = ( '-extend_source -bytereclen -r10000 -64' )
541 set FOPTIM = ( '-O2' )
542 set NOOPTFLAGS = ( '-O0' )
543 set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
544 'external_fields_load.F' )
545 set LIBS = ( '-lmpi' )
546 breaksw
547 case HP-UX+mpi:
548 set FC = ( 'mpif77' )
549 set LINK = ( 'mpif77' )
550 set INCLUDES = ( '-I/opt/mpi/include' )
551 case HP-UX:
552 echo "Configuring for HP Exemplar"
553 set CPP = ( '/usr/ccs/lbin/cpp -P' )
554 set DEFINES = ( ${DEFINES} '-DTARGET_HP -DWORDLENGTH=4' )
555 set FFLAGS = ( '+es +U77 +Onoautopar +Oexemplar_model' \
556 '+Okernel_threads' )
557 set FOPTIM = ( '+O2' )
558 set NOOPTFLAGS = ( '+O0' )
559 set NOOPTFILES = ( 'barrier.F different_multiple.F' \
560 'external_fields_load.F' )
561 breaksw
562 case Linux-ia64+mpi:
563 echo "Configuring with MPI"
564 case Linux-ia64:
565 echo "Configuring for " $platform
566 set LN = ( '/bin/ln -s' )
567 set CPP = ( '/lib/cpp -traditional -P' )
568 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
569 set FC = ( 'efc' )
570 set FFLAGS = ( '-WB -Vaxlib -u -w' )
571 # set FOPTIM = ( '-O2 -ftz' )
572 set FOPTIM = ( '-O3 -mp' )
573 set LINK = ( 'efc' )
574 set LIBS = ( '-lmpi -lscs -lpthread' )
575 breaksw
576 case Linux-alpha+mpi:
577 echo "Configuring with MPI"
578 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
579 set INCLUDES = ( '-I/usr/local/include' )
580 case Linux-alpha:
581 echo "Configuring for " $platform
582 set LN = ( '/bin/ln -s' )
583 set CPP = ( '/lib/cpp -traditional -P' )
584 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
585 set FC = ( 'g77' )
586 set FFLAGS = ( ' ' )
587 if ($?IEEE) set FFLAGS = ( $FFLAGS '-ffloat-store' )
588 set FOPTIM = ( '-ffast-math -fexpensive-optimizations -fomit-frame-pointer -O3' )
589 set LINK = ( 'g77' )
590 breaksw
591 case Linux*+pgi+mpi:
592 if ($?include_jam_libs) then
593 set INCLUDES = ( '-I/usr/local/mpich-1.2.1/pgi_fortran_binding/include' )
594 set LIBS = ( '-L/usr/local/mpich-1.2.1/pgi_fortran_binding/lib/ -lfmpich -lmpich' )
595 else
596 set INCLUDES = ( '-I/usr/local/include' )
597 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
598 endif
599 case Linux*+pgi:
600 echo "Configuring for " $platform
601 set LN = ( '/bin/ln -s' )
602 set CPP = ( '/lib/cpp -traditional -P' )
603 set DEFINES = ( ${DEFINES} '-DWORDLENGTH=4' )
604 set FC = ( 'pgf77' )
605 set FFLAGS = ( '-byteswapio -r8 -Mnodclchk -Mextend' )
606 set FOPTIM = ( '-tp p6 -v -O2 -Munroll -Mvect=cachesize:512000,transform -Kieee' )
607 set LINK = ( 'pgf77' )
608 breaksw
609 case Linux*+mpi:
610 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
611 set INCLUDES = ( '-I/usr/local/include' )
612 case Linux*:
613 echo "Configuring for " $platform
614 set LN = ( '/bin/ln -s' )
615 set CPP = ( '/lib/cpp -traditional -P' )
616 switch ($FC)
617 case g77:
618 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
619 set FFLAGS = ( '-Wimplicit -Wunused -Wuninitialized' )
620 if ($?IEEE) set FFLAGS = ( $FFLAGS '-ffloat-store' )
621 set FOPTIM = ( '-O3 -malign-double -funroll-loops' )
622 set NOOPTFLAGS = ( '-O0' )
623 breaksw
624 case pgf77:
625 set DEFINES = ( ${DEFINES} '-DWORDLENGTH=4' )
626 set FC = ( 'pgf77' )
627 set FFLAGS = ( '-byteswapio -r8 -Mnodclchk -Mextend' )
628 set FOPTIM = ( '-tp p6 -v -O2 -Munroll -Mvect=cachesize:512000,transform -Kieee' )
629 breaksw
630 case ifc:
631 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
632 set FFLAGS = ( '-132 -r8 -i4 -w95 -W0 -WB' )
633 if ($?IEEE) set FFLAGS = ( $FFLAGS '-mp' )
634 set FOPTIM = ( '-O3 -align' )
635 #P3 set FOPTIM = ( $FOPTIM '-tpp6 -xWKM' )
636 #P4 set FOPTIM = ( $FOPTIM '-tpp7 -xWKM' )
637 set LIBS = ( ${LIBS} '-lPEPCF90' )
638 breaksw
639 default:
640 echo Error: Linux compiler not recognized: \$FC=$FC
641 exit
642 breaksw
643 endsw
644 breaksw
645 case T3E:
646 case sn6312:
647 echo "Configuring for T3E"
648 set CPP = ( '/opt/ctl/bin/cpp -P')
649 set DEFINES = ( ${DEFINES} '-DTARGET_T3E -DWORDLENGTH=4' )
650 set FC = ( 'f90' )
651 set LINK = ( 'f90' )
652 set FFLAGS = ( '-O 2,fusion' )
653 breaksw
654 case T90:
655 case sn7113:
656 echo "Configuring for T90"
657 set FC = ( 'f90' )
658 set LINK = ( 'f90' )
659 set LN = ( '/bin/ln -s' )
660 set CPP = ( '/opt/ctl/bin/cpp -N -P' )
661 set DEFINES = ( ${DEFINES} '-DTARGET_CRAY_VECTOR -DWORDLENGTH=4' )
662 set FFLAGS = ( '-m3 -Rabc -N 132')
663 set FOPTIM = ( '-O0' )
664 set NOOPTFLAGS = ( '-O0' )
665 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
666 breaksw
667 case SV1:
668 case sn3002:
669 set FC = ( 'f90' )
670 set LINK = ( 'f90' )
671 set LN = ( '/bin/ln -s' )
672 set CPP = ( '/opt/ctl/bin/cpp -N -P' )
673 set DEFINES = ( ${DEFINES} '-DTARGET_CRAY_VECTOR -DWORDLENGTH=4' )
674 set FFLAGS = ( '-m3 -Rabc -ei -eI -s cf77types -N 132')
675 set FOPTIM = ( '-O0' )
676 set NOOPTFLAGS = ( '-O0' )
677 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
678 breaksw
679 case cg01+pgi:
680 set LN = ( '/bin/ln -s' )
681 set CPP = ( '/lib/cpp -traditional -P' )
682 set INCLUDES = ( '-I/usr/local/pkg/mpi/mpi-1.2.4..8a-gm-1.5/pgi/include' )
683 set DEFINES = ( ${DEFINES} '-DWORDLENGTH=4' )
684 set FC = ( '/usr/local/pkg/mpi/mpi-1.2.4..8a-gm-1.5/pgi/bin/mpif77' )
685 set FFLAGS = ( '-byteswapio -r8 -Mnodclchk -Mextend' )
686 # set LIBS = ( '-L/home/cnh/src/gm-1.4/libgm')
687 set FOPTIM = ( '-tp p6 -v -O2 -Munroll -Mvect=cachesize:512000,transform -Kieee' )
688 set LINK = ( '/usr/local/pkg/mpi/mpi-1.2.4..8a-gm-1.5/pgi/bin/mpif77' )
689 breaksw
690 case SP3:
691 # originally from A. Biastoch, SIO.
692 # e.g. horizon.npaci.edu
693 echo "Configuring for IBM SP POWER3"
694 set SOURCEDIRS = ( ./ $SOURCEDIRS )
695 set LN = ( 'ln -s' )
696 set DEFINES = ( ${DEFINES} '-DTARGET_PWR3 -DTARGET_SGI -DWORDLENGTH=4' )
697 set INCLUDES = ( '-I/usr/lpp/ppe.poe/include' )
698 # set CPP = ( '/lib/cpp' )
699 set FC = ( 'mpxlf95' )
700 set LINK = ( 'mpxlf95' )
701 set FLAGS = ( '-O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
702 '-bmaxdata:0x80000000 -bloadmap:mitgcmuv.map' )
703 set FFLAGS = ( '-qfixed=132 -O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
704 '-bmaxdata:0x80000000 ' )
705 set LDFLAGS = ( '-O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
706 '-bmaxdata:0x80000000' )
707 set LIBS = ( ' -L/usr/local/apps/mass -lmass' )
708 # set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4' )
709 # set FOPTIM = ( '-O3' )
710 # set NOOPTFLAGS = ( '-O0' )
711 # set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
712 # 'external_fields_load.F' )
713 set RMFILES = ( 'rii_files' )
714 breaksw
715 case SP4:
716 #ph: e.g. bluesky.ucar.edu, marcellus.navo.hpc.mil
717 echo "Configuring for IBM SP POWER4"
718 set SOURCEDIRS = ( ./ $SOURCEDIRS )
719 set LN = ( 'ln -s' )
720 set DEFINES = ( ${DEFINES} '-DTARGET_PWR3 -DTARGET_SGI -DWORDLENGTH=4' )
721 set INCLUDES = ( '-I/usr/lpp/ppe.poe/include' )
722 # set CPP = ( '/lib/cpp' )
723 set FC = ( 'mpxlf95' )
724 set LINK = ( 'mpxlf95' )
725 set FLAGS = ( '-O3 -qarch=pwr4 -qtune=pwr4 -qcache=auto -qmaxmem=-1' \
726 '-bmaxdata:0x80000000 -bloadmap:mitgcmuv.map' )
727 set FFLAGS = ( '-qfixed=132 -O3 -qarch=pwr4 -qtune=pwr4 -qcache=auto -qmaxmem=-1' \
728 '-bmaxdata:0x80000000 ' )
729 set LDFLAGS = ( '-O3 -qarch=pwr4 -qtune=pwr4 -qcache=auto -qmaxmem=-1' \
730 '-bmaxdata:0x80000000' )
731 set LIBS = ( ' -L/usr/local/apps/mass -lmass' )
732 # set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4' )
733 # set FOPTIM = ( '-O3' )
734 # set NOOPTFLAGS = ( '-O0' )
735 # set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
736 # 'external_fields_load.F' )
737 set RMFILES = ( 'rii_files' )
738 breaksw
739 case aer-linux-cluster+mpi
740 echo "Configuring for " $platform
741 set LN = ( '/bin/ln -s' )
742 set CPP = ( '/lib/cpp -traditional -P' )
743 set DEFINES = ( ${DEFINES} '-DWORDLENGTH=4' )
744 set FC = ( '/opt/mpich/bin/mpif77' )
745 set LINK = ( '/opt/mpich/bin/mpif77' )
746 set FFLAGS = ( '-byteswapio -r8 -Mnodclchk -Mextend' )
747 set FOPTIM = ( '-tp p6 -v -O2 -Munroll -Mvect=cachesize:512000,transform -Kieee' )
748 set LIBS = ( '-L/opt/mpich/lib/ -lfmpich -lmpich' )
749 set INCLUDES = ( '-I/opt/mpich/include' )
750 breaksw
751 case gfdl-sgi-o3k
752 echo "Configuring for " $platform
753 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
754 set FFLAGS = ( 'extend_source -mp -mpio -bytereclen -mips4 -r8 -static' )
755 set FOPTIM = ( '-O3' )
756 set LIBS = ( '-lmpi' )
757 set INCLUDES = ( '-I/opt/mpt/1510/usr/include' )
758 breaksw
759 default:
760 echo "Error: platform not recognized: uname -p = " $platform$USEMPI
761 exit
762 breaksw
763 default:
764 echo "Error: platform not recognized: uname -p = " $platform$USEMPI
765 exit
766 breaksw
767 endsw
768
769 ###############################################################################
770 ## ##
771 ## Everything below here should not need to be changed. Platform specific ##
772 ## changes and code specific changes should be configured above this line. ##
773 ## ##
774 ###############################################################################
775
776 # Convert lists of directories into command-line options
777 foreach inc ($INCLUDEDIRS)
778 set INCLUDES = ($INCLUDES -I$inc)
779 end
780
781 # Search for source code
782 rm -rf .links.tmp;mkdir .links.tmp
783 echo "# This section creates symbolic links" > srclinks.tmp
784 echo "" >> srclinks.tmp
785 echo -n 'SRCFILES = ' > srclist.inc
786 echo -n 'CSRCFILES = ' > csrclist.inc
787 echo -n 'HEADERFILES = ' > hlist.inc
788 foreach dr ($SOURCEDIRS $INCLUDEDIRS .)
789 set deplist=( )
790 foreach srcfile (`cd $dr; ls *.[hcF]`)
791 if (! -r .links.tmp/$srcfile) then
792 if (-f $dr/$srcfile) then
793 switch ($srcfile:e)
794 case F:
795 touch .links.tmp/$srcfile
796 set deplist=($deplist $srcfile)
797 echo ' \' >> srclist.inc
798 echo -n " " $srcfile >> srclist.inc
799 breaksw
800 case c:
801 touch .links.tmp/$srcfile
802 set deplist=($deplist $srcfile)
803 echo ' \' >> csrclist.inc
804 echo -n " " $srcfile >> csrclist.inc
805 breaksw
806 case h:
807 touch .links.tmp/$srcfile
808 set deplist=($deplist $srcfile)
809 echo ' \' >> hlist.inc
810 echo -n " " $srcfile >> hlist.inc
811 breaksw
812 endsw
813 endif
814 endif
815 end
816 if ($#deplist != 0) then
817 echo "# These files are linked from $dr" >> srclinks.tmp
818 echo $deplist':' >> srclinks.tmp
819 echo ' $(LN) '$dr'/$@ $@' >> srclinks.tmp
820 endif
821 end
822 rm -rf .links.tmp
823 echo "" >> srclist.inc
824 echo "" >> csrclist.inc
825 echo "" >> hlist.inc
826
827 set THISHOSTNAME = ( `hostname` )
828 set THISCWD = ( `pwd` )
829 set THISDATE = ( `date` )
830
831 if (-r $mfile) mv -f $mfile $mfile.bak
832 ###########################################
833 ## This is the template for the makefile ##
834 ###########################################
835 echo Creating makefile: $mfile
836 echo "# Multithreaded + multi-processing makefile for $mach" > ${mfile}
837 echo "# This makefile was generated automatically on" >> ${mfile}
838 echo "# $THISDATE" >> ${mfile}
839 echo "# by the command:" >> ${mfile}
840 echo "# ${0} $argv" >> ${mfile}
841 echo "# executed by:" >> ${mfile}
842 echo "# $USER@${THISHOSTNAME}:${THISCWD}" >> ${mfile}
843 cat >> ${mfile} <<EOF
844 #
845 # BUILDDIR : Directory where object files are written
846 # SOURCEDIRS : Directories containing the source (.F) files
847 # INCLUDEDIRS : Directories containing the header-source (.h) files
848 # EXEDIR : Directory where executable that is generated is written
849 # EXECUTABLE : Full path of executable binary
850 #
851 # CPP : C-preprocessor command
852 # INCLUDES : Directories searched for header files
853 # DEFINES : Macro definitions for CPP
854 # MAKEDEPEND : Dependency generator
855 # KPP : Special preprocessor command (specific to platform)
856 # KFLAGS : Flags for KPP
857 # FC : Fortran compiler command
858 # FFLAGS : Configuration/debugging options for FC
859 # FOPTIM : Optimization options for FC
860 # LINK : Command for link editor program
861 # LIBS : Library flags /or/ additional optimization/debugging flags
862
863 ROOTDIR = ${ROOTDIR}
864 BUILDDIR = ${BUILDDIR}
865 SOURCEDIRS = ${SOURCEDIRS}
866 INCLUDEDIRS = ${INCLUDEDIRS}
867 EXEDIR = ${EXEDIR}
868 EXECUTABLE = \$(EXEDIR)/${EXECUTABLE}
869 TOOLSDIR = ${TOOLSDIR}
870
871 EOF
872
873
874 # JAM libraries on Hyades
875 if ($?include_jam_libs) then
876 cat >> ${mfile} <<EOF
877 # extra stuff for Hyades ............................................
878 HYADES_DIR = /u/u0/cnh/jam-lib/software
879 HYADES_DIR = /u/u0/cnh/jam-lib-twoproc
880 HYADES_DIR = /usr/local/jamlib/current/dual_proc
881 WORK_DIR = \$(HYADES_DIR)
882 DEPOSIT_DIR = linux_bin
883
884 STARTXOBJDIR = startx_util/\$(DEPOSIT_DIR)
885 STARTXOBJ = \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/startx_timer.o \
886 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/startx_util.o \
887 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/client.o \
888 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/csutil.o
889
890 JAMOBJDIR = jam/\$(DEPOSIT_DIR)
891 JAMOBJ = \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_init.o \
892 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_kernel.o \
893 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_malloc.o \
894 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_vmalloc.o \
895 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_mutex.o
896
897 JAMCOBJDIR = jam_collective/\$(DEPOSIT_DIR)
898 JAMCOBJ = \$(WORK_DIR)/jam_collective/\$(DEPOSIT_DIR)/jam_collective.o
899
900 XLIBS = \$(STARTXOBJ) \$(JAMOBJ) \$(JAMCOBJ)
901
902 # ..................................................................
903
904 EOF
905 endif
906
907
908 cat >> ${mfile} <<EOF
909 # Unix ln (link)
910 LN = ${LN}
911 # C preprocessor
912 CPP = cat \$< | ${S64} | ${CPP}
913 # Dependency generator
914 MAKEDEPEND = ${MAKEDEPEND}
915 # Special preprocessor (KAP on DECs, FPP on Crays)
916 KPP = ${KPP}
917 # Fortran compiler
918 FC = ${FC}
919 # Link editor
920 LINK = ${LINK}
921
922 # Defines for CPP
923 DEFINES = ${DEFINES}
924 # Includes for CPP
925 INCLUDES = ${INCLUDES}
926 # Flags for KPP
927 KFLAGS1 = ${KFLAGS1}
928 KFLAGS2 = ${KFLAGS2}
929 # Optim./debug for FC
930 FFLAGS = ${FFLAGS}
931 FOPTIM = ${FOPTIM}
932 # Flags for CC
933 CFLAGS = ${CFLAGS}
934 # Files that should not be optimized
935 NOOPTFILES = ${NOOPTFILES}
936 NOOPTFLAGS = ${NOOPTFLAGS}
937 # Flags and libraries needed for linking
938 LIBS = ${LIBS} \$(XLIBS)
939
940 EOF
941
942 cat srclist.inc >> ${mfile}
943 cat csrclist.inc >> ${mfile}
944 cat hlist.inc >> ${mfile}
945 echo 'F77FILES = $(SRCFILES:.F=.f)' >> ${mfile}
946 echo 'OBJFILES = $(SRCFILES:.F=.o) $(CSRCFILES:.c=.o)' >> ${mfile}
947
948 rm -f srclist.inc csrclist.inc hlist.inc flist.tmp clist.tmp
949
950 cat >> ${mfile} <<EOF
951
952 .SUFFIXES:
953 .SUFFIXES: .o .f .p .F .c
954
955 all: \$(EXECUTABLE)
956 \$(EXECUTABLE): \$(OBJFILES)
957 \$(LINK) -o \$@ \$(FFLAGS) \$(FOPTIM) \$(OBJFILES) \$(LIBS)
958 depend:
959 @make links
960 \$(MAKEDEPEND) -o .f \$(DEFINES) \$(INCLUDES) \$(SRCFILES)
961
962 links: \$(SRCFILES) \$(CSRCFILES) \$(HEADERFILES)
963
964 small_f: \$(F77FILES)
965
966 output.txt: \$(EXECUTABLE)
967 @printf 'running ... '
968 @\$(EXECUTABLE) > \$@
969
970 clean:
971 -rm -rf *.o *.f *.p ${RMFILES} work.{pc,pcl}
972 Clean:
973 @make clean
974 @make cleanlinks
975 -rm -f Makefile.bak
976 CLEAN:
977 @make Clean
978 -find \$(EXEDIR) -name "*.meta" -exec rm {} \;
979 -find \$(EXEDIR) -name "*.data" -exec rm {} \;
980 -find \$(EXEDIR) -name "fort.*" -exec rm {} \;
981 -rm -f \$(EXECUTABLE)
982
983 makefile:
984 ${0} $argv
985 cleanlinks:
986 -find . -type l -exec rm {} \;
987
988 # The normal chain of rules is ( .F - .f - .o )
989 .F.f:
990 \$(CPP) \$(DEFINES) \$(INCLUDES) > \$@
991 .f.o:
992 \$(FC) \$(FFLAGS) \$(FOPTIM) -c \$<
993 .c.o:
994 \$(CC) \$(CFLAGS) -c \$<
995
996 # Special exceptions that use the ( .F - .p - .f - .o ) rule-chain
997 .F.p:
998 \$(CPP) \$(DEFINES) \$(INCLUDES) > \$@
999 .p.f:
1000 \$(KPP) \$(KFLAGS1)\$@ \$(KFLAGS2) \$<
1001 EOF
1002
1003 # Make list of "exceptions" that need ".p" files
1004 foreach sf ($KPPFILES)
1005 set fname=( ${sf:t} )
1006 echo "${fname:r}.f: ${fname:r}.p" >> ${mfile}
1007 end
1008 foreach sf ($NOOPTFILES)
1009 set fname=( ${sf:t} )
1010 echo "${fname:r}.o: ${fname:r}.f" >> ${mfile}
1011 echo ' $(FC) $(FFLAGS) $(NOOPTFLAGS) -c $<' >> ${mfile}
1012 end
1013 echo "" >> ${mfile}
1014
1015 # Add rules for links
1016 cat srclinks.tmp >> ${mfile}
1017 rm -f srclinks.tmp
1018
1019 echo "" >> ${mfile}
1020 echo "# DO NOT DELETE" >> ${mfile}
1021
1022 exit

  ViewVC Help
Powered by ViewVC 1.1.22