/[MITgcm]/MITgcm/tools/genmake
ViewVC logotype

Contents of /MITgcm/tools/genmake

Parent Directory Parent Directory | Revision Log Revision Log | View Revision Graph Revision Graph


Revision 1.61 - (show annotations) (download)
Fri Feb 15 21:26:37 2002 UTC (22 years, 1 month ago) by heimbach
Branch: MAIN
CVS Tags: ecco_c44_e18, ecco_c44_e19, ecco_c44_e17, checkpoint44f_pre, release1_final_v1, chkpt44d_post, checkpoint44e_post, checkpoint44e_pre
Branch point for: release1_final
Changes since 1.60: +8 -3 lines
Added variable MAKEDEPEND.
Is modified for case SunOS, uses ../tools/xmakedepend

1 #!/bin/csh -f
2 #
3 # $Header: /u/gcmpack/MITgcm/tools/genmake,v 1.60 2002/02/11 21:52:31 heimbach Exp $
4 # $Name: $
5 #
6 # Makefile generator for MITgcm UV codes
7 # created by cnh 03/98
8 # adapted by aja 06/98
9 # modified by aja 01/00
10
11 # Default lists
12 set DISABLE = ( aim autodiff cal cost ctrl ecco exf grdchk flt )
13 set DEFINES = ( )
14 set ENABLE = ( )
15 set MODS = ( )
16
17 # Grab variables/lists from .genmakerc
18 if (-r .genmakerc) source .genmakerc
19
20 # Process command-line arguments
21 set allargs=( $argv )
22 while ($#allargs)
23 set arg = $allargs[1]
24 switch ($arg)
25 case -makefile:
26 set mfile = ( Makefile )
27 breaksw
28 case -makefile=*:
29 set mfile = ( `echo $arg | sed 's/-makefile=//' `)
30 breaksw
31 case -platform:
32 case -platform=:
33 echo "To change platform you must specify one with -platform="
34 echo "eg. -platform=sparc or -platform=mips"
35 exit
36 breaksw
37 case -platform*:
38 if ($?platform) then
39 echo Option -platform=dir can only be specified once.; exit 1
40 endif
41 set platform = ( `echo $arg | sed 's/-platform=//' `)
42 breaksw
43 case -rootdir:
44 case -rootdir=:
45 echo "To specify root directory you must specify one with -rootdir=dir"
46 echo "with NO space eg. -rootdir=../../.. or -rootdir=/usr/people/joe/src"
47 exit
48 breaksw
49 case -rootdir=*:
50 if ($?ROOTDIR) then
51 echo "***" Warning: variable \$ROOTDIR is already set to $ROOTDIR
52 echo "***" Command line \"$arg\" will override this.
53 endif
54 set ROOTDIR = ( `echo $arg | sed 's/-rootdir=//' `)
55 breaksw
56 case -mods:
57 case -mods=:
58 echo "To specify an additional source directory you must specify one with -mods=dir"
59 echo "with NO space eg. -mods=../code or -mods=/usr/people/joe/src"
60 exit
61 breaksw
62 case -mods=*:
63 set MODS = ( $MODS `echo $arg | sed 's/-mods=//' | sed 's/,/ /g' `)
64 breaksw
65 case -disable:
66 case -disable=:
67 echo "To disable packages from compilation use -disable=pkg1,pkg2"
68 echo "with NO spaces eg. -disable=kpp,gmredi or -disable=all (to enable all packages)"
69 exit
70 breaksw
71 case -disable=*:
72 set DISABLE = ( $DISABLE `echo $arg | sed 's/-disable=//' | sed 's/,/ /g' `)
73 breaksw
74 case -enable:
75 case -enable=:
76 echo "To enable packages from compilation use -enable=pkg1,pkg2"
77 echo "with NO spaces eg. -enable=aim or -enable=all (to enable all packages)"
78 echo "-enable overrides -disable, ie. a package listed in both is enabled"
79 exit
80 breaksw
81 case -ieee:
82 set IEEE
83 breaksw
84 case -enable=*:
85 set ENABLE = ( $ENABLE `echo $arg | sed 's/-enable=//' | sed 's/,/ /g' `)
86 breaksw
87 case -mpi:
88 echo "Enabling MPI options"
89 set USEMPI
90 breaksw
91 case -jam:
92 set include_jam_libs
93 echo "Including paths to JAM libraries"
94 breaksw
95 case -help:
96 echo "usage: $0 [-help] [-makefile[=...]] [-platform=...] [-mpi] [-jam] [-disable=pkg1[,pkg2,...]] [-enable=pkg1[,pkg2,...]] [-mods=dir1[,dir2,...]] [-rootdir=dir]"
97 cat << EOF
98
99 $0 is used to generate the Makefile in the current directory.
100
101 Typical invocations are:
102 o from "bin": ../tools/genmake
103 o from "verification/expt/code": ../../../tools/genmake
104 o from "verification/expt/input": ../../../tools/genmake -mods=../code
105 o from a scratch directory: ~/mitgcm/tools/genmake -rootdir=~/mitgcm
106 or ~/mitgcm/tools/genmake -rootdir=~/mitgcm -mods=~/mymods
107
108 Packages (collected modules of code) can be disabled to avoid unnecessary
109 compilation of unused code. For instance if you know you will not
110 use GM/Redi, KPP and OBCS and they are appropriate turned-off in the
111 configuration:
112 .../tools/genmake -disable=gmredi,kpp,obcs
113
114 If you add some source files you can re-call the previous instance of
115 genmake with "make makefile".
116
117 genmake also reads the file .genmakerc which can be used to configure
118 options (primarily the command-line options above) for particular experiments.
119 EOF
120 exit
121 breaksw
122 default:
123 echo "Unknown command-line option: " $arg
124 echo $0 "-help to show usage"
125 exit
126 breaksw
127 endsw
128 shift allargs
129 end
130
131 # Default actions/options
132
133 # If platform wasn't specified then determine platform type of the host
134 if (! $?platform) then
135 set platform = (`uname`)
136 # This let's us distinguish between different Linux platforms
137 if ($platform == Linux) then
138 set machine = (`uname -m`)
139 set platform = ($platform'-'$machine)
140 endif
141 endif
142 # If name of makefile wasn't specified then use default "Makefile"
143 if (! $?mfile) set mfile = ( Makefile )
144
145 set mach = ( `uname -a` )
146 echo Operating system: $mach
147
148 # Directories for source, includes, binaries and executables
149 #
150 # If -rootdir wasn't specified then assume script is being run from bin
151 # but if it was supplied then we should place the executable in the build dir
152 if (! $?ROOTDIR) then
153 set pwd=`pwd`
154 if ($pwd:t == bin & -d ../model & -d ../eesupp & -d ../pkg) then
155 set ROOTDIR = ( .. )
156 endif
157 endif
158 # Scan for logical ROOTDIR
159 if (! $?ROOTDIR) then
160 foreach dr (. .. ../.. ../../.. ../../../.. ../../../../..)
161 if (-d $dr/model & -d $dr/eesupp & -d $dr/pkg) then
162 set ROOTDIR = $dr
163 echo ROOTDIR was not specified. Setting ROOTDIR = \"$ROOTDIR\"
164 break
165 endif
166 end
167 endif
168 if (! $?ROOTDIR) then
169 echo Root directory was not specified and could not be determined.
170 echo Specify the root location of the model source with -rootdir=dir
171 exit 1
172 endif
173 if (! -d $ROOTDIR) then
174 echo Root directory $ROOTDIR not found.;exit 1
175 endif
176 # If -mods wasn't specified then we will assume that we can find all the
177 # source code in the standard directories
178 if (! $?MODS) then
179 set SOURCEDIRS = ( )
180 set INCLUDEDIRS = ( )
181 else
182 set SOURCEDIRS = ( $MODS )
183 set INCLUDEDIRS = ( $MODS )
184 endif
185 if (! $?BUILDDIR) set BUILDDIR = ( . )
186 if (! -d $BUILDDIR) then
187 echo Build directory $BUILDDIR not found.;exit 1
188 endif
189 if (! $?EXEDIR) then
190 set pwd=`pwd`
191 if ($pwd:t == bin & -d ../exe & $ROOTDIR == ..) then
192 set EXEDIR = ( ../exe )
193 else
194 set EXEDIR = ( . )
195 endif
196 endif
197 if (! -d $EXEDIR) then
198 echo Executable directory $EXEDIR not found.;exit 1
199 endif
200 if (! $?TOOLSDIR) set TOOLSDIR = ( $ROOTDIR/tools )
201 if (! -d $TOOLSDIR) then
202 echo Tools directory $TOOLSDIR not found.;exit 1
203 endif
204 if (! $?EXECUTABLE) set EXECUTABLE = ( mitgcmuv )
205
206 # We have a special set of source files in eesupp/src which
207 # are generated from some template source files. We'll make them
208 # first so the appear as regular source code
209 if (-r $ROOTDIR/eesupp/src/Makefile) then
210 echo Making source files in eesupp from templates...
211 (cd $ROOTDIR/eesupp/src/; make) >& make_eesupp.errs
212 if ($status == 0) then
213 rm -f make_eesupp.errs
214 else
215 cat make_eesupp.errs
216 exit 2
217 endif
218 endif
219
220 # Now scan the standard source code tree
221 foreach dr ($SOURCEDIRS)
222 set adr=$dr
223 if (! -d $adr) then
224 echo mods directory $adr not found.; exit 1
225 endif
226 echo Adding mods dir: $adr
227 end
228 if (! $?PACKAGES) then
229 set PACKAGES=()
230 foreach pkg (`cd $ROOTDIR/pkg; find . -type d | grep -v CVS | sed 's:\./::' | grep -v "\." | sort`)
231 if (-d $ROOTDIR/pkg/$pkg) set PACKAGES=($PACKAGES $pkg)
232 end
233 endif
234 foreach dr ($PACKAGES)
235 set enable
236 foreach p ($DISABLE)
237 if ($p != 'all' & ! -d $ROOTDIR/pkg/$p) then
238 echo Specified package \"$p\" does not exist.
239 exit 1
240 endif
241 if ($dr == $p) unset enable
242 if ($p == 'all') unset enable
243 # The following allows entire trees to be disabled
244 if ($dr:h == $p) unset enable
245 if ($dr:h:h == $p) unset enable
246 if ($dr:h:h:h == $p) unset enable
247 if ($dr:h:h:h:h == $p) unset enable
248 end
249 foreach p ($ENABLE)
250 if ($dr == $p) set enable
251 end
252 if ($?enable) then
253 set adr=$ROOTDIR/pkg/$dr
254 if (! -d $adr) then
255 echo Source directory $adr not found.; exit 1
256 endif
257 echo Adding pkg dir: $adr
258 set SOURCEDIRS = ($SOURCEDIRS $adr)
259 set INCLUDEDIRS = ($INCLUDEDIRS $adr)
260 else
261 echo " *" Package \"$dr\" NOT enabled.
262 switch ($dr)
263 case mom_fluxform:
264 set DEFINES = ($DEFINES '-DDISABLE_MOM_FLUXFORM'); breaksw
265 case mom_vecinv:
266 set DEFINES = ($DEFINES '-DDISABLE_MOM_VECINV'); breaksw
267 case generic_advdiff:
268 set DEFINES = ($DEFINES '-DDISABLE_GENERIC_ADVDIFF'); breaksw
269 default:
270 breaksw
271 endsw
272 endif
273 end
274 if (! $?STANDARDDIRS) set STANDARDDIRS=(eesupp model)
275 foreach dr ($STANDARDDIRS)
276 set adr=$ROOTDIR/$dr/src
277 if (! -d $adr) then
278 echo Source directory $adr not found.; exit 1
279 endif
280 echo Adding src dir: $adr
281 set SOURCEDIRS = ($SOURCEDIRS $adr)
282 set idr = `echo $adr | sed 's/src/inc/'`
283 set INCLUDEDIRS = ($INCLUDEDIRS $idr)
284 end
285
286 # This is the generic configuration.
287 # Platform specific options are chosen below
288 set LN = ( 'ln -s' )
289 set CPP = ( '/lib/cpp -P' )
290 set S64 = ( '$(TOOLSDIR)/set64bitConst.sh' )
291 set KPP = ( )
292 set FC = ( 'f77' )
293 set LINK = ( 'f77' )
294 set MAKEDEPEND = ( 'makedepend' )
295 set INCLUDES = ( -I. )
296 set FFLAGS = ( )
297 set FOPTIM = ( )
298 set CFLAGS = ( )
299 set KFLAGS1 = ( )
300 set KFLAGS2 = ( )
301 set LIBS = ( )
302 set KPPFILES = ( )
303 set NOOPTFILES = ( )
304 set NOOPTFLAGS = ( )
305 set RMFILES = ( )
306
307 # We often want to use different compile/link options is using MPI
308 if ($?USEMPI) then
309 set USEMPI = ( '+mpi' )
310 set DEFINES = ( ${DEFINES} '-DALLOW_USE_MPI -DALWAYS_USE_MPI' )
311 else
312 set USEMPI
313 # set DEFINES = ( ${DEFINES} '-UALLOW_USE_MPI -UALWAYS_USE_MPI' )
314 endif
315
316 # Platform specific options
317 switch ($platform$USEMPI)
318 case OSF1+mpi:
319 echo "Configuring for DEC Alpha with MPI"
320 set LIBS = ( '-lfmpi -lmpi -lkmp_osfp10 -pthread' )
321 case OSF1:
322 echo "Configuring for DEC Alpha"
323 set CPP = ( '/usr/bin/cpp -P' )
324 set DEFINES = ( ${DEFINES} '-DTARGET_DEC -DWORDLENGTH=1' )
325 set KPP = ( )
326 set KPPFILES = ( )
327 set KFLAGS1 = ( )
328 set FC = ( 'f77' )
329 set FFLAGS = ( '-convert big_endian -r8 -extend_source -automatic -call_shared -notransform_loops -align dcommons' )
330 set FOPTIM = ( '-O5 -fast -tune host -inline all' )
331 set NOOPTFLAGS = ( '-O0' )
332 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
333 set RMFILES = ( '*.p.out' )
334 breaksw
335 case IRIX64+mpi:
336 echo "Configuring for SGI Mips with MPI"
337 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
338 set INCLUDES = ( '-I/usr/local/mpi/include' )
339 set FC = ( 'mpif77' )
340 set LINK = ( 'mpif77' )
341 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
342 set FOPTIM = ( '-O3' )
343 set RMFILES = ( 'rii_files' )
344 breaksw
345 case IRIX64:
346 echo "Configuring for SGI Mips"
347 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
348 set INCLUDES = ( '-I/usr/local/mpi/include' )
349 set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4 -r8 -static' )
350 set FOPTIM = ( '-O3' )
351 # set NOOPTFLAGS = ( '-O0' )
352 # set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
353 # 'external_fields_load.F' )
354 set RMFILES = ( 'rii_files' )
355 breaksw
356 case o2:
357 case IRIX:
358 echo "Configuring for SGI O2 running IRIX 6.5"
359 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
360 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
361 set FOPTIM = ( '-O2' )
362 set NOOPTFLAGS = ( '-O0' )
363 breaksw
364 case o2+mpi:
365 case IRIX+mpi:
366 echo "Configuring for SGI O2 running IRIX 6.5 with MPI"
367 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
368 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
369 set FOPTIM = ( '-O2' )
370 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F' )
371 set NOOPTFLAGS = ( '-O0' )
372 set LIBS = ( '-lmpi' )
373 breaksw
374 case o2k+mpi:
375 echo "Configuring for SGI Origin2000 running IRIX 6.5"
376 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
377 set INCLUDES = ( '-I/usr/include' )
378 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
379 set FOPTIM = ( '-O2' )
380 set NOOPTFILES = ( 'calc_mom_rhs.F' )
381 set NOOPTFLAGS = ( '-O1' )
382 set LIBS = ( '-lmpi -lscs' )
383 breaksw
384 case onyx:
385 case onyx+mpi:
386 echo "Configuring for SGI ONYX running IRIX64"
387 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
388 set FFLAGS = ( '-extend_source -bytereclen -r10000 -64' )
389 set FOPTIM = ( '-O2' )
390 set NOOPTFLAGS = ( '-O0' )
391 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F' )
392 set LIBS = ( '-lmpi' )
393 breaksw
394 case SunOS:
395 set LN = ( '/usr/bin/ln -s' )
396 set CPP = ( '/usr/ccs/lib/cpp -P' )
397 set MAKEDEPEND = ( ${TOOLSDIR}/xmakedepend )
398 set DEFINES = ( ${DEFINES} '-DTARGET_SUN -DWORDLENGTH=4 -D_d=E' )
399 set FFLAGS = ( '-stackvar -explicitpar -vpara -e -u -noautopar -xtypemap=real:64,double:64,integer:32 -fsimple=0' )
400 set FOPTIM = ( '-dalign -O3 -xarch=v9' )
401 set CFLAGS = ( '-dalign -O3 -xarch=v9' )
402 set NOOPTFLAGS = ( '-dalign -O0 -xarch=v9' )
403 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F ini_vertical_grid.F ini_spherical_polar_grid.F ini_cori.F mon_printstats_rl.F mon_printstats_rs.F aim_aim2dyn.F aim_dyn2aim.F aim_aim2dyn_exchanges.F aim_external_fields_load.F aim_calc_diags.F aim_external_forcing.F aim_do_atmos_physics.F aim_write_diags.F aim_do_inphys.F ')
404 breaksw
405 case SunOS+mpi:
406 set LN = ( '/usr/bin/ln -s' )
407 set CPP = ( '/usr/ccs/lib/cpp -P' )
408 set DEFINES = ( ${DEFINES} '-DTARGET_SUN -DWORDLENGTH=4 -D_d=E' )
409 set INCLUDES = ( '-I/usr/local/mpi/include' )
410 set LIBS = ( '-L/usr/local/mpi/lib/solaris/ch_shmem -lmpi -lthread' \
411 set FFLAGS = ( '-stackvar -explicitpar -vpara -e -u -noautopar -xtypemap=real:64,double:64,integer:32 -fsimple=0' )
412 set FOPTIM = ( '-dalign -O3 -xarch=v9' )
413 set NOOPTFLAGS = ( '-dalign -O0 -xarch=v9' )
414 '-lsocket -lnsl' )
415 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F ini_vertical_grid.F ini_spherical_polar_grid.F ini_cori.F mon_printstats_rl.F mon_printstats_rs.F')
416 breaksw
417 case IRIX32:
418 echo "Configuring for SGI ONYX running IRIX64"
419 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
420 set INCLUDES = ( '-I/usr/include' )
421 set FFLAGS = ( '-extend_source -bytereclen -r10000 -64' )
422 set FOPTIM = ( '-O2' )
423 set NOOPTFLAGS = ( '-O0' )
424 set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
425 'external_fields_load.F' )
426 set LIBS = ( '-lmpi' )
427 breaksw
428 case HP-UX+mpi:
429 set FC = ( 'mpif77' )
430 set LINK = ( 'mpif77' )
431 set INCLUDES = ( '-I/opt/mpi/include' )
432 case HP-UX:
433 echo "Configuring for HP Exemplar"
434 set CPP = ( '/usr/ccs/lbin/cpp -P' )
435 set DEFINES = ( ${DEFINES} '-DTARGET_HP -DWORDLENGTH=4' )
436 set FFLAGS = ( '+es +U77 +Onoautopar +Oexemplar_model' \
437 '+Okernel_threads' )
438 set FOPTIM = ( '+O2' )
439 set NOOPTFLAGS = ( '+O0' )
440 set NOOPTFILES = ( 'barrier.F different_multiple.F' \
441 'external_fields_load.F' )
442 breaksw
443 case Linux-alpha+mpi:
444 echo "Configuring with MPI"
445 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
446 set INCLUDES = ( '-I/usr/local/include' )
447 case Linux-alpha:
448 echo "Configuring for " $platform
449 set LN = ( '/bin/ln -s' )
450 set CPP = ( '/lib/cpp -traditional -P' )
451 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
452 set FC = ( 'g77' )
453 set FFLAGS = ( ' ' )
454 if ($?IEEE) set FFLAGS = ( $FFLAGS '-ffloat-store' )
455 set FOPTIM = ( '-ffast-math -fexpensive-optimizations -fomit-frame-pointer -O3' )
456 set LINK = ( 'g77' )
457 breaksw
458 case Linux*+pgi+mpi:
459 if ($?include_jam_libs) then
460 set INCLUDES = ( '-I/usr/local/mpich-1.2.1/pgi_fortran_binding/include' )
461 set LIBS = ( '-L/usr/local/mpich-1.2.1/pgi_fortran_binding/lib/ -lfmpich -lmpich' )
462 else
463 set INCLUDES = ( '-I/usr/local/include' )
464 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
465 endif
466 case Linux*+pgi:
467 echo "Configuring for " $platform
468 set LN = ( '/bin/ln -s' )
469 set CPP = ( '/lib/cpp -traditional -P' )
470 set DEFINES = ( ${DEFINES} '-DWORDLENGTH=4' )
471 set FC = ( 'pgf77' )
472 set FFLAGS = ( '-byteswapio -r8 -Mnodclchk -Mextend' )
473 set FOPTIM = ( '-tp p6 -v -O2 -Munroll -Mvect=cachesize:512000,transform -Kieee' )
474 set LINK = ( 'pgf77' )
475 breaksw
476 case Linux*+mpi:
477 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
478 set INCLUDES = ( '-I/usr/local/include' )
479 case Linux*:
480 echo "Configuring for " $platform
481 set LN = ( '/bin/ln -s' )
482 set CPP = ( '/lib/cpp -traditional -P' )
483 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
484 set FC = ( 'g77' )
485 set FFLAGS = ( '-Wimplicit -Wunused -Wuninitialized' )
486 if ($?IEEE) set FFLAGS = ( $FFLAGS '-ffloat-store' )
487 set FOPTIM = ( '-O3 -malign-double -funroll-loops' )
488 set LINK = ( 'g77' )
489 breaksw
490 case T3E:
491 case sn6312:
492 echo "Configuring for T3E"
493 set CPP = ( '/opt/ctl/bin/cpp -P')
494 set DEFINES = ( ${DEFINES} '-DTARGET_T3E -DWORDLENGTH=4' )
495 set FC = ( 'f90' )
496 set LINK = ( 'f90' )
497 set FFLAGS = ( '-O 2,fusion' )
498 breaksw
499 case T90:
500 case sn7113:
501 echo "Configuring for T90"
502 set FC = ( 'f90' )
503 set LINK = ( 'f90' )
504 set LN = ( '/bin/ln -s' )
505 set CPP = ( '/opt/ctl/bin/cpp -N -P' )
506 set DEFINES = ( ${DEFINES} '-DTARGET_CRAY_VECTOR -DWORDLENGTH=4' )
507 set FFLAGS = ( '-m3 -Rabc -N 132')
508 set FOPTIM = ( '-O0' )
509 set NOOPTFLAGS = ( '-O0' )
510 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
511 breaksw
512 case SV1:
513 case sn3002:
514 set FC = ( 'f90' )
515 set LINK = ( 'f90' )
516 set LN = ( '/bin/ln -s' )
517 set CPP = ( '/opt/ctl/bin/cpp -N -P' )
518 set DEFINES = ( ${DEFINES} '-DTARGET_CRAY_VECTOR -DWORDLENGTH=4' )
519 set FFLAGS = ( '-m3 -Rabc -ei -eI -s cf77types -N 132')
520 set FOPTIM = ( '-O0' )
521 set NOOPTFLAGS = ( '-O0' )
522 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
523 breaksw
524 case SP3:
525 # originally from A. Biastoch, SIO.
526 echo "Configuring for IBM SP POWER3"
527 set SOURCEDIRS = ( ./ $SOURCEDIRS )
528 set LN = ( 'ln -s' )
529 set DEFINES = ( ${DEFINES} '-DTARGET_PWR3 -DTARGET_SGI -DWORDLENGTH=4' )
530 set INCLUDES = ( '-I/usr/lpp/ppe.poe/include' )
531 # set CPP = ( '/lib/cpp' )
532 set FC = ( 'mpxlf95' )
533 set LINK = ( 'mpxlf95' )
534 set FLAGS = ( '-O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
535 '-bmaxdata:0x80000000 -bloadmap:mitgcmuv.map' )
536 set FFLAGS = ( '-qfixed=132 -O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
537 '-bmaxdata:0x80000000 ' )
538 set LDFLAGS = ( '-O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
539 '-bmaxdata:0x80000000' )
540 set LIBS = ( ' -L/usr/local/apps/mass -lmass' )
541 # set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4' )
542 # set FOPTIM = ( '-O3' )
543 # set NOOPTFLAGS = ( '-O0' )
544 # set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
545 # 'external_fields_load.F' )
546 set RMFILES = ( 'rii_files' )
547 breaksw
548 default:
549 echo "Error: platform not recognized: uname -p = " $platform$USEMPI
550 exit
551 breaksw
552 endsw
553
554 ###############################################################################
555 ## ##
556 ## Everything below here should not need to be changed. Platform specific ##
557 ## changes and code specific changes should be configured above this line. ##
558 ## ##
559 ###############################################################################
560
561 # Convert lists of directories into command-line options
562 foreach inc ($INCLUDEDIRS)
563 set INCLUDES = ($INCLUDES -I$inc)
564 end
565
566 # Search for source code
567 rm -rf .links.tmp;mkdir .links.tmp
568 echo "# This section creates symbolic links" > srclinks.tmp
569 echo "" >> srclinks.tmp
570 echo -n 'SRCFILES = ' > srclist.inc
571 echo -n 'CSRCFILES = ' > csrclist.inc
572 echo -n 'HEADERFILES = ' > hlist.inc
573 foreach dr ($SOURCEDIRS $INCLUDEDIRS .)
574 set deplist=( )
575 foreach srcfile (`cd $dr; ls *.[hcF]`)
576 if (! -r .links.tmp/$srcfile) then
577 if (-f $dr/$srcfile) then
578 switch ($srcfile:e)
579 case F:
580 touch .links.tmp/$srcfile
581 set deplist=($deplist $srcfile)
582 echo ' \' >> srclist.inc
583 echo -n " " $srcfile >> srclist.inc
584 breaksw
585 case c:
586 touch .links.tmp/$srcfile
587 set deplist=($deplist $srcfile)
588 echo ' \' >> csrclist.inc
589 echo -n " " $srcfile >> csrclist.inc
590 breaksw
591 case h:
592 touch .links.tmp/$srcfile
593 set deplist=($deplist $srcfile)
594 echo ' \' >> hlist.inc
595 echo -n " " $srcfile >> hlist.inc
596 breaksw
597 endsw
598 endif
599 endif
600 end
601 if ($#deplist != 0) then
602 echo "# These files are linked from $dr" >> srclinks.tmp
603 echo $deplist':' >> srclinks.tmp
604 echo ' $(LN) '$dr'/$@ $@' >> srclinks.tmp
605 endif
606 end
607 rm -rf .links.tmp
608 echo "" >> srclist.inc
609 echo "" >> csrclist.inc
610 echo "" >> hlist.inc
611
612 set THISHOSTNAME = ( `hostname` )
613 set THISCWD = ( `pwd` )
614 set THISDATE = ( `date` )
615
616 if (-r $mfile) mv -f $mfile $mfile.bak
617 ###########################################
618 ## This is the template for the makefile ##
619 ###########################################
620 echo Creating makefile: $mfile
621 echo "# Multithreaded + multi-processing makefile for $mach" > ${mfile}
622 echo "# This makefile was generated automatically on" >> ${mfile}
623 echo "# $THISDATE" >> ${mfile}
624 echo "# by the command:" >> ${mfile}
625 echo "# ${0} $argv" >> ${mfile}
626 echo "# executed by:" >> ${mfile}
627 echo "# $USER@${THISHOSTNAME}:${THISCWD}" >> ${mfile}
628 cat >> ${mfile} <<EOF
629 #
630 # BUILDDIR : Directory where object files are written
631 # SOURCEDIRS : Directories containing the source (.F) files
632 # INCLUDEDIRS : Directories containing the header-source (.h) files
633 # EXEDIR : Directory where executable that is generated is written
634 # EXECUTABLE : Full path of executable binary
635 #
636 # CPP : C-preprocessor command
637 # INCLUDES : Directories searched for header files
638 # DEFINES : Macro definitions for CPP
639 # MAKEDEPEND : Dependency generator
640 # KPP : Special preprocessor command (specific to platform)
641 # KFLAGS : Flags for KPP
642 # FC : Fortran compiler command
643 # FFLAGS : Configuration/debugging options for FC
644 # FOPTIM : Optimization options for FC
645 # LINK : Command for link editor program
646 # LIBS : Library flags /or/ additional optimization/debugging flags
647
648 ROOTDIR = ${ROOTDIR}
649 BUILDDIR = ${BUILDDIR}
650 SOURCEDIRS = ${SOURCEDIRS}
651 INCLUDEDIRS = ${INCLUDEDIRS}
652 EXEDIR = ${EXEDIR}
653 EXECUTABLE = \$(EXEDIR)/${EXECUTABLE}
654 TOOLSDIR = ${TOOLSDIR}
655
656 EOF
657
658
659 # JAM libraries on Hyades
660 if ($?include_jam_libs) then
661 cat >> ${mfile} <<EOF
662 # extra stuff for Hyades ............................................
663 HYADES_DIR = /u/u0/cnh/jam-lib/software
664 HYADES_DIR = /u/u0/cnh/jam-lib-twoproc
665 HYADES_DIR = /usr/local/jamlib/current/dual_proc
666 WORK_DIR = \$(HYADES_DIR)
667 DEPOSIT_DIR = linux_bin
668
669 STARTXOBJDIR = startx_util/\$(DEPOSIT_DIR)
670 STARTXOBJ = \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/startx_timer.o \
671 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/startx_util.o \
672 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/client.o \
673 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/csutil.o
674
675 JAMOBJDIR = jam/\$(DEPOSIT_DIR)
676 JAMOBJ = \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_init.o \
677 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_kernel.o \
678 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_malloc.o \
679 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_vmalloc.o \
680 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_mutex.o
681
682 JAMCOBJDIR = jam_collective/\$(DEPOSIT_DIR)
683 JAMCOBJ = \$(WORK_DIR)/jam_collective/\$(DEPOSIT_DIR)/jam_collective.o
684
685 XLIBS = \$(STARTXOBJ) \$(JAMOBJ) \$(JAMCOBJ)
686
687 # ..................................................................
688
689 EOF
690 endif
691
692
693 cat >> ${mfile} <<EOF
694 # Unix ln (link)
695 LN = ${LN}
696 # C preprocessor
697 CPP = cat \$< | ${S64} | ${CPP}
698 # Dependency generator
699 MAKEDEPEND = ${MAKEDEPEND}
700 # Special preprocessor (KAP on DECs, FPP on Crays)
701 KPP = ${KPP}
702 # Fortran compiler
703 FC = ${FC}
704 # Link editor
705 LINK = ${LINK}
706
707 # Defines for CPP
708 DEFINES = ${DEFINES}
709 # Includes for CPP
710 INCLUDES = ${INCLUDES}
711 # Flags for KPP
712 KFLAGS1 = ${KFLAGS1}
713 KFLAGS2 = ${KFLAGS2}
714 # Optim./debug for FC
715 FFLAGS = ${FFLAGS}
716 FOPTIM = ${FOPTIM}
717 # Flags for CC
718 CFLAGS = ${CFLAGS}
719 # Files that should not be optimized
720 NOOPTFILES = ${NOOPTFILES}
721 NOOPTFLAGS = ${NOOPTFLAGS}
722 # Flags and libraries needed for linking
723 LIBS = ${LIBS} \$(XLIBS)
724
725 EOF
726
727 cat srclist.inc >> ${mfile}
728 cat csrclist.inc >> ${mfile}
729 cat hlist.inc >> ${mfile}
730 echo 'F77FILES = $(SRCFILES:.F=.f)' >> ${mfile}
731 echo 'OBJFILES = $(SRCFILES:.F=.o) $(CSRCFILES:.c=.o)' >> ${mfile}
732
733 rm -f srclist.inc csrclist.inc hlist.inc flist.tmp clist.tmp
734
735 cat >> ${mfile} <<EOF
736
737 .SUFFIXES:
738 .SUFFIXES: .o .f .p .F .c
739
740 all: \$(EXECUTABLE)
741 \$(EXECUTABLE): \$(OBJFILES)
742 \$(LINK) -o \$@ \$(FFLAGS) \$(FOPTIM) \$(OBJFILES) \$(LIBS)
743 depend:
744 @make links
745 \$(MAKEDEPEND) -o .f \$(DEFINES) \$(INCLUDES) \$(SRCFILES)
746
747 links: \$(SRCFILES) \$(CSRCFILES) \$(HEADERFILES)
748
749 small_f: \$(F77FILES)
750
751 output.txt: \$(EXECUTABLE)
752 @printf 'running ... '
753 @\$(EXECUTABLE) > \$@
754
755 clean:
756 -rm -rf *.o *.f *.p ${RMFILES}
757 Clean:
758 @make clean
759 @make cleanlinks
760 -rm -f Makefile.bak
761 CLEAN:
762 @make Clean
763 -find \$(EXEDIR) -name "*.meta" -exec rm {} \;
764 -find \$(EXEDIR) -name "*.data" -exec rm {} \;
765 -rm -f \$(EXECUTABLE)
766
767 makefile:
768 ${0} $argv
769 cleanlinks:
770 -find . -type l -exec rm {} \;
771
772 # The normal chain of rules is ( .F - .f - .o )
773 .F.f:
774 \$(CPP) \$(DEFINES) \$(INCLUDES) > \$@
775 .f.o:
776 \$(FC) \$(FFLAGS) \$(FOPTIM) -c \$<
777 .c.o:
778 \$(CC) \$(CFLAGS) -c \$<
779
780 # Special exceptions that use the ( .F - .p - .f - .o ) rule-chain
781 .F.p:
782 \$(CPP) \$(DEFINES) \$(INCLUDES) > \$@
783 .p.f:
784 \$(KPP) \$(KFLAGS1)\$@ \$(KFLAGS2) \$<
785 EOF
786
787 # Make list of "exceptions" that need ".p" files
788 foreach sf ($KPPFILES)
789 set fname=( ${sf:t} )
790 echo "${fname:r}.f: ${fname:r}.p" >> ${mfile}
791 end
792 foreach sf ($NOOPTFILES)
793 set fname=( ${sf:t} )
794 echo "${fname:r}.o: ${fname:r}.f" >> ${mfile}
795 echo ' $(FC) $(FFLAGS) $(NOOPTFLAGS) -c $<' >> ${mfile}
796 end
797 echo "" >> ${mfile}
798
799 # Add rules for links
800 cat srclinks.tmp >> ${mfile}
801 rm -f srclinks.tmp
802
803 echo "" >> ${mfile}
804 echo "# DO NOT DELETE" >> ${mfile}
805
806 exit

  ViewVC Help
Powered by ViewVC 1.1.22