#!/bin/csh -f
#
# $Header: /home/ubuntu/mnt/e9_copy/MITgcm/tools/Attic/genmake.sgi,v 1.3.2.1 1998/06/20 21:15:23 cnh Exp $
#
#  Makefile generator for MITgcm UV codes
#

# Generate make files for SGI IRIX system
set mfile = ( Makefile.sgi     )
set mach  = ( 'SGI IRIX/mips4'    )

# Directories for source, includes, binaries and executables
# Note
# o If you prefer/need everything under a single directory
#   copy everything in ../psupp/src, ../model/src,
#   ../psupp/inc and ../model/inc into a directory and then
#   edit the paths below to read
#   set PSUPP_SDIR = (  )
#   set MODEL_SDIR = (  )
#   set PSUPP_IDIR = (  )
#   set MODEL_IDIR = (  )
#   set TDIR       = (  )
#   set BDIR       = (  )
#   set EDIR       = (  )
set PSUPP_SDIR = ( ../eesupp/src/ )
set MODEL_SDIR = ( ../model/src/ )
set PSUPP_IDIR = ( ../eesupp/inc/ )
set MODEL_IDIR = ( ../model/inc/ )
set TDIR       = ( ../tools/ )
set BDIR       = ( ../bin/       )
set EDIR       = ( ../exe/       )
set EXE        = ( mitgcmuv      )

set CPP   = ( '/lib/cpp -P $(INCLUDES) -DUSE_IRIX' )
set FCOMP = ( 'f77 -extend_source -mp -mpio -bytereclen -O3 -r10000 -c' )
set LINK  = ( 'f77 -mp -mpio -bytereclen -O3 -r10000 ' )
set INCLUDES = ( '-I. -I$(PSUPP_IDIR) -I$(MODEL_IDIR) ' \
                 '-I/usr/local/mpi/include' )

echo "Creating make file ${mfile} "
echo "#"                    > ${mfile}
echo "# Multithreaded + multi-processing makefile for $mach "      >> ${mfile}
echo "# This make file was generated automatically by the command" >> ${mfile}
echo "# " \"${0}\"                                                 >> ${mfile}
echo "# on `hostname`:`pwd` "                                      >> ${mfile}
echo "#  " `date`                                                  >> ${mfile}
echo "# by $user"                                                  >> ${mfile}
echo "#         "                                                  >> ${mfile}

cat >> ${mfile} <<EOF

# PSUPP_SDIR: Directory holding parallel support routines
# MODEL_SDIR: Directory model code
# PSUPP_IDIR: Directory holding parallel support header files
# MODEL_IDIR: Directory model header files
# TDIR      : Directory where build tools are stored
# BDIR      : Directory where object files are written
# EDIR      : Directory where executable that is generated is written
# INCLUDES  : Directories searched for header files
# CPP       : C-preprocessor command               
# FCOMP     : Fortran compiler command             
# LINK      : Command for link editor program          
# Note           
# ====
# o PSUPP_SDIR ... EDIR can all be set to the current directory if
#   you want to organise things that way. Alternatively they can be
#   set to different directories so that code can be kept on a backed
#   up disk while object files and executables are created on scratch
#   disks. I prefer this latter setup!
# o Under Solaris if the disk on which the compiler is generating 
#   object files and executables is mounted via NFS rather than being
#   a local SCSI disk compilation times can increase by a factor of
#   ten!
PSUPP_SDIR = ${PSUPP_SDIR}
MODEL_SDIR = ${MODEL_SDIR}
PSUPP_IDIR = ${PSUPP_IDIR}
MODEL_IDIR = ${MODEL_IDIR}
TDIR       = ${TDIR}
BDIR       = ${BDIR}  
EDIR       = ${EDIR}
INCLUDES   = ${INCLUDES}
EXE        = \$(EDIR)${EXE}
EOF

echo "# C preprocessor   " >> ${mfile}
echo 'CPP        =' ${CPP} >> ${mfile}
echo "# Fortran compiler " >> ${mfile}
echo 'FCOMP = '${FCOMP}    >> ${mfile}
echo "# Link editor      " >> ${mfile}
echo 'LINK  = '${LINK}     >> ${mfile}
echo "                   " >> ${mfile}


set psupp_slist = ( )
set psupp_olist = ( )
if ( ${PSUPP_SDIR} != ${MODEL_SDIR} ) then
 set flist = `ls -1 ${PSUPP_SDIR} | grep '.*\.F'`
 if ( "${flist}" != "" ) then
  foreach f ( $flist )
   set fname = ( ${f:t}       )
   set pf    = ( ${fname:r}.f )
   set of    = ( ${fname:r}.o )
   echo ${pf}: '$(PSUPP_SDIR)'${fname}   >> ${mfile}.$$
   echo '	@echo Preprocessing $(PSUPP_SDIR)'${fname} >> ${mfile}.$$
   echo '	@ $(CPP) $(PSUPP_SDIR)'${fname}' > '$pf >> ${mfile}.$$
   echo ${of}: ${pf}  >> ${mfile}.$$
   echo '	@echo Compiling '${pf} >> ${mfile}.$$
   echo '	@ $(FCOMP) '$pf >> ${mfile}.$$
   set psupp_slist = ( ${psupp_slist} ${f}  )
   set psupp_olist = ( ${psupp_olist} ${of} )
  end
 endif
