--- MITgcm/pkg/mom_fluxform/mom_v_adv_wv.F	2001/03/28 19:51:14	1.1
+++ MITgcm/pkg/mom_fluxform/mom_v_adv_wv.F	2001/05/29 14:01:38	1.2
@@ -0,0 +1,87 @@
+C $Header: /home/ubuntu/mnt/e9_copy/MITgcm/pkg/mom_fluxform/mom_v_adv_wv.F,v 1.2 2001/05/29 14:01:38 adcroft Exp $
+C $Name:  $
+
+#include "CPP_OPTIONS.h"
+
+      SUBROUTINE MOM_V_ADV_WV(
+     I        bi,bj,k,
+     I        vFld,wFld,
+     O        advectiveFluxWV,
+     I        myThid)
+      IMPLICIT NONE
+C
+C     Calculate advective flux in R direction for V eqn
+C
+
+C     == Global variables ==
+#include "SIZE.h"
+#include "EEPARAMS.h"
+#include "PARAMS.h"
+#include "GRID.h"
+
+C     == Routine arguments ==
+      INTEGER bi,bj,k
+      _RL vFld(1-OLx:sNx+OLx,1-OLy:sNy+OLy,Nr,nSx,nSy)
+      _RL wFld(1-OLx:sNx+OLx,1-OLy:sNy+OLy,Nr,nSx,nSy)
+      _RL advectiveFluxWV(1-OLx:sNx+OLx,1-OLy:sNy+OLy)
+      INTEGER myThid
+
+C     == Local variables ==
+      INTEGER i,j
+
+      IF ( k.GT.Nr .OR.
+     &    (k.EQ.1.AND.rigidLid) ) THEN
+C     Advective flux = 0  at k=Nr+1 ; = 0 at k=1 if rigid-lid
+
+      DO j=1-Oly,sNy+Oly
+       DO i=1-Olx,sNx+Olx
+        advectiveFluxWV(i,j) = 0.
+       ENDDO
+      ENDDO
+
+      ELSEIF (k.EQ.1) THEN
+C     (linear) Free-surface correction at k=1
+
+      DO j=1-Oly+1,sNy+Oly
+       DO i=1-Olx,sNx+Olx
+        advectiveFluxWV(i,j) =
+     &     0.5*(
+     &        wFld(i, j ,k,bi,bj)*rA(i, j ,bi,bj)
+     &       +wFld(i,j-1,k,bi,bj)*rA(i,j-1,bi,bj)
+     &         )*vFld(i,j,k,bi,bj)
+       ENDDO
+      ENDDO
+
+      ELSE
+
+C     Vertical advection - interior ; assume vFld & wFld are masked 
+      DO j=1-Oly+1,sNy+Oly
+       DO i=1-Olx,sNx+Olx
+        advectiveFluxWV(i,j) =
+     &    0.25*(
+     &        wFld(i, j ,k,bi,bj)*rA(i, j ,bi,bj)
+     &       +wFld(i,j-1,k,bi,bj)*rA(i,j-1,bi,bj)
+     &         )*( vFld(i,j,k,bi,bj)+vFld(i,j,k-1,bi,bj) )
+       ENDDO
+      ENDDO
+
+      IF (.NOT. rigidLid) THEN
+C     (linear) Free-surface correction at k>1
+        DO j=1-Oly+1,sNy+Oly
+         DO i=1-Olx,sNx+Olx
+          advectiveFluxWV(i,j) = advectiveFluxWV(i,j)
+     &     +0.25*(
+     &          wFld(i, j ,k,bi,bj)*rA(i, j ,bi,bj)*
+     &          (maskC(i,j,k,bi,bj) - maskC(i,j,k-1,bi,bj))
+     &         +wFld(i,j-1,k,bi,bj)*rA(i,j-1,bi,bj)*
+     &          (maskC(i,j-1,k,bi,bj)-maskC(i,j-1,k-1,bi,bj))
+     &           )*vFld(i,j,k,bi,bj)
+         ENDDO
+        ENDDO
+C- endif NOT rigidLid
+      ENDIF
+
+      ENDIF
+
+      RETURN
+      END