/[MITgcm]/MITgcm/tools/genmake
ViewVC logotype

Contents of /MITgcm/tools/genmake

Parent Directory Parent Directory | Revision Log Revision Log | View Revision Graph Revision Graph


Revision 1.56.2.6.2.1 - (show annotations) (download)
Thu Aug 25 16:22:16 2005 UTC (18 years, 7 months ago) by dimitri
Branch: release1_50yr
Changes since 1.56.2.6: +15 -4 lines
adding ecco1x1 verification/global_with_CFC11 experiment

1 #!/bin/csh -f
2 #
3 # $Header: /u/gcmpack/MITgcm/tools/Attic/genmake,v 1.56.2.6 2003/05/01 00:01:16 dimitri Exp $
4 # $Name: release1_50yr $
5 #
6 # Makefile generator for MITgcm UV codes
7 # created by cnh 03/98
8 # adapted by aja 06/98
9 # modified by aja 01/00
10
11 # Default lists
12 set DISABLE = ( aim autodiff cal cost ctrl ecco exf grdchk flt seaice )
13 set DEFINES = ( )
14 set ENABLE = ( )
15 set MODS = ( )
16
17 # Grab variables/lists from .genmakerc
18 if (-r .genmakerc) source .genmakerc
19
20 # Process command-line arguments
21 set allargs=( $argv )
22 while ($#allargs)
23 set arg = $allargs[1]
24 switch ($arg)
25 case -makefile:
26 set mfile = ( Makefile )
27 breaksw
28 case -makefile=*:
29 set mfile = ( `echo $arg | sed 's/-makefile=//' `)
30 breaksw
31 case -platform:
32 case -platform=:
33 echo "To change platform you must specify one with -platform="
34 echo "eg. -platform=sparc or -platform=mips"
35 exit
36 breaksw
37 case -platform*:
38 if ($?platform) then
39 echo Option -platform=dir can only be specified once.; exit 1
40 endif
41 set platform = ( `echo $arg | sed 's/-platform=//' `)
42 breaksw
43 case -rootdir:
44 case -rootdir=:
45 echo "To specify root directory you must specify one with -rootdir=dir"
46 echo "with NO space eg. -rootdir=../../.. or -rootdir=/usr/people/joe/src"
47 exit
48 breaksw
49 case -rootdir=*:
50 if ($?ROOTDIR) then
51 echo "***" Warning: variable \$ROOTDIR is already set to $ROOTDIR
52 echo "***" Command line \"$arg\" will override this.
53 endif
54 set ROOTDIR = ( `echo $arg | sed 's/-rootdir=//' `)
55 breaksw
56 case -mods:
57 case -mods=:
58 echo "To specify an additional source directory you must specify one with -mods=dir"
59 echo "with NO space eg. -mods=../code or -mods=/usr/people/joe/src"
60 exit
61 breaksw
62 case -mods=*:
63 set MODS = ( $MODS `echo $arg | sed 's/-mods=//' | sed 's/,/ /g' `)
64 breaksw
65 case -disable:
66 case -disable=:
67 echo "To disable packages from compilation use -disable=pkg1,pkg2"
68 echo "with NO spaces eg. -disable=kpp,gmredi or -disable=all (to enable all packages)"
69 exit
70 breaksw
71 case -disable=*:
72 set DISABLE = ( $DISABLE `echo $arg | sed 's/-disable=//' | sed 's/,/ /g' `)
73 breaksw
74 case -enable:
75 case -enable=:
76 echo "To enable packages from compilation use -enable=pkg1,pkg2"
77 echo "with NO spaces eg. -enable=aim or -enable=all (to enable all packages)"
78 echo "-enable overrides -disable, ie. a package listed in both is enabled"
79 exit
80 breaksw
81 case -ieee:
82 set IEEE
83 breaksw
84 case -enable=*:
85 set ENABLE = ( $ENABLE `echo $arg | sed 's/-enable=//' | sed 's/,/ /g' `)
86 breaksw
87 case -mpi:
88 echo "Enabling MPI options"
89 set USEMPI
90 breaksw
91 case -jam:
92 set include_jam_libs
93 echo "Including paths to JAM libraries"
94 breaksw
95 case -help:
96 echo "usage: $0 [-help] [-makefile[=...]] [-platform=...] [-mpi] [-jam] [-disable=pkg1[,pkg2,...]] [-enable=pkg1[,pkg2,...]] [-mods=dir1[,dir2,...]] [-rootdir=dir]"
97 cat << EOF
98
99 $0 is used to generate the Makefile in the current directory.
100
101 Typical invocations are:
102 o from "bin": ../tools/genmake
103 o from "verification/expt/code": ../../../tools/genmake
104 o from "verification/expt/input": ../../../tools/genmake -mods=../code
105 o from a scratch directory: ~/mitgcm/tools/genmake -rootdir=~/mitgcm
106 or ~/mitgcm/tools/genmake -rootdir=~/mitgcm -mods=~/mymods
107
108 Packages (collected modules of code) can be disabled to avoid unnecessary
109 compilation of unused code. For instance if you know you will not
110 use GM/Redi, KPP and OBCS and they are appropriate turned-off in the
111 configuration:
112 .../tools/genmake -disable=gmredi,kpp,obcs
113
114 If you add some source files you can re-call the previous instance of
115 genmake with "make makefile".
116
117 genmake also reads the file .genmakerc which can be used to configure
118 options (primarily the command-line options above) for particular experiments.
119 EOF
120 exit
121 breaksw
122 default:
123 echo "Unknown command-line option: " $arg
124 echo $0 "-help to show usage"
125 exit
126 breaksw
127 endsw
128 shift allargs
129 end
130
131 # Default actions/options
132
133 # If platform wasn't specified then determine platform type of the host
134 if (! $?platform) then
135 set platform = (`uname`)
136 # This let's us distinguish between different Linux platforms
137 if ($platform == Linux) then
138 set machine = (`uname -m`)
139 set platform = ($platform'-'$machine)
140 endif
141 endif
142 # If name of makefile wasn't specified then use default "Makefile"
143 if (! $?mfile) set mfile = ( Makefile )
144
145 set mach = ( `uname -a` )
146 echo Operating system: $mach
147
148 # Directories for source, includes, binaries and executables
149 #
150 # If -rootdir wasn't specified then assume script is being run from bin
151 # but if it was supplied then we should place the executable in the build dir
152 if (! $?ROOTDIR) then
153 set pwd=`pwd`
154 if ($pwd:t == bin & -d ../model & -d ../eesupp & -d ../pkg) then
155 set ROOTDIR = ( .. )
156 endif
157 endif
158 # Scan for logical ROOTDIR
159 if (! $?ROOTDIR) then
160 foreach dr (. .. ../.. ../../.. ../../../.. ../../../../..)
161 if (-d $dr/model & -d $dr/eesupp & -d $dr/pkg) then
162 set ROOTDIR = $dr
163 echo ROOTDIR was not specified. Setting ROOTDIR = \"$ROOTDIR\"
164 break
165 endif
166 end
167 endif
168 if (! $?ROOTDIR) then
169 echo Root directory was not specified and could not be determined.
170 echo Specify the root location of the model source with -rootdir=dir
171 exit 1
172 endif
173 if (! -d $ROOTDIR) then
174 echo Root directory $ROOTDIR not found.;exit 1
175 endif
176 # If -mods wasn't specified then we will assume that we can find all the
177 # source code in the standard directories
178 if (! $?MODS) then
179 set SOURCEDIRS = ( )
180 set INCLUDEDIRS = ( )
181 else
182 set SOURCEDIRS = ( $MODS )
183 set INCLUDEDIRS = ( $MODS )
184 endif
185 if (! $?BUILDDIR) set BUILDDIR = ( . )
186 if (! -d $BUILDDIR) then
187 echo Build directory $BUILDDIR not found.;exit 1
188 endif
189 if (! $?EXEDIR) then
190 set pwd=`pwd`
191 if ($pwd:t == bin & -d ../exe & $ROOTDIR == ..) then
192 set EXEDIR = ( ../exe )
193 else
194 set EXEDIR = ( . )
195 endif
196 endif
197 if (! -d $EXEDIR) then
198 echo Executable directory $EXEDIR not found.;exit 1
199 endif
200 if (! $?TOOLSDIR) set TOOLSDIR = ( $ROOTDIR/tools )
201 if (! -d $TOOLSDIR) then
202 echo Tools directory $TOOLSDIR not found.;exit 1
203 endif
204 if (! $?EXECUTABLE) set EXECUTABLE = ( mitgcmuv )
205
206 # We have a special set of source files in eesupp/src which
207 # are generated from some template source files. We'll make them
208 # first so the appear as regular source code
209 if (-r $ROOTDIR/eesupp/src/Makefile) then
210 echo Making source files in eesupp from templates...
211 (cd $ROOTDIR/eesupp/src/; make) >& make_eesupp.errs
212 if ($status == 0) then
213 rm -f make_eesupp.errs
214 else
215 cat make_eesupp.errs
216 exit 2
217 endif
218 endif
219
220 # Now scan the standard source code tree
221 foreach dr ($SOURCEDIRS)
222 set adr=$dr
223 if (! -d $adr) then
224 echo mods directory $adr not found.; exit 1
225 endif
226 echo Adding mods dir: $adr
227 end
228 if (! $?PACKAGES) then
229 set PACKAGES=()
230 foreach pkg (`cd $ROOTDIR/pkg; find . -type d | grep -v CVS | sed 's:\./::' | grep -v "\." | sort`)
231 if (-d $ROOTDIR/pkg/$pkg) set PACKAGES=($PACKAGES $pkg)
232 end
233 endif
234 foreach dr ($PACKAGES)
235 set enable
236 foreach p ($DISABLE)
237 if ($p != 'all' & ! -d $ROOTDIR/pkg/$p) then
238 echo Specified package \"$p\" does not exist.
239 exit 1
240 endif
241 if ($dr == $p) unset enable
242 if ($p == 'all') unset enable
243 # The following allows entire trees to be disabled
244 if ($dr:h == $p) unset enable
245 if ($dr:h:h == $p) unset enable
246 if ($dr:h:h:h == $p) unset enable
247 if ($dr:h:h:h:h == $p) unset enable
248 end
249 foreach p ($ENABLE)
250 if ($dr == $p) set enable
251 end
252 if ($?enable) then
253 set adr=$ROOTDIR/pkg/$dr
254 if (! -d $adr) then
255 echo Source directory $adr not found.; exit 1
256 endif
257 echo Adding pkg dir: $adr
258 set SOURCEDIRS = ($SOURCEDIRS $adr)
259 set INCLUDEDIRS = ($INCLUDEDIRS $adr)
260 else
261 echo " *" Package \"$dr\" NOT enabled.
262 switch ($dr)
263 case mom_fluxform:
264 set DEFINES = ($DEFINES '-DDISABLE_MOM_FLUXFORM'); breaksw
265 case mom_vecinv:
266 set DEFINES = ($DEFINES '-DDISABLE_MOM_VECINV'); breaksw
267 case generic_advdiff:
268 set DEFINES = ($DEFINES '-DDISABLE_GENERIC_ADVDIFF'); breaksw
269 default:
270 breaksw
271 endsw
272 endif
273 end
274 if (! $?STANDARDDIRS) set STANDARDDIRS=(eesupp model)
275 foreach dr ($STANDARDDIRS)
276 set adr=$ROOTDIR/$dr/src
277 if (! -d $adr) then
278 echo Source directory $adr not found.; exit 1
279 endif
280 echo Adding src dir: $adr
281 set SOURCEDIRS = ($SOURCEDIRS $adr)
282 set idr = `echo $adr | sed 's/src/inc/'`
283 set INCLUDEDIRS = ($INCLUDEDIRS $idr)
284 end
285
286 # This is the generic configuration.
287 # Platform specific options are chosen below
288 set LN = ( 'ln -s' )
289 set CPP = ( '/lib/cpp -P' )
290 set S64 = ( '$(TOOLSDIR)/set64bitConst.sh' )
291 set KPP = ( )
292 set FC = ( 'f77' )
293 set LINK = ( 'f77' )
294 set MAKEDEPEND = ( 'makedepend' )
295 set INCLUDES = ( -I. )
296 set FFLAGS = ( )
297 set FOPTIM = ( )
298 set CFLAGS = ( )
299 set KFLAGS1 = ( )
300 set KFLAGS2 = ( )
301 set LIBS = ( )
302 set KPPFILES = ( )
303 set NOOPTFILES = ( )
304 set NOOPTFLAGS = ( )
305 set RMFILES = ( )
306
307 # We often want to use different compile/link options is using MPI
308 if ($?USEMPI) then
309 set USEMPI = ( '+mpi' )
310 set DEFINES = ( ${DEFINES} '-DALLOW_USE_MPI -DALWAYS_USE_MPI' )
311 else
312 set USEMPI
313 # set DEFINES = ( ${DEFINES} '-UALLOW_USE_MPI -UALWAYS_USE_MPI' )
314 endif
315
316 # Platform specific options
317 switch ($platform$USEMPI)
318 case OSF1+mpi:
319 echo "Configuring for DEC Alpha with MPI"
320 set LIBS = ( '-lfmpi -lmpi -lkmp_osfp10 -pthread' )
321 case OSF1:
322 echo "Configuring for DEC Alpha"
323 set CPP = ( '/usr/bin/cpp -P' )
324 set DEFINES = ( ${DEFINES} '-DTARGET_DEC -DWORDLENGTH=1' )
325 set KPP = ( )
326 set KPPFILES = ( )
327 set KFLAGS1 = ( )
328 set FC = ( 'f77' )
329 set FFLAGS = ( '-convert big_endian -r8 -extend_source -automatic -call_shared -notransform_loops -align dcommons' )
330 set FOPTIM = ( '-O5 -fast -tune host -inline all' )
331 set NOOPTFLAGS = ( '-O0' )
332 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
333 set RMFILES = ( '*.p.out' )
334 breaksw
335 case IRIX64+mpi:
336 echo "Configuring for SGI Mips with MPI"
337 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
338 set INCLUDES = ( '-I/usr/local/mpi/include' )
339 set FC = ( 'mpif77' )
340 set LINK = ( 'mpif77' )
341 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
342 set FOPTIM = ( '-O3' )
343 set RMFILES = ( 'rii_files' )
344 breaksw
345 case IRIX64:
346 echo "Configuring for SGI Mips"
347 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
348 set INCLUDES = ( '-I/usr/local/mpi/include' )
349 set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4 -r8 -static' )
350 set FOPTIM = ( '-O3' )
351 if ($?IEEE) set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4 -static' )
352 if ($?IEEE) set FOPTIM = ( '-O0 -OPT:IEEE_arithmetic=1 -OPT:IEEE_NaN_inf=ON' )
353 set RMFILES = ( 'rii_files' )
354 breaksw
355 case o2:
356 case IRIX:
357 echo "Configuring for SGI O2 running IRIX 6.5"
358 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
359 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
360 set FOPTIM = ( '-O2' )
361 set NOOPTFLAGS = ( '-O0' )
362 breaksw
363 case o2+mpi:
364 case IRIX+mpi:
365 echo "Configuring for SGI O2 running IRIX 6.5 with MPI"
366 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
367 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
368 set FOPTIM = ( '-O2' )
369 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F' )
370 set NOOPTFLAGS = ( '-O0' )
371 set LIBS = ( '-lmpi' )
372 breaksw
373 case o2k+mpi:
374 echo "Configuring for SGI Origin2000 running IRIX 6.5"
375 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
376 set INCLUDES = ( '-I/usr/include' )
377 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
378 set FOPTIM = ( '-O3 -OPT:Olimit=0:roundoff=3:div_split=ON:alias=typed' )
379 set LIBS = ( '-lmpi -lscs' )
380 breaksw
381 case o2k_noopt:
382 case o2k_noopt+mpi:
383 echo "Configuring for SGI Origin2000 running IRIX 6.5"
384 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
385 set INCLUDES = ( '-I/usr/include' )
386 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
387 set FOPTIM = ( '-O0' )
388 set LIBS = ( '-lmpi' )
389 breaksw
390 case ames_dbg+mpi:
391 echo "Configuring for SGI Origin2000 running IRIX 6.5"
392 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
393 set INCLUDES = ( '-I/usr/include -I/opt/mpt/mpt/usr/include' )
394 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
395 set LIBS = ( '-lmpi -lscs' )
396 set FC = ( 'f90' )
397 set LINK = ( 'f90' )
398 breaksw
399 case ames_opt+mpi:
400 echo "Configuring for SGI Origin2000 running IRIX 6.5"
401 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
402 set INCLUDES = ( '-I/usr/include -I/opt/mpt/mpt/usr/include' )
403 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
404 set FOPTIM = ( '-O3 -OPT:Olimit=0:roundoff=3:div_split=ON:alias=typed' )
405 set LIBS = ( '-lmpi -lscs' )
406 set FC = ( 'f90' )
407 set LINK = ( 'f90' )
408 breaksw
409 case o3k+mpi:
410 echo "Configuring for SGI Origin3000 running IRIX 6.5"
411 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
412 set INCLUDES = ( '-I/usr/include' )
413 set FFLAGS = ( '-64 -extend_source -bytereclen -mips4' )
414 set CFLAGS = ( '-64' )
415 set FOPTIM = ( '-O3 -OPT:Olimit=0:roundoff=3:div_split=ON' )
416 set LIBS = ( '-lmpi -lscs' )
417 breaksw
418 case columbia+mpi:
419 echo "Configuring for Columbia"
420 set CPP = ( '/lib/cpp -traditional -P' )
421 set FFLAGS = ( '-mp -132 -r8 -i4 -w95 -W0 -WB -convert big_endian -assume byterecl' )
422 set FOPTIM = ( '-O3 -align' )
423 set LIBS = ( '-L/opt/sgi/mpt/1.11-85/lib -lmpi' )
424 set FC = ( 'ifort' )
425 set LINK = ( 'ifort' )
426 set DEFINES = ( '-DWORDLENGTH=4' )
427 set INCLUDES = ( '-I/opt/sgi/mpt/1.11-85/include' )
428 breaksw
429 case onyx:
430 case onyx+mpi:
431 echo "Configuring for SGI ONYX running IRIX64"
432 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
433 set FFLAGS = ( '-extend_source -bytereclen -r10000 -64' )
434 set FOPTIM = ( '-O2' )
435 set NOOPTFLAGS = ( '-O0' )
436 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F' )
437 set LIBS = ( '-lmpi' )
438 breaksw
439 case SunOS:
440 set LN = ( '/usr/bin/ln -s' )
441 set CPP = ( '/usr/ccs/lib/cpp -P' )
442 set MAKEDEPEND = ( ${TOOLSDIR}/xmakedepend )
443 set DEFINES = ( ${DEFINES} '-DTARGET_SUN -DWORDLENGTH=4 -D_d=E' )
444 set FFLAGS = ( '-stackvar -explicitpar -vpara -e -u -noautopar -xtypemap=real:64,double:64,integer:32 -fsimple=0' )
445 set FOPTIM = ( '-dalign -O3 -xarch=v9' )
446 set CFLAGS = ( '-dalign -O3 -xarch=v9' )
447 set NOOPTFLAGS = ( '-dalign -O0 -xarch=v9' )
448 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F ini_vertical_grid.F ini_spherical_polar_grid.F ini_cori.F mon_printstats_rl.F mon_printstats_rs.F aim_aim2dyn.F aim_dyn2aim.F aim_aim2dyn_exchanges.F aim_external_fields_load.F aim_calc_diags.F aim_external_forcing.F aim_do_atmos_physics.F aim_write_diags.F aim_do_inphys.F ')
449 breaksw
450 case SunOS+mpi:
451 set LN = ( '/usr/bin/ln -s' )
452 set CPP = ( '/usr/ccs/lib/cpp -P' )
453 set DEFINES = ( ${DEFINES} '-DTARGET_SUN -DWORDLENGTH=4 -D_d=E' )
454 set INCLUDES = ( '-I/usr/local/mpi/include' )
455 set LIBS = ( '-L/usr/local/mpi/lib/solaris/ch_shmem -lmpi -lthread' \
456 set FFLAGS = ( '-stackvar -explicitpar -vpara -e -u -noautopar -xtypemap=real:64,double:64,integer:32 -fsimple=0' )
457 set FOPTIM = ( '-dalign -O3 -xarch=v9' )
458 set NOOPTFLAGS = ( '-dalign -O0 -xarch=v9' )
459 '-lsocket -lnsl' )
460 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F ini_vertical_grid.F ini_spherical_polar_grid.F ini_cori.F mon_printstats_rl.F mon_printstats_rs.F')
461 breaksw
462 case IRIX32:
463 echo "Configuring for SGI ONYX running IRIX64"
464 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
465 set INCLUDES = ( '-I/usr/include' )
466 set FFLAGS = ( '-extend_source -bytereclen -r10000 -64' )
467 set FOPTIM = ( '-O2' )
468 set NOOPTFLAGS = ( '-O0' )
469 set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
470 'external_fields_load.F' )
471 set LIBS = ( '-lmpi' )
472 breaksw
473 case HP-UX+mpi:
474 set FC = ( 'mpif77' )
475 set LINK = ( 'mpif77' )
476 set INCLUDES = ( '-I/opt/mpi/include' )
477 case HP-UX:
478 echo "Configuring for HP Exemplar"
479 set CPP = ( '/usr/ccs/lbin/cpp -P' )
480 set DEFINES = ( ${DEFINES} '-DTARGET_HP -DWORDLENGTH=4' )
481 set FFLAGS = ( '+es +U77 +Onoautopar +Oexemplar_model' \
482 '+Okernel_threads' )
483 set FOPTIM = ( '+O2' )
484 set NOOPTFLAGS = ( '+O0' )
485 set NOOPTFILES = ( 'barrier.F different_multiple.F' \
486 'external_fields_load.F' )
487 breaksw
488 case Linux-alpha+mpi:
489 echo "Configuring with MPI"
490 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
491 set INCLUDES = ( '-I/usr/local/include' )
492 case Linux-alpha:
493 echo "Configuring for " $platform
494 set LN = ( '/bin/ln -s' )
495 set CPP = ( '/lib/cpp -traditional -P' )
496 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
497 set FC = ( 'g77' )
498 set FFLAGS = ( ' ' )
499 if ($?IEEE) set FFLAGS = ( $FFLAGS '-ffloat-store' )
500 set FOPTIM = ( '-ffast-math -fexpensive-optimizations -fomit-frame-pointer -O3' )
501 set LINK = ( 'g77' )
502 breaksw
503 case Linux*+pgi+mpi:
504 if ($?include_jam_libs) then
505 set INCLUDES = ( '-I/usr/local/mpich-1.2.1/pgi_fortran_binding/include' )
506 set LIBS = ( '-L/usr/local/mpich-1.2.1/pgi_fortran_binding/lib/ -lfmpich -lmpich' )
507 else
508 set INCLUDES = ( '-I/usr/local/include' )
509 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
510 endif
511 case Linux*+pgi:
512 echo "Configuring for " $platform
513 set LN = ( '/bin/ln -s' )
514 set CPP = ( '/lib/cpp -traditional -P' )
515 set DEFINES = ( ${DEFINES} '-DWORDLENGTH=4' )
516 set FC = ( 'pgf77' )
517 set FFLAGS = ( '-byteswapio -r8 -Mnodclchk -Mextend' )
518 set FOPTIM = ( '-tp p6 -v -O2 -Munroll -Mvect=cachesize:512000,transform -Kieee' )
519 set LINK = ( 'pgf77' )
520 breaksw
521 case Linux*+mpi:
522 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
523 set INCLUDES = ( '-I/usr/local/include' )
524 case Linux*:
525 echo "Configuring for " $platform
526 set LN = ( '/bin/ln -s' )
527 set CPP = ( '/lib/cpp -traditional -P' )
528 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
529 set FC = ( 'g77' )
530 set FFLAGS = ( '-Wimplicit -Wunused -Wuninitialized' )
531 if ($?IEEE) set FFLAGS = ( $FFLAGS '-ffloat-store' )
532 set FOPTIM = ( '-O3 -malign-double -funroll-loops' )
533 set LINK = ( 'g77' )
534 breaksw
535 case T3E:
536 case sn6312:
537 echo "Configuring for T3E"
538 set CPP = ( '/opt/ctl/bin/cpp -P')
539 set DEFINES = ( ${DEFINES} '-DTARGET_T3E -DWORDLENGTH=4' )
540 set FC = ( 'f90' )
541 set LINK = ( 'f90' )
542 set FFLAGS = ( '-O 2,fusion' )
543 breaksw
544 case T90:
545 case sn7113:
546 echo "Configuring for T90"
547 set FC = ( 'f90' )
548 set LINK = ( 'f90' )
549 set LN = ( '/bin/ln -s' )
550 set CPP = ( '/opt/ctl/bin/cpp -N -P' )
551 set DEFINES = ( ${DEFINES} '-DTARGET_CRAY_VECTOR -DWORDLENGTH=4' )
552 set FFLAGS = ( '-m3 -Rabc -N 132')
553 set FOPTIM = ( '-O0' )
554 set NOOPTFLAGS = ( '-O0' )
555 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
556 breaksw
557 case SV1:
558 case sn3002:
559 set FC = ( 'f90' )
560 set LINK = ( 'f90' )
561 set LN = ( '/bin/ln -s' )
562 set CPP = ( '/opt/ctl/bin/cpp -N -P' )
563 set DEFINES = ( ${DEFINES} '-DTARGET_CRAY_VECTOR -DWORDLENGTH=4' )
564 set FFLAGS = ( '-m3 -Rabc -ei -eI -s cf77types -N 132')
565 set FOPTIM = ( '-O0' )
566 set NOOPTFLAGS = ( '-O0' )
567 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
568 breaksw
569 case SP3:
570 # originally from A. Biastoch, SIO.
571 echo "Configuring for IBM SP POWER3"
572 set SOURCEDIRS = ( ./ $SOURCEDIRS )
573 set LN = ( 'ln -s' )
574 set DEFINES = ( ${DEFINES} '-DTARGET_PWR3 -DTARGET_SGI -DWORDLENGTH=4' )
575 set INCLUDES = ( '-I/usr/lpp/ppe.poe/include' )
576 # set CPP = ( '/lib/cpp' )
577 set FC = ( 'mpxlf95' )
578 set LINK = ( 'mpxlf95' )
579 set FLAGS = ( '-O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
580 '-bmaxdata:0x80000000 -bloadmap:mitgcmuv.map' )
581 set FFLAGS = ( '-qfixed=132 -O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
582 '-bmaxdata:0x80000000 ' )
583 set LDFLAGS = ( '-O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
584 '-bmaxdata:0x80000000' )
585 set LIBS = ( ' -L/usr/local/apps/mass -lmass' )
586 # set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4' )
587 # set FOPTIM = ( '-O3' )
588 # set NOOPTFLAGS = ( '-O0' )
589 # set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
590 # 'external_fields_load.F' )
591 set RMFILES = ( 'rii_files' )
592 breaksw
593 default:
594 echo "Error: platform not recognized: uname -p = " $platform$USEMPI
595 exit
596 breaksw
597 endsw
598
599 ###############################################################################
600 ## ##
601 ## Everything below here should not need to be changed. Platform specific ##
602 ## changes and code specific changes should be configured above this line. ##
603 ## ##
604 ###############################################################################
605
606 # Convert lists of directories into command-line options
607 foreach inc ($INCLUDEDIRS)
608 set INCLUDES = ($INCLUDES -I$inc)
609 end
610
611 # Search for source code
612 rm -rf .links.tmp;mkdir .links.tmp
613 echo "# This section creates symbolic links" > srclinks.tmp
614 echo "" >> srclinks.tmp
615 echo -n 'SRCFILES = ' > srclist.inc
616 echo -n 'CSRCFILES = ' > csrclist.inc
617 echo -n 'HEADERFILES = ' > hlist.inc
618 foreach dr ($SOURCEDIRS $INCLUDEDIRS .)
619 set deplist=( )
620 foreach srcfile (`cd $dr; ls *.[hcF]`)
621 if (! -r .links.tmp/$srcfile) then
622 if (-f $dr/$srcfile) then
623 switch ($srcfile:e)
624 case F:
625 touch .links.tmp/$srcfile
626 set deplist=($deplist $srcfile)
627 echo ' \' >> srclist.inc
628 echo -n " " $srcfile >> srclist.inc
629 breaksw
630 case c:
631 touch .links.tmp/$srcfile
632 set deplist=($deplist $srcfile)
633 echo ' \' >> csrclist.inc
634 echo -n " " $srcfile >> csrclist.inc
635 breaksw
636 case h:
637 touch .links.tmp/$srcfile
638 set deplist=($deplist $srcfile)
639 echo ' \' >> hlist.inc
640 echo -n " " $srcfile >> hlist.inc
641 breaksw
642 endsw
643 endif
644 endif
645 end
646 if ($#deplist != 0) then
647 echo "# These files are linked from $dr" >> srclinks.tmp
648 echo $deplist':' >> srclinks.tmp
649 echo ' $(LN) '$dr'/$@ $@' >> srclinks.tmp
650 endif
651 end
652 rm -rf .links.tmp
653 echo "" >> srclist.inc
654 echo "" >> csrclist.inc
655 echo "" >> hlist.inc
656
657 set THISHOSTNAME = ( `hostname` )
658 set THISCWD = ( `pwd` )
659 set THISDATE = ( `date` )
660
661 if (-r $mfile) mv -f $mfile $mfile.bak
662 ###########################################
663 ## This is the template for the makefile ##
664 ###########################################
665 echo Creating makefile: $mfile
666 echo "# Multithreaded + multi-processing makefile for $mach" > ${mfile}
667 echo "# This makefile was generated automatically on" >> ${mfile}
668 echo "# $THISDATE" >> ${mfile}
669 echo "# by the command:" >> ${mfile}
670 echo "# ${0} $argv" >> ${mfile}
671 echo "# executed by:" >> ${mfile}
672 echo "# $USER@${THISHOSTNAME}:${THISCWD}" >> ${mfile}
673 cat >> ${mfile} <<EOF
674 #
675 # BUILDDIR : Directory where object files are written
676 # SOURCEDIRS : Directories containing the source (.F) files
677 # INCLUDEDIRS : Directories containing the header-source (.h) files
678 # EXEDIR : Directory where executable that is generated is written
679 # EXECUTABLE : Full path of executable binary
680 #
681 # CPP : C-preprocessor command
682 # INCLUDES : Directories searched for header files
683 # DEFINES : Macro definitions for CPP
684 # MAKEDEPEND : Dependency generator
685 # KPP : Special preprocessor command (specific to platform)
686 # KFLAGS : Flags for KPP
687 # FC : Fortran compiler command
688 # FFLAGS : Configuration/debugging options for FC
689 # FOPTIM : Optimization options for FC
690 # LINK : Command for link editor program
691 # LIBS : Library flags /or/ additional optimization/debugging flags
692
693 ROOTDIR = ${ROOTDIR}
694 BUILDDIR = ${BUILDDIR}
695 SOURCEDIRS = ${SOURCEDIRS}
696 INCLUDEDIRS = ${INCLUDEDIRS}
697 EXEDIR = ${EXEDIR}
698 EXECUTABLE = \$(EXEDIR)/${EXECUTABLE}
699 TOOLSDIR = ${TOOLSDIR}
700
701 EOF
702
703
704 # JAM libraries on Hyades
705 if ($?include_jam_libs) then
706 cat >> ${mfile} <<EOF
707 # extra stuff for Hyades ............................................
708 HYADES_DIR = /u/u0/cnh/jam-lib/software
709 HYADES_DIR = /u/u0/cnh/jam-lib-twoproc
710 HYADES_DIR = /usr/local/jamlib/current/dual_proc
711 WORK_DIR = \$(HYADES_DIR)
712 DEPOSIT_DIR = linux_bin
713
714 STARTXOBJDIR = startx_util/\$(DEPOSIT_DIR)
715 STARTXOBJ = \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/startx_timer.o \
716 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/startx_util.o \
717 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/client.o \
718 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/csutil.o
719
720 JAMOBJDIR = jam/\$(DEPOSIT_DIR)
721 JAMOBJ = \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_init.o \
722 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_kernel.o \
723 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_malloc.o \
724 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_vmalloc.o \
725 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_mutex.o
726
727 JAMCOBJDIR = jam_collective/\$(DEPOSIT_DIR)
728 JAMCOBJ = \$(WORK_DIR)/jam_collective/\$(DEPOSIT_DIR)/jam_collective.o
729
730 XLIBS = \$(STARTXOBJ) \$(JAMOBJ) \$(JAMCOBJ)
731
732 # ..................................................................
733
734 EOF
735 endif
736
737
738 cat >> ${mfile} <<EOF
739 # Unix ln (link)
740 LN = ${LN}
741 # C preprocessor
742 CPP = cat \$< | ${S64} | ${CPP}
743 # Dependency generator
744 MAKEDEPEND = ${MAKEDEPEND}
745 # Special preprocessor (KAP on DECs, FPP on Crays)
746 KPP = ${KPP}
747 # Fortran compiler
748 FC = ${FC}
749 # Link editor
750 LINK = ${LINK}
751
752 # Defines for CPP
753 DEFINES = ${DEFINES}
754 # Includes for CPP
755 INCLUDES = ${INCLUDES}
756 # Flags for KPP
757 KFLAGS1 = ${KFLAGS1}
758 KFLAGS2 = ${KFLAGS2}
759 # Optim./debug for FC
760 FFLAGS = ${FFLAGS}
761 FOPTIM = ${FOPTIM}
762 # Flags for CC
763 CFLAGS = ${CFLAGS}
764 # Files that should not be optimized
765 NOOPTFILES = ${NOOPTFILES}
766 NOOPTFLAGS = ${NOOPTFLAGS}
767 # Flags and libraries needed for linking
768 LIBS = ${LIBS} \$(XLIBS)
769
770 EOF
771
772 cat srclist.inc >> ${mfile}
773 cat csrclist.inc >> ${mfile}
774 cat hlist.inc >> ${mfile}
775 echo 'F77FILES = $(SRCFILES:.F=.f)' >> ${mfile}
776 echo 'OBJFILES = $(SRCFILES:.F=.o) $(CSRCFILES:.c=.o)' >> ${mfile}
777
778 rm -f srclist.inc csrclist.inc hlist.inc flist.tmp clist.tmp
779
780 cat >> ${mfile} <<EOF
781
782 .SUFFIXES:
783 .SUFFIXES: .o .f .p .F .c
784
785 all: \$(EXECUTABLE)
786 \$(EXECUTABLE): \$(OBJFILES)
787 \$(LINK) -o \$@ \$(FFLAGS) \$(FOPTIM) \$(OBJFILES) \$(LIBS)
788 depend:
789 @make links
790 \$(MAKEDEPEND) -o .f \$(DEFINES) \$(INCLUDES) \$(SRCFILES)
791
792 links: \$(SRCFILES) \$(CSRCFILES) \$(HEADERFILES)
793
794 small_f: \$(F77FILES)
795
796 output.txt: \$(EXECUTABLE)
797 @printf 'running ... '
798 @\$(EXECUTABLE) > \$@
799
800 clean:
801 -rm -rf *.o *.f *.p ${RMFILES}
802 Clean:
803 @make clean
804 @make cleanlinks
805 -rm -f Makefile.bak
806 CLEAN:
807 @make Clean
808 -find \$(EXEDIR) -name "*.meta" -exec rm {} \;
809 -find \$(EXEDIR) -name "*.data" -exec rm {} \;
810 -rm -f \$(EXECUTABLE)
811
812 makefile:
813 ${0} $argv
814 cleanlinks:
815 -find . -type l -exec rm {} \;
816
817 # The normal chain of rules is ( .F - .f - .o )
818 .F.f:
819 \$(CPP) \$(DEFINES) \$(INCLUDES) > \$@
820 .f.o:
821 \$(FC) \$(FFLAGS) \$(FOPTIM) -c \$<
822 .c.o:
823 \$(CC) \$(CFLAGS) -c \$<
824
825 # Special exceptions that use the ( .F - .p - .f - .o ) rule-chain
826 .F.p:
827 \$(CPP) \$(DEFINES) \$(INCLUDES) > \$@
828 .p.f:
829 \$(KPP) \$(KFLAGS1)\$@ \$(KFLAGS2) \$<
830 EOF
831
832 # Make list of "exceptions" that need ".p" files
833 foreach sf ($KPPFILES)
834 set fname=( ${sf:t} )
835 echo "${fname:r}.f: ${fname:r}.p" >> ${mfile}
836 end
837 foreach sf ($NOOPTFILES)
838 set fname=( ${sf:t} )
839 echo "${fname:r}.o: ${fname:r}.f" >> ${mfile}
840 echo ' $(FC) $(FFLAGS) $(NOOPTFLAGS) -c $<' >> ${mfile}
841 end
842 echo "" >> ${mfile}
843
844 # Add rules for links
845 cat srclinks.tmp >> ${mfile}
846 rm -f srclinks.tmp
847
848 echo "" >> ${mfile}
849 echo "# DO NOT DELETE" >> ${mfile}
850
851 exit

  ViewVC Help
Powered by ViewVC 1.1.22