endif

set model_slist = ( )
set model_olist = ( )
set flist = `ls -1 ${MODEL_SDIR} | grep '.*\.F'`
if ( "${flist}" != "" ) then
 foreach f ( ${flist} )
  set fname = ( ${f:t}       )
  set pf    = ( ${fname:r}.f )
  set of    = ( ${fname:r}.o )
  echo ${pf}: '$(MODEL_SDIR)'${fname}   >> ${mfile}.$$
  echo '	@echo Preprocessing $(MODEL_SDIR)'${fname} >> ${mfile}.$$
  echo '	@ $(CPP) $(MODEL_SDIR)'${fname}' > '$pf >> ${mfile}.$$
  echo ${of}: ${pf}  >> ${mfile}.$$
  echo '	@echo Compiling '${pf} >> ${mfile}.$$
  echo '	@ $(FCOMP) '$pf >> ${mfile}.$$
  set model_slist = ( ${model_slist} ${f}  )
  set model_olist = ( ${model_olist} ${of} )
 end
endif

echo "                   " >> ${mfile}
echo "# ===========      " >> ${mfile}
echo "# File lists       " >> ${mfile}
echo "# ===========      " >> ${mfile}
if ( $#psupp_olist == 0 ) then
 echo 'psupp_objs = ' >> ${mfile}
else if ( $#psupp_olist == 1 ) then
 echo 'psupp_objs = '${psupp_olist} >> ${mfile}
else
 echo 'psupp_objs = '$psupp_olist[1] '\' >> ${mfile}
 set psupp_count = 2
 while ( $psupp_count < $#psupp_olist )
  echo '             '$psupp_olist[$psupp_count] '\' >> ${mfile}
  @ psupp_count = $psupp_count + 1
 end
 echo '             '$psupp_olist[$#psupp_olist] >> ${mfile}
endif
echo "                   " >> ${mfile}
if ( $#psupp_slist == 0 ) then
 echo 'psupp_srcs = ' >> ${mfile}
else if ( $#psupp_slist == 1 ) then
 echo 'psupp_srcs = $(PSUPP_SDIR)'${psupp_slist} >> ${mfile}
else
 echo 'psupp_srcs = $(PSUPP_SDIR)'$psupp_slist[1] '\' >> ${mfile}
 set psupp_count = 2
 while ( $psupp_count < $#psupp_slist )
  echo '             $(PSUPP_SDIR)'$psupp_slist[$psupp_count] '\' >> ${mfile}
  @ psupp_count = $psupp_count + 1
 end
 echo '             $(PSUPP_SDIR)'$psupp_slist[$#psupp_slist] >> ${mfile}
endif
echo "                   " >> ${mfile}
if ( $#model_olist == 0 ) then
 echo 'model_objs = ' >> ${mfile}
else if ( $#model_olist == 1 ) then
 echo 'model_objs = '${model_olist} >> ${mfile}
else
 echo 'model_objs = '$model_olist[1] '\' >> ${mfile}
 set model_count = 2
 while ( $model_count < $#model_olist )
  echo '             '$model_olist[$model_count] '\' >> ${mfile}
  @ model_count = $model_count + 1
 end
 echo '             '$model_olist[$#model_olist] >> ${mfile}
endif
echo "                   " >> ${mfile}
if ( $#model_slist == 0 ) then
 echo 'model_srcs = ' >> ${mfile}
else if ( $#model_slist == 1 ) then
 echo 'model_srcs = $(MODEL_SDIR)'${model_slist} >> ${mfile}
else
 echo 'model_srcs = $(MODEL_SDIR)'$model_slist[1] '\' >> ${mfile}
 set model_count = 2
 while ( $model_count < $#model_slist )
  echo '             $(MODEL_SDIR)'$model_slist[$model_count] '\' >> ${mfile}
  @ model_count = $model_count + 1
 end
 echo '             $(MODEL_SDIR)'$model_slist[$#model_slist] >> ${mfile}
endif
echo "                   " >> ${mfile}
echo 'objs = $(psupp_objs) $(model_objs)' >> ${mfile}
echo 'srcs = $(psupp_srcs) $(model_srcs)' >> ${mfile}
echo "                   " >> ${mfile}
echo "# ===========      " >> ${mfile}
echo "# Begin rules      " >> ${mfile}
echo "# ===========      " >> ${mfile}
echo "                   " >> ${mfile}
echo '$(EXE): $(objs)    ' >> ${mfile}
echo '	$(LINK) -o $(EXE) $(objs)' >> ${mfile}
echo "                   " >> ${mfile}
echo 'clean:  ' >> ${mfile}
echo '	rm *.o *.f               ' >> ${mfile}
echo "                   " >> ${mfile}
echo 'depend:  ' >> ${mfile}
echo '	makedepend -f $(TDIR)'${mfile}' $(INCLUDES) $(srcs) ' >> ${mfile}
echo "                   " >> ${mfile}
cat ${mfile}.$$ >> ${mfile}
\rm ${mfile}.$$

# $ Id: $