/[MITgcm]/MITgcm/tools/genmake
ViewVC logotype

Contents of /MITgcm/tools/genmake

Parent Directory Parent Directory | Revision Log Revision Log | View Revision Graph Revision Graph


Revision 1.56.2.5 - (show annotations) (download)
Fri Feb 7 08:54:52 2003 UTC (21 years, 1 month ago) by dimitri
Branch: release1
CVS Tags: release1_p12, release1_p13, release1_p13_pre, release1_p12_pre
Changes since 1.56.2.4: +20 -1 lines
Modified File tools/genmake

1 #!/bin/csh -f
2 #
3 # $Header: /u/gcmpack/MITgcm/tools/genmake,v 1.56.2.4 2002/12/05 08:06:18 dimitri Exp $
4 # $Name: $
5 #
6 # Makefile generator for MITgcm UV codes
7 # created by cnh 03/98
8 # adapted by aja 06/98
9 # modified by aja 01/00
10
11 # Default lists
12 set DISABLE = ( aim autodiff cal cost ctrl ecco exf grdchk flt seaice )
13 set DEFINES = ( )
14 set ENABLE = ( )
15 set MODS = ( )
16
17 # Grab variables/lists from .genmakerc
18 if (-r .genmakerc) source .genmakerc
19
20 # Process command-line arguments
21 set allargs=( $argv )
22 while ($#allargs)
23 set arg = $allargs[1]
24 switch ($arg)
25 case -makefile:
26 set mfile = ( Makefile )
27 breaksw
28 case -makefile=*:
29 set mfile = ( `echo $arg | sed 's/-makefile=//' `)
30 breaksw
31 case -platform:
32 case -platform=:
33 echo "To change platform you must specify one with -platform="
34 echo "eg. -platform=sparc or -platform=mips"
35 exit
36 breaksw
37 case -platform*:
38 if ($?platform) then
39 echo Option -platform=dir can only be specified once.; exit 1
40 endif
41 set platform = ( `echo $arg | sed 's/-platform=//' `)
42 breaksw
43 case -rootdir:
44 case -rootdir=:
45 echo "To specify root directory you must specify one with -rootdir=dir"
46 echo "with NO space eg. -rootdir=../../.. or -rootdir=/usr/people/joe/src"
47 exit
48 breaksw
49 case -rootdir=*:
50 if ($?ROOTDIR) then
51 echo "***" Warning: variable \$ROOTDIR is already set to $ROOTDIR
52 echo "***" Command line \"$arg\" will override this.
53 endif
54 set ROOTDIR = ( `echo $arg | sed 's/-rootdir=//' `)
55 breaksw
56 case -mods:
57 case -mods=:
58 echo "To specify an additional source directory you must specify one with -mods=dir"
59 echo "with NO space eg. -mods=../code or -mods=/usr/people/joe/src"
60 exit
61 breaksw
62 case -mods=*:
63 set MODS = ( $MODS `echo $arg | sed 's/-mods=//' | sed 's/,/ /g' `)
64 breaksw
65 case -disable:
66 case -disable=:
67 echo "To disable packages from compilation use -disable=pkg1,pkg2"
68 echo "with NO spaces eg. -disable=kpp,gmredi or -disable=all (to enable all packages)"
69 exit
70 breaksw
71 case -disable=*:
72 set DISABLE = ( $DISABLE `echo $arg | sed 's/-disable=//' | sed 's/,/ /g' `)
73 breaksw
74 case -enable:
75 case -enable=:
76 echo "To enable packages from compilation use -enable=pkg1,pkg2"
77 echo "with NO spaces eg. -enable=aim or -enable=all (to enable all packages)"
78 echo "-enable overrides -disable, ie. a package listed in both is enabled"
79 exit
80 breaksw
81 case -ieee:
82 set IEEE
83 breaksw
84 case -enable=*:
85 set ENABLE = ( $ENABLE `echo $arg | sed 's/-enable=//' | sed 's/,/ /g' `)
86 breaksw
87 case -mpi:
88 echo "Enabling MPI options"
89 set USEMPI
90 breaksw
91 case -jam:
92 set include_jam_libs
93 echo "Including paths to JAM libraries"
94 breaksw
95 case -help:
96 echo "usage: $0 [-help] [-makefile[=...]] [-platform=...] [-mpi] [-jam] [-disable=pkg1[,pkg2,...]] [-enable=pkg1[,pkg2,...]] [-mods=dir1[,dir2,...]] [-rootdir=dir]"
97 cat << EOF
98
99 $0 is used to generate the Makefile in the current directory.
100
101 Typical invocations are:
102 o from "bin": ../tools/genmake
103 o from "verification/expt/code": ../../../tools/genmake
104 o from "verification/expt/input": ../../../tools/genmake -mods=../code
105 o from a scratch directory: ~/mitgcm/tools/genmake -rootdir=~/mitgcm
106 or ~/mitgcm/tools/genmake -rootdir=~/mitgcm -mods=~/mymods
107
108 Packages (collected modules of code) can be disabled to avoid unnecessary
109 compilation of unused code. For instance if you know you will not
110 use GM/Redi, KPP and OBCS and they are appropriate turned-off in the
111 configuration:
112 .../tools/genmake -disable=gmredi,kpp,obcs
113
114 If you add some source files you can re-call the previous instance of
115 genmake with "make makefile".
116
117 genmake also reads the file .genmakerc which can be used to configure
118 options (primarily the command-line options above) for particular experiments.
119 EOF
120 exit
121 breaksw
122 default:
123 echo "Unknown command-line option: " $arg
124 echo $0 "-help to show usage"
125 exit
126 breaksw
127 endsw
128 shift allargs
129 end
130
131 # Default actions/options
132
133 # If platform wasn't specified then determine platform type of the host
134 if (! $?platform) then
135 set platform = (`uname`)
136 # This let's us distinguish between different Linux platforms
137 if ($platform == Linux) then
138 set machine = (`uname -m`)
139 set platform = ($platform'-'$machine)
140 endif
141 endif
142 # If name of makefile wasn't specified then use default "Makefile"
143 if (! $?mfile) set mfile = ( Makefile )
144
145 set mach = ( `uname -a` )
146 echo Operating system: $mach
147
148 # Directories for source, includes, binaries and executables
149 #
150 # If -rootdir wasn't specified then assume script is being run from bin
151 # but if it was supplied then we should place the executable in the build dir
152 if (! $?ROOTDIR) then
153 set pwd=`pwd`
154 if ($pwd:t == bin & -d ../model & -d ../eesupp & -d ../pkg) then
155 set ROOTDIR = ( .. )
156 endif
157 endif
158 # Scan for logical ROOTDIR
159 if (! $?ROOTDIR) then
160 foreach dr (. .. ../.. ../../.. ../../../.. ../../../../..)
161 if (-d $dr/model & -d $dr/eesupp & -d $dr/pkg) then
162 set ROOTDIR = $dr
163 echo ROOTDIR was not specified. Setting ROOTDIR = \"$ROOTDIR\"
164 break
165 endif
166 end
167 endif
168 if (! $?ROOTDIR) then
169 echo Root directory was not specified and could not be determined.
170 echo Specify the root location of the model source with -rootdir=dir
171 exit 1
172 endif
173 if (! -d $ROOTDIR) then
174 echo Root directory $ROOTDIR not found.;exit 1
175 endif
176 # If -mods wasn't specified then we will assume that we can find all the
177 # source code in the standard directories
178 if (! $?MODS) then
179 set SOURCEDIRS = ( )
180 set INCLUDEDIRS = ( )
181 else
182 set SOURCEDIRS = ( $MODS )
183 set INCLUDEDIRS = ( $MODS )
184 endif
185 if (! $?BUILDDIR) set BUILDDIR = ( . )
186 if (! -d $BUILDDIR) then
187 echo Build directory $BUILDDIR not found.;exit 1
188 endif
189 if (! $?EXEDIR) then
190 set pwd=`pwd`
191 if ($pwd:t == bin & -d ../exe & $ROOTDIR == ..) then
192 set EXEDIR = ( ../exe )
193 else
194 set EXEDIR = ( . )
195 endif
196 endif
197 if (! -d $EXEDIR) then
198 echo Executable directory $EXEDIR not found.;exit 1
199 endif
200 if (! $?TOOLSDIR) set TOOLSDIR = ( $ROOTDIR/tools )
201 if (! -d $TOOLSDIR) then
202 echo Tools directory $TOOLSDIR not found.;exit 1
203 endif
204 if (! $?EXECUTABLE) set EXECUTABLE = ( mitgcmuv )
205
206 # We have a special set of source files in eesupp/src which
207 # are generated from some template source files. We'll make them
208 # first so the appear as regular source code
209 if (-r $ROOTDIR/eesupp/src/Makefile) then
210 echo Making source files in eesupp from templates...
211 (cd $ROOTDIR/eesupp/src/; make) >& make_eesupp.errs
212 if ($status == 0) then
213 rm -f make_eesupp.errs
214 else
215 cat make_eesupp.errs
216 exit 2
217 endif
218 endif
219
220 # Now scan the standard source code tree
221 foreach dr ($SOURCEDIRS)
222 set adr=$dr
223 if (! -d $adr) then
224 echo mods directory $adr not found.; exit 1
225 endif
226 echo Adding mods dir: $adr
227 end
228 if (! $?PACKAGES) then
229 set PACKAGES=()
230 foreach pkg (`cd $ROOTDIR/pkg; find . -type d | grep -v CVS | sed 's:\./::' | grep -v "\." | sort`)
231 if (-d $ROOTDIR/pkg/$pkg) set PACKAGES=($PACKAGES $pkg)
232 end
233 endif
234 foreach dr ($PACKAGES)
235 set enable
236 foreach p ($DISABLE)
237 if ($p != 'all' & ! -d $ROOTDIR/pkg/$p) then
238 echo Specified package \"$p\" does not exist.
239 exit 1
240 endif
241 if ($dr == $p) unset enable
242 if ($p == 'all') unset enable
243 # The following allows entire trees to be disabled
244 if ($dr:h == $p) unset enable
245 if ($dr:h:h == $p) unset enable
246 if ($dr:h:h:h == $p) unset enable
247 if ($dr:h:h:h:h == $p) unset enable
248 end
249 foreach p ($ENABLE)
250 if ($dr == $p) set enable
251 end
252 if ($?enable) then
253 set adr=$ROOTDIR/pkg/$dr
254 if (! -d $adr) then
255 echo Source directory $adr not found.; exit 1
256 endif
257 echo Adding pkg dir: $adr
258 set SOURCEDIRS = ($SOURCEDIRS $adr)
259 set INCLUDEDIRS = ($INCLUDEDIRS $adr)
260 else
261 echo " *" Package \"$dr\" NOT enabled.
262 switch ($dr)
263 case mom_fluxform:
264 set DEFINES = ($DEFINES '-DDISABLE_MOM_FLUXFORM'); breaksw
265 case mom_vecinv:
266 set DEFINES = ($DEFINES '-DDISABLE_MOM_VECINV'); breaksw
267 case generic_advdiff:
268 set DEFINES = ($DEFINES '-DDISABLE_GENERIC_ADVDIFF'); breaksw
269 default:
270 breaksw
271 endsw
272 endif
273 end
274 if (! $?STANDARDDIRS) set STANDARDDIRS=(eesupp model)
275 foreach dr ($STANDARDDIRS)
276 set adr=$ROOTDIR/$dr/src
277 if (! -d $adr) then
278 echo Source directory $adr not found.; exit 1
279 endif
280 echo Adding src dir: $adr
281 set SOURCEDIRS = ($SOURCEDIRS $adr)
282 set idr = `echo $adr | sed 's/src/inc/'`
283 set INCLUDEDIRS = ($INCLUDEDIRS $idr)
284 end
285
286 # This is the generic configuration.
287 # Platform specific options are chosen below
288 set LN = ( 'ln -s' )
289 set CPP = ( '/lib/cpp -P' )
290 set S64 = ( '$(TOOLSDIR)/set64bitConst.sh' )
291 set KPP = ( )
292 set FC = ( 'f77' )
293 set LINK = ( 'f77' )
294 set MAKEDEPEND = ( 'makedepend' )
295 set INCLUDES = ( -I. )
296 set FFLAGS = ( )
297 set FOPTIM = ( )
298 set CFLAGS = ( )
299 set KFLAGS1 = ( )
300 set KFLAGS2 = ( )
301 set LIBS = ( )
302 set KPPFILES = ( )
303 set NOOPTFILES = ( )
304 set NOOPTFLAGS = ( )
305 set RMFILES = ( )
306
307 # We often want to use different compile/link options is using MPI
308 if ($?USEMPI) then
309 set USEMPI = ( '+mpi' )
310 set DEFINES = ( ${DEFINES} '-DALLOW_USE_MPI -DALWAYS_USE_MPI' )
311 else
312 set USEMPI
313 # set DEFINES = ( ${DEFINES} '-UALLOW_USE_MPI -UALWAYS_USE_MPI' )
314 endif
315
316 # Platform specific options
317 switch ($platform$USEMPI)
318 case OSF1+mpi:
319 echo "Configuring for DEC Alpha with MPI"
320 set LIBS = ( '-lfmpi -lmpi -lkmp_osfp10 -pthread' )
321 case OSF1:
322 echo "Configuring for DEC Alpha"
323 set CPP = ( '/usr/bin/cpp -P' )
324 set DEFINES = ( ${DEFINES} '-DTARGET_DEC -DWORDLENGTH=1' )
325 set KPP = ( )
326 set KPPFILES = ( )
327 set KFLAGS1 = ( )
328 set FC = ( 'f77' )
329 set FFLAGS = ( '-convert big_endian -r8 -extend_source -automatic -call_shared -notransform_loops -align dcommons' )
330 set FOPTIM = ( '-O5 -fast -tune host -inline all' )
331 set NOOPTFLAGS = ( '-O0' )
332 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
333 set RMFILES = ( '*.p.out' )
334 breaksw
335 case IRIX64+mpi:
336 echo "Configuring for SGI Mips with MPI"
337 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
338 set INCLUDES = ( '-I/usr/local/mpi/include' )
339 set FC = ( 'mpif77' )
340 set LINK = ( 'mpif77' )
341 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
342 set FOPTIM = ( '-O3' )
343 set RMFILES = ( 'rii_files' )
344 breaksw
345 case IRIX64:
346 echo "Configuring for SGI Mips"
347 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
348 set INCLUDES = ( '-I/usr/local/mpi/include' )
349 set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4 -r8 -static' )
350 set FOPTIM = ( '-O3' )
351 if ($?IEEE) set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4 -static' )
352 if ($?IEEE) set FOPTIM = ( '-O0 -OPT:IEEE_arithmetic=1 -OPT:IEEE_NaN_inf=ON' )
353 set RMFILES = ( 'rii_files' )
354 breaksw
355 case o2:
356 case IRIX:
357 echo "Configuring for SGI O2 running IRIX 6.5"
358 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
359 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
360 set FOPTIM = ( '-O2' )
361 set NOOPTFLAGS = ( '-O0' )
362 breaksw
363 case o2+mpi:
364 case IRIX+mpi:
365 echo "Configuring for SGI O2 running IRIX 6.5 with MPI"
366 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
367 set FFLAGS = ( '-extend_source -bytereclen -r10000 -mips4' )
368 set FOPTIM = ( '-O2' )
369 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F' )
370 set NOOPTFLAGS = ( '-O0' )
371 set LIBS = ( '-lmpi' )
372 breaksw
373 case o2k+mpi:
374 echo "Configuring for SGI Origin2000 running IRIX 6.5"
375 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
376 set INCLUDES = ( '-I/usr/include' )
377 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
378 set FOPTIM = ( '-O3 -OPT:Olimit=0:roundoff=3:div_split=ON:alias=typed' )
379 set LIBS = ( '-lmpi -lscs' )
380 breaksw
381 case o2k_noopt:
382 case o2k_noopt+mpi:
383 echo "Configuring for SGI Origin2000 running IRIX 6.5"
384 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
385 set INCLUDES = ( '-I/usr/include' )
386 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
387 set FOPTIM = ( '-O0' )
388 set LIBS = ( '-lmpi' )
389 breaksw
390 case ames_dbg+mpi:
391 echo "Configuring for SGI Origin2000 running IRIX 6.5"
392 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
393 set INCLUDES = ( '-I/usr/include -I/opt/mpt/1.6.1.beta/usr/include' )
394 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
395 set LIBS = ( '-lmpi -lscs' )
396 set FC = ( 'f90' )
397 set LINK = ( 'f90' )
398 breaksw
399 case ames_opt+mpi:
400 echo "Configuring for SGI Origin2000 running IRIX 6.5"
401 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
402 set INCLUDES = ( '-I/usr/include -I/opt/mpt/1.6.1.beta/usr/include' )
403 set FFLAGS = ( '-n32 -extend_source -bytereclen' )
404 set FOPTIM = ( '-O3 -OPT:Olimit=0:roundoff=3:div_split=ON:alias=typed' )
405 set LIBS = ( '-lmpi -lscs' )
406 set FC = ( 'f90' )
407 set LINK = ( 'f90' )
408 breaksw
409 case onyx:
410 case onyx+mpi:
411 echo "Configuring for SGI ONYX running IRIX64"
412 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
413 set FFLAGS = ( '-extend_source -bytereclen -r10000 -64' )
414 set FOPTIM = ( '-O2' )
415 set NOOPTFLAGS = ( '-O0' )
416 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F' )
417 set LIBS = ( '-lmpi' )
418 breaksw
419 case SunOS:
420 set LN = ( '/usr/bin/ln -s' )
421 set CPP = ( '/usr/ccs/lib/cpp -P' )
422 set MAKEDEPEND = ( ${TOOLSDIR}/xmakedepend )
423 set DEFINES = ( ${DEFINES} '-DTARGET_SUN -DWORDLENGTH=4 -D_d=E' )
424 set FFLAGS = ( '-stackvar -explicitpar -vpara -e -u -noautopar -xtypemap=real:64,double:64,integer:32 -fsimple=0' )
425 set FOPTIM = ( '-dalign -O3 -xarch=v9' )
426 set CFLAGS = ( '-dalign -O3 -xarch=v9' )
427 set NOOPTFLAGS = ( '-dalign -O0 -xarch=v9' )
428 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F ini_vertical_grid.F ini_spherical_polar_grid.F ini_cori.F mon_printstats_rl.F mon_printstats_rs.F aim_aim2dyn.F aim_dyn2aim.F aim_aim2dyn_exchanges.F aim_external_fields_load.F aim_calc_diags.F aim_external_forcing.F aim_do_atmos_physics.F aim_write_diags.F aim_do_inphys.F ')
429 breaksw
430 case SunOS+mpi:
431 set LN = ( '/usr/bin/ln -s' )
432 set CPP = ( '/usr/ccs/lib/cpp -P' )
433 set DEFINES = ( ${DEFINES} '-DTARGET_SUN -DWORDLENGTH=4 -D_d=E' )
434 set INCLUDES = ( '-I/usr/local/mpi/include' )
435 set LIBS = ( '-L/usr/local/mpi/lib/solaris/ch_shmem -lmpi -lthread' \
436 set FFLAGS = ( '-stackvar -explicitpar -vpara -e -u -noautopar -xtypemap=real:64,double:64,integer:32 -fsimple=0' )
437 set FOPTIM = ( '-dalign -O3 -xarch=v9' )
438 set NOOPTFLAGS = ( '-dalign -O0 -xarch=v9' )
439 '-lsocket -lnsl' )
440 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F ini_vertical_grid.F ini_spherical_polar_grid.F ini_cori.F mon_printstats_rl.F mon_printstats_rs.F')
441 breaksw
442 case IRIX32:
443 echo "Configuring for SGI ONYX running IRIX64"
444 set DEFINES = ( ${DEFINES} '-DTARGET_SGI -DWORDLENGTH=4' )
445 set INCLUDES = ( '-I/usr/include' )
446 set FFLAGS = ( '-extend_source -bytereclen -r10000 -64' )
447 set FOPTIM = ( '-O2' )
448 set NOOPTFLAGS = ( '-O0' )
449 set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
450 'external_fields_load.F' )
451 set LIBS = ( '-lmpi' )
452 breaksw
453 case HP-UX+mpi:
454 set FC = ( 'mpif77' )
455 set LINK = ( 'mpif77' )
456 set INCLUDES = ( '-I/opt/mpi/include' )
457 case HP-UX:
458 echo "Configuring for HP Exemplar"
459 set CPP = ( '/usr/ccs/lbin/cpp -P' )
460 set DEFINES = ( ${DEFINES} '-DTARGET_HP -DWORDLENGTH=4' )
461 set FFLAGS = ( '+es +U77 +Onoautopar +Oexemplar_model' \
462 '+Okernel_threads' )
463 set FOPTIM = ( '+O2' )
464 set NOOPTFLAGS = ( '+O0' )
465 set NOOPTFILES = ( 'barrier.F different_multiple.F' \
466 'external_fields_load.F' )
467 breaksw
468 case Linux-alpha+mpi:
469 echo "Configuring with MPI"
470 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
471 set INCLUDES = ( '-I/usr/local/include' )
472 case Linux-alpha:
473 echo "Configuring for " $platform
474 set LN = ( '/bin/ln -s' )
475 set CPP = ( '/lib/cpp -traditional -P' )
476 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
477 set FC = ( 'g77' )
478 set FFLAGS = ( ' ' )
479 if ($?IEEE) set FFLAGS = ( $FFLAGS '-ffloat-store' )
480 set FOPTIM = ( '-ffast-math -fexpensive-optimizations -fomit-frame-pointer -O3' )
481 set LINK = ( 'g77' )
482 breaksw
483 case Linux*+pgi+mpi:
484 if ($?include_jam_libs) then
485 set INCLUDES = ( '-I/usr/local/mpich-1.2.1/pgi_fortran_binding/include' )
486 set LIBS = ( '-L/usr/local/mpich-1.2.1/pgi_fortran_binding/lib/ -lfmpich -lmpich' )
487 else
488 set INCLUDES = ( '-I/usr/local/include' )
489 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
490 endif
491 case Linux*+pgi:
492 echo "Configuring for " $platform
493 set LN = ( '/bin/ln -s' )
494 set CPP = ( '/lib/cpp -traditional -P' )
495 set DEFINES = ( ${DEFINES} '-DWORDLENGTH=4' )
496 set FC = ( 'pgf77' )
497 set FFLAGS = ( '-byteswapio -r8 -Mnodclchk -Mextend' )
498 set FOPTIM = ( '-tp p6 -v -O2 -Munroll -Mvect=cachesize:512000,transform -Kieee' )
499 set LINK = ( 'pgf77' )
500 breaksw
501 case Linux*+mpi:
502 set LIBS = ( '-L/usr/local/lib/LINUX/ch_p4/ -lfmpich -lmpich' )
503 set INCLUDES = ( '-I/usr/local/include' )
504 case Linux*:
505 echo "Configuring for " $platform
506 set LN = ( '/bin/ln -s' )
507 set CPP = ( '/lib/cpp -traditional -P' )
508 set DEFINES = ( ${DEFINES} '-D_BYTESWAPIO -DWORDLENGTH=4' )
509 set FC = ( 'g77' )
510 set FFLAGS = ( '-Wimplicit -Wunused -Wuninitialized' )
511 if ($?IEEE) set FFLAGS = ( $FFLAGS '-ffloat-store' )
512 set FOPTIM = ( '-O3 -malign-double -funroll-loops' )
513 set LINK = ( 'g77' )
514 breaksw
515 case T3E:
516 case sn6312:
517 echo "Configuring for T3E"
518 set CPP = ( '/opt/ctl/bin/cpp -P')
519 set DEFINES = ( ${DEFINES} '-DTARGET_T3E -DWORDLENGTH=4' )
520 set FC = ( 'f90' )
521 set LINK = ( 'f90' )
522 set FFLAGS = ( '-O 2,fusion' )
523 breaksw
524 case T90:
525 case sn7113:
526 echo "Configuring for T90"
527 set FC = ( 'f90' )
528 set LINK = ( 'f90' )
529 set LN = ( '/bin/ln -s' )
530 set CPP = ( '/opt/ctl/bin/cpp -N -P' )
531 set DEFINES = ( ${DEFINES} '-DTARGET_CRAY_VECTOR -DWORDLENGTH=4' )
532 set FFLAGS = ( '-m3 -Rabc -N 132')
533 set FOPTIM = ( '-O0' )
534 set NOOPTFLAGS = ( '-O0' )
535 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
536 breaksw
537 case SV1:
538 case sn3002:
539 set FC = ( 'f90' )
540 set LINK = ( 'f90' )
541 set LN = ( '/bin/ln -s' )
542 set CPP = ( '/opt/ctl/bin/cpp -N -P' )
543 set DEFINES = ( ${DEFINES} '-DTARGET_CRAY_VECTOR -DWORDLENGTH=4' )
544 set FFLAGS = ( '-m3 -Rabc -ei -eI -s cf77types -N 132')
545 set FOPTIM = ( '-O0' )
546 set NOOPTFLAGS = ( '-O0' )
547 set NOOPTFILES = ( 'barrier.F different_multiple.F external_fields_load.F')
548 breaksw
549 case SP3:
550 # originally from A. Biastoch, SIO.
551 echo "Configuring for IBM SP POWER3"
552 set SOURCEDIRS = ( ./ $SOURCEDIRS )
553 set LN = ( 'ln -s' )
554 set DEFINES = ( ${DEFINES} '-DTARGET_PWR3 -DTARGET_SGI -DWORDLENGTH=4' )
555 set INCLUDES = ( '-I/usr/lpp/ppe.poe/include' )
556 # set CPP = ( '/lib/cpp' )
557 set FC = ( 'mpxlf95' )
558 set LINK = ( 'mpxlf95' )
559 set FLAGS = ( '-O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
560 '-bmaxdata:0x80000000 -bloadmap:mitgcmuv.map' )
561 set FFLAGS = ( '-qfixed=132 -O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
562 '-bmaxdata:0x80000000 ' )
563 set LDFLAGS = ( '-O3 -qarch=pwr3 -qtune=pwr3 -qcache=auto -qmaxmem=-1' \
564 '-bmaxdata:0x80000000' )
565 set LIBS = ( ' -L/usr/local/apps/mass -lmass' )
566 # set FFLAGS = ( '-extend_source -mp -mpio -bytereclen -r10000 -mips4' )
567 # set FOPTIM = ( '-O3' )
568 # set NOOPTFLAGS = ( '-O0' )
569 # set NOOPTFILES = ( 'barrier.F different_multiple.F ' \
570 # 'external_fields_load.F' )
571 set RMFILES = ( 'rii_files' )
572 breaksw
573 default:
574 echo "Error: platform not recognized: uname -p = " $platform$USEMPI
575 exit
576 breaksw
577 endsw
578
579 ###############################################################################
580 ## ##
581 ## Everything below here should not need to be changed. Platform specific ##
582 ## changes and code specific changes should be configured above this line. ##
583 ## ##
584 ###############################################################################
585
586 # Convert lists of directories into command-line options
587 foreach inc ($INCLUDEDIRS)
588 set INCLUDES = ($INCLUDES -I$inc)
589 end
590
591 # Search for source code
592 rm -rf .links.tmp;mkdir .links.tmp
593 echo "# This section creates symbolic links" > srclinks.tmp
594 echo "" >> srclinks.tmp
595 echo -n 'SRCFILES = ' > srclist.inc
596 echo -n 'CSRCFILES = ' > csrclist.inc
597 echo -n 'HEADERFILES = ' > hlist.inc
598 foreach dr ($SOURCEDIRS $INCLUDEDIRS .)
599 set deplist=( )
600 foreach srcfile (`cd $dr; ls *.[hcF]`)
601 if (! -r .links.tmp/$srcfile) then
602 if (-f $dr/$srcfile) then
603 switch ($srcfile:e)
604 case F:
605 touch .links.tmp/$srcfile
606 set deplist=($deplist $srcfile)
607 echo ' \' >> srclist.inc
608 echo -n " " $srcfile >> srclist.inc
609 breaksw
610 case c:
611 touch .links.tmp/$srcfile
612 set deplist=($deplist $srcfile)
613 echo ' \' >> csrclist.inc
614 echo -n " " $srcfile >> csrclist.inc
615 breaksw
616 case h:
617 touch .links.tmp/$srcfile
618 set deplist=($deplist $srcfile)
619 echo ' \' >> hlist.inc
620 echo -n " " $srcfile >> hlist.inc
621 breaksw
622 endsw
623 endif
624 endif
625 end
626 if ($#deplist != 0) then
627 echo "# These files are linked from $dr" >> srclinks.tmp
628 echo $deplist':' >> srclinks.tmp
629 echo ' $(LN) '$dr'/$@ $@' >> srclinks.tmp
630 endif
631 end
632 rm -rf .links.tmp
633 echo "" >> srclist.inc
634 echo "" >> csrclist.inc
635 echo "" >> hlist.inc
636
637 set THISHOSTNAME = ( `hostname` )
638 set THISCWD = ( `pwd` )
639 set THISDATE = ( `date` )
640
641 if (-r $mfile) mv -f $mfile $mfile.bak
642 ###########################################
643 ## This is the template for the makefile ##
644 ###########################################
645 echo Creating makefile: $mfile
646 echo "# Multithreaded + multi-processing makefile for $mach" > ${mfile}
647 echo "# This makefile was generated automatically on" >> ${mfile}
648 echo "# $THISDATE" >> ${mfile}
649 echo "# by the command:" >> ${mfile}
650 echo "# ${0} $argv" >> ${mfile}
651 echo "# executed by:" >> ${mfile}
652 echo "# $USER@${THISHOSTNAME}:${THISCWD}" >> ${mfile}
653 cat >> ${mfile} <<EOF
654 #
655 # BUILDDIR : Directory where object files are written
656 # SOURCEDIRS : Directories containing the source (.F) files
657 # INCLUDEDIRS : Directories containing the header-source (.h) files
658 # EXEDIR : Directory where executable that is generated is written
659 # EXECUTABLE : Full path of executable binary
660 #
661 # CPP : C-preprocessor command
662 # INCLUDES : Directories searched for header files
663 # DEFINES : Macro definitions for CPP
664 # MAKEDEPEND : Dependency generator
665 # KPP : Special preprocessor command (specific to platform)
666 # KFLAGS : Flags for KPP
667 # FC : Fortran compiler command
668 # FFLAGS : Configuration/debugging options for FC
669 # FOPTIM : Optimization options for FC
670 # LINK : Command for link editor program
671 # LIBS : Library flags /or/ additional optimization/debugging flags
672
673 ROOTDIR = ${ROOTDIR}
674 BUILDDIR = ${BUILDDIR}
675 SOURCEDIRS = ${SOURCEDIRS}
676 INCLUDEDIRS = ${INCLUDEDIRS}
677 EXEDIR = ${EXEDIR}
678 EXECUTABLE = \$(EXEDIR)/${EXECUTABLE}
679 TOOLSDIR = ${TOOLSDIR}
680
681 EOF
682
683
684 # JAM libraries on Hyades
685 if ($?include_jam_libs) then
686 cat >> ${mfile} <<EOF
687 # extra stuff for Hyades ............................................
688 HYADES_DIR = /u/u0/cnh/jam-lib/software
689 HYADES_DIR = /u/u0/cnh/jam-lib-twoproc
690 HYADES_DIR = /usr/local/jamlib/current/dual_proc
691 WORK_DIR = \$(HYADES_DIR)
692 DEPOSIT_DIR = linux_bin
693
694 STARTXOBJDIR = startx_util/\$(DEPOSIT_DIR)
695 STARTXOBJ = \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/startx_timer.o \
696 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/startx_util.o \
697 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/client.o \
698 \$(WORK_DIR)/startx_util/\$(DEPOSIT_DIR)/csutil.o
699
700 JAMOBJDIR = jam/\$(DEPOSIT_DIR)
701 JAMOBJ = \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_init.o \
702 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_kernel.o \
703 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_malloc.o \
704 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_vmalloc.o \
705 \$(WORK_DIR)/jam/\$(DEPOSIT_DIR)/jam_mutex.o
706
707 JAMCOBJDIR = jam_collective/\$(DEPOSIT_DIR)
708 JAMCOBJ = \$(WORK_DIR)/jam_collective/\$(DEPOSIT_DIR)/jam_collective.o
709
710 XLIBS = \$(STARTXOBJ) \$(JAMOBJ) \$(JAMCOBJ)
711
712 # ..................................................................
713
714 EOF
715 endif
716
717
718 cat >> ${mfile} <<EOF
719 # Unix ln (link)
720 LN = ${LN}
721 # C preprocessor
722 CPP = cat \$< | ${S64} | ${CPP}
723 # Dependency generator
724 MAKEDEPEND = ${MAKEDEPEND}
725 # Special preprocessor (KAP on DECs, FPP on Crays)
726 KPP = ${KPP}
727 # Fortran compiler
728 FC = ${FC}
729 # Link editor
730 LINK = ${LINK}
731
732 # Defines for CPP
733 DEFINES = ${DEFINES}
734 # Includes for CPP
735 INCLUDES = ${INCLUDES}
736 # Flags for KPP
737 KFLAGS1 = ${KFLAGS1}
738 KFLAGS2 = ${KFLAGS2}
739 # Optim./debug for FC
740 FFLAGS = ${FFLAGS}
741 FOPTIM = ${FOPTIM}
742 # Flags for CC
743 CFLAGS = ${CFLAGS}
744 # Files that should not be optimized
745 NOOPTFILES = ${NOOPTFILES}
746 NOOPTFLAGS = ${NOOPTFLAGS}
747 # Flags and libraries needed for linking
748 LIBS = ${LIBS} \$(XLIBS)
749
750 EOF
751
752 cat srclist.inc >> ${mfile}
753 cat csrclist.inc >> ${mfile}
754 cat hlist.inc >> ${mfile}
755 echo 'F77FILES = $(SRCFILES:.F=.f)' >> ${mfile}
756 echo 'OBJFILES = $(SRCFILES:.F=.o) $(CSRCFILES:.c=.o)' >> ${mfile}
757
758 rm -f srclist.inc csrclist.inc hlist.inc flist.tmp clist.tmp
759
760 cat >> ${mfile} <<EOF
761
762 .SUFFIXES:
763 .SUFFIXES: .o .f .p .F .c
764
765 all: \$(EXECUTABLE)
766 \$(EXECUTABLE): \$(OBJFILES)
767 \$(LINK) -o \$@ \$(FFLAGS) \$(FOPTIM) \$(OBJFILES) \$(LIBS)
768 depend:
769 @make links
770 \$(MAKEDEPEND) -o .f \$(DEFINES) \$(INCLUDES) \$(SRCFILES)
771
772 links: \$(SRCFILES) \$(CSRCFILES) \$(HEADERFILES)
773
774 small_f: \$(F77FILES)
775
776 output.txt: \$(EXECUTABLE)
777 @printf 'running ... '
778 @\$(EXECUTABLE) > \$@
779
780 clean:
781 -rm -rf *.o *.f *.p ${RMFILES}
782 Clean:
783 @make clean
784 @make cleanlinks
785 -rm -f Makefile.bak
786 CLEAN:
787 @make Clean
788 -find \$(EXEDIR) -name "*.meta" -exec rm {} \;
789 -find \$(EXEDIR) -name "*.data" -exec rm {} \;
790 -rm -f \$(EXECUTABLE)
791
792 makefile:
793 ${0} $argv
794 cleanlinks:
795 -find . -type l -exec rm {} \;
796
797 # The normal chain of rules is ( .F - .f - .o )
798 .F.f:
799 \$(CPP) \$(DEFINES) \$(INCLUDES) > \$@
800 .f.o:
801 \$(FC) \$(FFLAGS) \$(FOPTIM) -c \$<
802 .c.o:
803 \$(CC) \$(CFLAGS) -c \$<
804
805 # Special exceptions that use the ( .F - .p - .f - .o ) rule-chain
806 .F.p:
807 \$(CPP) \$(DEFINES) \$(INCLUDES) > \$@
808 .p.f:
809 \$(KPP) \$(KFLAGS1)\$@ \$(KFLAGS2) \$<
810 EOF
811
812 # Make list of "exceptions" that need ".p" files
813 foreach sf ($KPPFILES)
814 set fname=( ${sf:t} )
815 echo "${fname:r}.f: ${fname:r}.p" >> ${mfile}
816 end
817 foreach sf ($NOOPTFILES)
818 set fname=( ${sf:t} )
819 echo "${fname:r}.o: ${fname:r}.f" >> ${mfile}
820 echo ' $(FC) $(FFLAGS) $(NOOPTFLAGS) -c $<' >> ${mfile}
821 end
822 echo "" >> ${mfile}
823
824 # Add rules for links
825 cat srclinks.tmp >> ${mfile}
826 rm -f srclinks.tmp
827
828 echo "" >> ${mfile}
829 echo "# DO NOT DELETE" >> ${mfile}
830
831 exit

  ViewVC Help
Powered by ViewVC 1.1.22