| 1 |
C $Header: /u/gcmpack/MITgcm/pkg/mom_fluxform/mom_fluxform.F,v 1.30 2005/11/24 00:06:38 heimbach Exp $ |
| 2 |
C $Name: $ |
| 3 |
|
| 4 |
CBOI |
| 5 |
C !TITLE: pkg/mom\_advdiff |
| 6 |
C !AUTHORS: adcroft@mit.edu |
| 7 |
C !INTRODUCTION: Flux-form Momentum Equations Package |
| 8 |
C |
| 9 |
C Package "mom\_fluxform" provides methods for calculating explicit terms |
| 10 |
C in the momentum equation cast in flux-form: |
| 11 |
C \begin{eqnarray*} |
| 12 |
C G^u & = & -\frac{1}{\rho} \partial_x \phi_h |
| 13 |
C -\nabla \cdot {\bf v} u |
| 14 |
C -fv |
| 15 |
C +\frac{1}{\rho} \nabla \cdot {\bf \tau}^x |
| 16 |
C + \mbox{metrics} |
| 17 |
C \\ |
| 18 |
C G^v & = & -\frac{1}{\rho} \partial_y \phi_h |
| 19 |
C -\nabla \cdot {\bf v} v |
| 20 |
C +fu |
| 21 |
C +\frac{1}{\rho} \nabla \cdot {\bf \tau}^y |
| 22 |
C + \mbox{metrics} |
| 23 |
C \end{eqnarray*} |
| 24 |
C where ${\bf v}=(u,v,w)$ and $\tau$, the stress tensor, includes surface |
| 25 |
C stresses as well as internal viscous stresses. |
| 26 |
CEOI |
| 27 |
|
| 28 |
#include "MOM_FLUXFORM_OPTIONS.h" |
| 29 |
|
| 30 |
CBOP |
| 31 |
C !ROUTINE: MOM_FLUXFORM |
| 32 |
|
| 33 |
C !INTERFACE: ========================================================== |
| 34 |
SUBROUTINE MOM_FLUXFORM( |
| 35 |
I bi,bj,iMin,iMax,jMin,jMax,k,kUp,kDown, |
| 36 |
I KappaRU, KappaRV, |
| 37 |
U fVerU, fVerV, |
| 38 |
O guDiss, gvDiss, |
| 39 |
I myTime, myIter, myThid) |
| 40 |
|
| 41 |
C !DESCRIPTION: |
| 42 |
C Calculates all the horizontal accelerations except for the implicit surface |
| 43 |
C pressure gradient and implciit vertical viscosity. |
| 44 |
|
| 45 |
C !USES: =============================================================== |
| 46 |
C == Global variables == |
| 47 |
IMPLICIT NONE |
| 48 |
#include "SIZE.h" |
| 49 |
#include "DYNVARS.h" |
| 50 |
#include "FFIELDS.h" |
| 51 |
#include "EEPARAMS.h" |
| 52 |
#include "PARAMS.h" |
| 53 |
#include "GRID.h" |
| 54 |
#include "SURFACE.h" |
| 55 |
|
| 56 |
C !INPUT PARAMETERS: =================================================== |
| 57 |
C bi,bj :: tile indices |
| 58 |
C iMin,iMax,jMin,jMAx :: loop ranges |
| 59 |
C k :: vertical level |
| 60 |
C kUp :: =1 or 2 for consecutive k |
| 61 |
C kDown :: =2 or 1 for consecutive k |
| 62 |
C KappaRU :: vertical viscosity |
| 63 |
C KappaRV :: vertical viscosity |
| 64 |
C fVerU :: vertical flux of U, 2 1/2 dim for pipe-lining |
| 65 |
C fVerV :: vertical flux of V, 2 1/2 dim for pipe-lining |
| 66 |
C guDiss :: dissipation tendency (all explicit terms), u component |
| 67 |
C gvDiss :: dissipation tendency (all explicit terms), v component |
| 68 |
C myTime :: current time |
| 69 |
C myIter :: current time-step number |
| 70 |
C myThid :: thread number |
| 71 |
INTEGER bi,bj,iMin,iMax,jMin,jMax |
| 72 |
INTEGER k,kUp,kDown |
| 73 |
_RL KappaRU(1-OLx:sNx+OLx,1-OLy:sNy+OLy,Nr) |
| 74 |
_RL KappaRV(1-OLx:sNx+OLx,1-OLy:sNy+OLy,Nr) |
| 75 |
_RL fVerU(1-OLx:sNx+OLx,1-OLy:sNy+OLy,2) |
| 76 |
_RL fVerV(1-OLx:sNx+OLx,1-OLy:sNy+OLy,2) |
| 77 |
_RL guDiss(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 78 |
_RL gvDiss(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 79 |
_RL myTime |
| 80 |
INTEGER myIter |
| 81 |
INTEGER myThid |
| 82 |
|
| 83 |
C !OUTPUT PARAMETERS: ================================================== |
| 84 |
C None - updates gU() and gV() in common blocks |
| 85 |
|
| 86 |
C !LOCAL VARIABLES: ==================================================== |
| 87 |
C i,j :: loop indices |
| 88 |
C vF :: viscous flux |
| 89 |
C v4F :: bi-harmonic viscous flux |
| 90 |
C cF :: Coriolis acceleration |
| 91 |
C mT :: Metric terms |
| 92 |
C fZon :: zonal fluxes |
| 93 |
C fMer :: meridional fluxes |
| 94 |
C fVrUp,fVrDw :: vertical viscous fluxes at interface k-1 & k |
| 95 |
INTEGER i,j |
| 96 |
_RL vF(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 97 |
_RL v4F(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 98 |
_RL cF(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 99 |
_RL mT(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 100 |
_RL fZon(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 101 |
_RL fMer(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 102 |
_RL fVrUp(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 103 |
_RL fVrDw(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 104 |
C afFacMom - Tracer parameters for turning terms |
| 105 |
C vfFacMom on and off. |
| 106 |
C pfFacMom afFacMom - Advective terms |
| 107 |
C cfFacMom vfFacMom - Eddy viscosity terms |
| 108 |
C mTFacMom pfFacMom - Pressure terms |
| 109 |
C cfFacMom - Coriolis terms |
| 110 |
C foFacMom - Forcing |
| 111 |
C mTFacMom - Metric term |
| 112 |
C uDudxFac, AhDudxFac, etc ... individual term parameters for switching terms off |
| 113 |
_RS hFacZ(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 114 |
_RS r_hFacZ(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 115 |
_RS xA(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 116 |
_RS yA(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 117 |
_RL uTrans(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 118 |
_RL vTrans(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 119 |
_RL uFld(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 120 |
_RL vFld(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 121 |
_RL rTransU(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 122 |
_RL rTransV(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 123 |
_RL KE(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 124 |
_RL viscAh_D(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 125 |
_RL viscAh_Z(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 126 |
_RL viscA4_D(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 127 |
_RL viscA4_Z(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 128 |
_RL vort3(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 129 |
_RL hDiv(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 130 |
_RL strain(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 131 |
_RL tension(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 132 |
_RL uDudxFac |
| 133 |
_RL AhDudxFac |
| 134 |
_RL vDudyFac |
| 135 |
_RL AhDudyFac |
| 136 |
_RL rVelDudrFac |
| 137 |
_RL ArDudrFac |
| 138 |
_RL fuFac |
| 139 |
_RL mtFacU |
| 140 |
_RL uDvdxFac |
| 141 |
_RL AhDvdxFac |
| 142 |
_RL vDvdyFac |
| 143 |
_RL AhDvdyFac |
| 144 |
_RL rVelDvdrFac |
| 145 |
_RL ArDvdrFac |
| 146 |
_RL fvFac |
| 147 |
_RL mtFacV |
| 148 |
_RL sideMaskFac |
| 149 |
LOGICAL bottomDragTerms,harmonic,biharmonic,useVariableViscosity |
| 150 |
CEOP |
| 151 |
|
| 152 |
C Initialise intermediate terms |
| 153 |
DO j=1-OLy,sNy+OLy |
| 154 |
DO i=1-OLx,sNx+OLx |
| 155 |
vF(i,j) = 0. |
| 156 |
v4F(i,j) = 0. |
| 157 |
cF(i,j) = 0. |
| 158 |
mT(i,j) = 0. |
| 159 |
fZon(i,j) = 0. |
| 160 |
fMer(i,j) = 0. |
| 161 |
fVrUp(i,j)= 0. |
| 162 |
fVrDw(i,j)= 0. |
| 163 |
rTransU(i,j)= 0. |
| 164 |
rTransV(i,j)= 0. |
| 165 |
strain(i,j) = 0. |
| 166 |
tension(i,j)= 0. |
| 167 |
guDiss(i,j) = 0. |
| 168 |
gvDiss(i,j) = 0. |
| 169 |
#ifdef ALLOW_AUTODIFF_TAMC |
| 170 |
vort3(i,j) = 0. _d 0 |
| 171 |
strain(i,j) = 0. _d 0 |
| 172 |
tension(i,j) = 0. _d 0 |
| 173 |
#endif |
| 174 |
ENDDO |
| 175 |
ENDDO |
| 176 |
|
| 177 |
C-- Term by term tracer parmeters |
| 178 |
C o U momentum equation |
| 179 |
uDudxFac = afFacMom*1. |
| 180 |
AhDudxFac = vfFacMom*1. |
| 181 |
vDudyFac = afFacMom*1. |
| 182 |
AhDudyFac = vfFacMom*1. |
| 183 |
rVelDudrFac = afFacMom*1. |
| 184 |
ArDudrFac = vfFacMom*1. |
| 185 |
mTFacU = mtFacMom*1. |
| 186 |
fuFac = cfFacMom*1. |
| 187 |
C o V momentum equation |
| 188 |
uDvdxFac = afFacMom*1. |
| 189 |
AhDvdxFac = vfFacMom*1. |
| 190 |
vDvdyFac = afFacMom*1. |
| 191 |
AhDvdyFac = vfFacMom*1. |
| 192 |
rVelDvdrFac = afFacMom*1. |
| 193 |
ArDvdrFac = vfFacMom*1. |
| 194 |
mTFacV = mtFacMom*1. |
| 195 |
fvFac = cfFacMom*1. |
| 196 |
|
| 197 |
IF (implicitViscosity) THEN |
| 198 |
ArDudrFac = 0. |
| 199 |
ArDvdrFac = 0. |
| 200 |
ENDIF |
| 201 |
|
| 202 |
C note: using standard stencil (no mask) results in under-estimating |
| 203 |
C vorticity at a no-slip boundary by a factor of 2 = sideDragFactor |
| 204 |
IF ( no_slip_sides ) THEN |
| 205 |
sideMaskFac = sideDragFactor |
| 206 |
ELSE |
| 207 |
sideMaskFac = 0. _d 0 |
| 208 |
ENDIF |
| 209 |
|
| 210 |
IF ( no_slip_bottom |
| 211 |
& .OR. bottomDragQuadratic.NE.0. |
| 212 |
& .OR. bottomDragLinear.NE.0.) THEN |
| 213 |
bottomDragTerms=.TRUE. |
| 214 |
ELSE |
| 215 |
bottomDragTerms=.FALSE. |
| 216 |
ENDIF |
| 217 |
|
| 218 |
C-- Calculate open water fraction at vorticity points |
| 219 |
CALL MOM_CALC_HFACZ(bi,bj,k,hFacZ,r_hFacZ,myThid) |
| 220 |
|
| 221 |
C---- Calculate common quantities used in both U and V equations |
| 222 |
C Calculate tracer cell face open areas |
| 223 |
DO j=1-OLy,sNy+OLy |
| 224 |
DO i=1-OLx,sNx+OLx |
| 225 |
xA(i,j) = _dyG(i,j,bi,bj) |
| 226 |
& *drF(k)*_hFacW(i,j,k,bi,bj) |
| 227 |
yA(i,j) = _dxG(i,j,bi,bj) |
| 228 |
& *drF(k)*_hFacS(i,j,k,bi,bj) |
| 229 |
ENDDO |
| 230 |
ENDDO |
| 231 |
|
| 232 |
C Make local copies of horizontal flow field |
| 233 |
DO j=1-OLy,sNy+OLy |
| 234 |
DO i=1-OLx,sNx+OLx |
| 235 |
uFld(i,j) = uVel(i,j,k,bi,bj) |
| 236 |
vFld(i,j) = vVel(i,j,k,bi,bj) |
| 237 |
ENDDO |
| 238 |
ENDDO |
| 239 |
|
| 240 |
C Calculate velocity field "volume transports" through tracer cell faces. |
| 241 |
DO j=1-OLy,sNy+OLy |
| 242 |
DO i=1-OLx,sNx+OLx |
| 243 |
uTrans(i,j) = uFld(i,j)*xA(i,j) |
| 244 |
vTrans(i,j) = vFld(i,j)*yA(i,j) |
| 245 |
ENDDO |
| 246 |
ENDDO |
| 247 |
|
| 248 |
CALL MOM_CALC_KE(bi,bj,k,2,uFld,vFld,KE,myThid) |
| 249 |
IF ( momViscosity) THEN |
| 250 |
CALL MOM_CALC_HDIV(bi,bj,k,2,uFld,vFld,hDiv,myThid) |
| 251 |
CALL MOM_CALC_RELVORT3(bi,bj,k,uFld,vFld,hFacZ,vort3,myThid) |
| 252 |
CALL MOM_CALC_TENSION(bi,bj,k,uFld,vFld,tension,myThid) |
| 253 |
CALL MOM_CALC_STRAIN(bi,bj,k,uFld,vFld,hFacZ,strain,myThid) |
| 254 |
DO j=1-Oly,sNy+Oly |
| 255 |
DO i=1-Olx,sNx+Olx |
| 256 |
IF ( hFacZ(i,j).EQ.0. ) THEN |
| 257 |
vort3(i,j) = sideMaskFac*vort3(i,j) |
| 258 |
strain(i,j) = sideMaskFac*strain(i,j) |
| 259 |
ENDIF |
| 260 |
ENDDO |
| 261 |
ENDDO |
| 262 |
#ifdef ALLOW_DIAGNOSTICS |
| 263 |
IF ( useDiagnostics ) THEN |
| 264 |
CALL DIAGNOSTICS_FILL(hDiv, 'momHDiv ',k,1,2,bi,bj,myThid) |
| 265 |
CALL DIAGNOSTICS_FILL(vort3, 'momVort3',k,1,2,bi,bj,myThid) |
| 266 |
CALL DIAGNOSTICS_FILL(tension,'Tension ',k,1,2,bi,bj,myThid) |
| 267 |
CALL DIAGNOSTICS_FILL(strain, 'Strain ',k,1,2,bi,bj,myThid) |
| 268 |
ENDIF |
| 269 |
#endif |
| 270 |
ENDIF |
| 271 |
|
| 272 |
C--- First call (k=1): compute vertical adv. flux fVerU(kUp) & fVerV(kUp) |
| 273 |
IF (momAdvection.AND.k.EQ.1) THEN |
| 274 |
|
| 275 |
C- Calculate vertical transports above U & V points (West & South face): |
| 276 |
CALL MOM_CALC_RTRANS( k, bi, bj, |
| 277 |
O rTransU, rTransV, |
| 278 |
I myTime, myIter, myThid) |
| 279 |
|
| 280 |
C- Free surface correction term (flux at k=1) |
| 281 |
CALL MOM_U_ADV_WU( bi,bj,k,uVel,wVel,rTransU, |
| 282 |
O fVerU(1-OLx,1-OLy,kUp), myThid ) |
| 283 |
|
| 284 |
CALL MOM_V_ADV_WV( bi,bj,k,vVel,wVel,rTransV, |
| 285 |
O fVerV(1-OLx,1-OLy,kUp), myThid ) |
| 286 |
|
| 287 |
C--- endif momAdvection & k=1 |
| 288 |
ENDIF |
| 289 |
|
| 290 |
|
| 291 |
C--- Calculate vertical transports (at k+1) below U & V points : |
| 292 |
IF (momAdvection) THEN |
| 293 |
CALL MOM_CALC_RTRANS( k+1, bi, bj, |
| 294 |
O rTransU, rTransV, |
| 295 |
I myTime, myIter, myThid) |
| 296 |
ENDIF |
| 297 |
|
| 298 |
IF (momViscosity) THEN |
| 299 |
CALL MOM_CALC_VISC( |
| 300 |
I bi,bj,k, |
| 301 |
O viscAh_Z,viscAh_D,viscA4_Z,viscA4_D, |
| 302 |
O harmonic,biharmonic,useVariableViscosity, |
| 303 |
I hDiv,vort3,tension,strain,KE,hFacZ, |
| 304 |
I myThid) |
| 305 |
ENDIF |
| 306 |
|
| 307 |
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7-|--+----| |
| 308 |
|
| 309 |
C---- Zonal momentum equation starts here |
| 310 |
|
| 311 |
IF (momAdvection) THEN |
| 312 |
C--- Calculate mean fluxes (advection) between cells for zonal flow. |
| 313 |
|
| 314 |
C-- Zonal flux (fZon is at east face of "u" cell) |
| 315 |
C Mean flow component of zonal flux -> fZon |
| 316 |
CALL MOM_U_ADV_UU(bi,bj,k,uTrans,uFld,fZon,myThid) |
| 317 |
|
| 318 |
C-- Meridional flux (fMer is at south face of "u" cell) |
| 319 |
C Mean flow component of meridional flux -> fMer |
| 320 |
CALL MOM_U_ADV_VU(bi,bj,k,vTrans,uFld,fMer,myThid) |
| 321 |
|
| 322 |
C-- Vertical flux (fVer is at upper face of "u" cell) |
| 323 |
C Mean flow component of vertical flux (at k+1) -> fVer |
| 324 |
CALL MOM_U_ADV_WU( |
| 325 |
I bi,bj,k+1,uVel,wVel,rTransU, |
| 326 |
O fVerU(1-OLx,1-OLy,kDown), myThid ) |
| 327 |
|
| 328 |
C-- Tendency is minus divergence of the fluxes + coriolis + pressure term |
| 329 |
DO j=jMin,jMax |
| 330 |
DO i=iMin,iMax |
| 331 |
gU(i,j,k,bi,bj) = |
| 332 |
#ifdef OLD_UV_GEOM |
| 333 |
& -_recip_hFacW(i,j,k,bi,bj)*recip_drF(k)/ |
| 334 |
& ( 0.5 _d 0*(rA(i,j,bi,bj)+rA(i-1,j,bi,bj)) ) |
| 335 |
#else |
| 336 |
& -_recip_hFacW(i,j,k,bi,bj)*recip_drF(k) |
| 337 |
& *recip_rAw(i,j,bi,bj) |
| 338 |
#endif |
| 339 |
& *( ( fZon(i,j ) - fZon(i-1,j) )*uDudxFac |
| 340 |
& +( fMer(i,j+1) - fMer(i, j) )*vDudyFac |
| 341 |
& +(fVerU(i,j,kDown) - fVerU(i,j,kUp))*rkSign*rVelDudrFac |
| 342 |
& ) |
| 343 |
ENDDO |
| 344 |
ENDDO |
| 345 |
|
| 346 |
#ifdef ALLOW_DIAGNOSTICS |
| 347 |
IF ( useDiagnostics ) THEN |
| 348 |
CALL DIAGNOSTICS_FILL(fZon,'ADVx_Um ',k,1,2,bi,bj,myThid) |
| 349 |
CALL DIAGNOSTICS_FILL(fMer,'ADVy_Um ',k,1,2,bi,bj,myThid) |
| 350 |
CALL DIAGNOSTICS_FILL(fVerU(1-Olx,1-Oly,kUp), |
| 351 |
& 'ADVrE_Um',k,1,2,bi,bj,myThid) |
| 352 |
ENDIF |
| 353 |
#endif |
| 354 |
|
| 355 |
#ifdef NONLIN_FRSURF |
| 356 |
C-- account for 3.D divergence of the flow in rStar coordinate: |
| 357 |
# ifndef DISABLE_RSTAR_CODE |
| 358 |
IF ( select_rStar.GT.0 ) THEN |
| 359 |
DO j=jMin,jMax |
| 360 |
DO i=iMin,iMax |
| 361 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj) |
| 362 |
& - (rStarExpW(i,j,bi,bj) - 1. _d 0)/deltaTfreesurf |
| 363 |
& *uVel(i,j,k,bi,bj) |
| 364 |
ENDDO |
| 365 |
ENDDO |
| 366 |
ENDIF |
| 367 |
IF ( select_rStar.LT.0 ) THEN |
| 368 |
DO j=jMin,jMax |
| 369 |
DO i=iMin,iMax |
| 370 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj) |
| 371 |
& - rStarDhWDt(i,j,bi,bj)*uVel(i,j,k,bi,bj) |
| 372 |
ENDDO |
| 373 |
ENDDO |
| 374 |
ENDIF |
| 375 |
# endif /* DISABLE_RSTAR_CODE */ |
| 376 |
#endif /* NONLIN_FRSURF */ |
| 377 |
|
| 378 |
ELSE |
| 379 |
C- if momAdvection / else |
| 380 |
DO j=1-OLy,sNy+OLy |
| 381 |
DO i=1-OLx,sNx+OLx |
| 382 |
gU(i,j,k,bi,bj) = 0. _d 0 |
| 383 |
ENDDO |
| 384 |
ENDDO |
| 385 |
|
| 386 |
C- endif momAdvection. |
| 387 |
ENDIF |
| 388 |
|
| 389 |
IF (momViscosity) THEN |
| 390 |
C--- Calculate eddy fluxes (dissipation) between cells for zonal flow. |
| 391 |
|
| 392 |
C Bi-harmonic term del^2 U -> v4F |
| 393 |
IF (biharmonic) |
| 394 |
& CALL MOM_U_DEL2U(bi,bj,k,uFld,hFacZ,v4f,myThid) |
| 395 |
|
| 396 |
C Laplacian and bi-harmonic terms, Zonal Fluxes -> fZon |
| 397 |
CALL MOM_U_XVISCFLUX(bi,bj,k,uFld,v4F,fZon, |
| 398 |
I viscAh_D,viscA4_D,myThid) |
| 399 |
|
| 400 |
C Laplacian and bi-harmonic termis, Merid Fluxes -> fMer |
| 401 |
CALL MOM_U_YVISCFLUX(bi,bj,k,uFld,v4F,hFacZ,fMer, |
| 402 |
I viscAh_Z,viscA4_Z,myThid) |
| 403 |
|
| 404 |
C Eddy component of vertical flux (interior component only) -> fVrUp & fVrDw |
| 405 |
IF (.NOT.implicitViscosity) THEN |
| 406 |
CALL MOM_U_RVISCFLUX(bi,bj, k, uVel,KappaRU,fVrUp,myThid) |
| 407 |
CALL MOM_U_RVISCFLUX(bi,bj,k+1,uVel,KappaRU,fVrDw,myThid) |
| 408 |
ENDIF |
| 409 |
|
| 410 |
C-- Tendency is minus divergence of the fluxes |
| 411 |
DO j=jMin,jMax |
| 412 |
DO i=iMin,iMax |
| 413 |
guDiss(i,j) = |
| 414 |
#ifdef OLD_UV_GEOM |
| 415 |
& -_recip_hFacW(i,j,k,bi,bj)*recip_drF(k)/ |
| 416 |
& ( 0.5 _d 0*(rA(i,j,bi,bj)+rA(i-1,j,bi,bj)) ) |
| 417 |
#else |
| 418 |
& -_recip_hFacW(i,j,k,bi,bj)*recip_drF(k) |
| 419 |
& *recip_rAw(i,j,bi,bj) |
| 420 |
#endif |
| 421 |
& *( ( fZon(i,j ) - fZon(i-1,j) )*AhDudxFac |
| 422 |
& +( fMer(i,j+1) - fMer(i, j) )*AhDudyFac |
| 423 |
& +( fVrDw(i,j) - fVrUp(i,j) )*rkSign*ArDudrFac |
| 424 |
& ) |
| 425 |
ENDDO |
| 426 |
ENDDO |
| 427 |
|
| 428 |
#ifdef ALLOW_DIAGNOSTICS |
| 429 |
IF ( useDiagnostics ) THEN |
| 430 |
CALL DIAGNOSTICS_FILL(fZon, 'VISCx_Um',k,1,2,bi,bj,myThid) |
| 431 |
CALL DIAGNOSTICS_FILL(fMer, 'VISCy_Um',k,1,2,bi,bj,myThid) |
| 432 |
IF (.NOT.implicitViscosity) |
| 433 |
& CALL DIAGNOSTICS_FILL(fVrUp,'VISrE_Um',k,1,2,bi,bj,myThid) |
| 434 |
ENDIF |
| 435 |
#endif |
| 436 |
|
| 437 |
C-- No-slip and drag BCs appear as body forces in cell abutting topography |
| 438 |
IF (no_slip_sides) THEN |
| 439 |
C- No-slip BCs impose a drag at walls... |
| 440 |
CALL MOM_U_SIDEDRAG( |
| 441 |
I bi,bj,k, |
| 442 |
I uFld, v4f, hFacZ, |
| 443 |
I viscAh_Z,viscA4_Z, |
| 444 |
I harmonic,biharmonic,useVariableViscosity, |
| 445 |
O vF, |
| 446 |
I myThid) |
| 447 |
DO j=jMin,jMax |
| 448 |
DO i=iMin,iMax |
| 449 |
gUdiss(i,j) = gUdiss(i,j) + vF(i,j) |
| 450 |
ENDDO |
| 451 |
ENDDO |
| 452 |
ENDIF |
| 453 |
C- No-slip BCs impose a drag at bottom |
| 454 |
IF (bottomDragTerms) THEN |
| 455 |
CALL MOM_U_BOTTOMDRAG(bi,bj,k,uFld,KE,KappaRU,vF,myThid) |
| 456 |
DO j=jMin,jMax |
| 457 |
DO i=iMin,iMax |
| 458 |
gUdiss(i,j) = gUdiss(i,j) + vF(i,j) |
| 459 |
ENDDO |
| 460 |
ENDDO |
| 461 |
ENDIF |
| 462 |
|
| 463 |
C- endif momViscosity |
| 464 |
ENDIF |
| 465 |
|
| 466 |
C-- Forcing term (moved to timestep.F) |
| 467 |
c IF (momForcing) |
| 468 |
c & CALL EXTERNAL_FORCING_U( |
| 469 |
c I iMin,iMax,jMin,jMax,bi,bj,k, |
| 470 |
c I myTime,myThid) |
| 471 |
|
| 472 |
C-- Metric terms for curvilinear grid systems |
| 473 |
IF (useNHMTerms) THEN |
| 474 |
C o Non-hydrosatic metric terms |
| 475 |
CALL MOM_U_METRIC_NH(bi,bj,k,uFld,wVel,mT,myThid) |
| 476 |
DO j=jMin,jMax |
| 477 |
DO i=iMin,iMax |
| 478 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)+mTFacU*mT(i,j) |
| 479 |
ENDDO |
| 480 |
ENDDO |
| 481 |
ENDIF |
| 482 |
IF (usingSphericalPolarMTerms) THEN |
| 483 |
CALL MOM_U_METRIC_SPHERE(bi,bj,k,uFld,vFld,mT,myThid) |
| 484 |
DO j=jMin,jMax |
| 485 |
DO i=iMin,iMax |
| 486 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)+mTFacU*mT(i,j) |
| 487 |
ENDDO |
| 488 |
ENDDO |
| 489 |
ENDIF |
| 490 |
IF (usingCylindricalGrid) THEN |
| 491 |
CALL MOM_U_METRIC_CYLINDER(bi,bj,k,uFld,vFld,mT,myThid) |
| 492 |
DO j=jMin,jMax |
| 493 |
DO i=iMin,iMax |
| 494 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)+mTFacU*mT(i,j) |
| 495 |
ENDDO |
| 496 |
ENDDO |
| 497 |
ENDIF |
| 498 |
|
| 499 |
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7-|--+----| |
| 500 |
|
| 501 |
C---- Meridional momentum equation starts here |
| 502 |
|
| 503 |
IF (momAdvection) THEN |
| 504 |
C--- Calculate mean fluxes (advection) between cells for meridional flow. |
| 505 |
C Mean flow component of zonal flux -> fZon |
| 506 |
CALL MOM_V_ADV_UV(bi,bj,k,uTrans,vFld,fZon,myThid) |
| 507 |
|
| 508 |
C-- Meridional flux (fMer is at north face of "v" cell) |
| 509 |
C Mean flow component of meridional flux -> fMer |
| 510 |
CALL MOM_V_ADV_VV(bi,bj,k,vTrans,vFld,fMer,myThid) |
| 511 |
|
| 512 |
C-- Vertical flux (fVer is at upper face of "v" cell) |
| 513 |
C Mean flow component of vertical flux (at k+1) -> fVerV |
| 514 |
CALL MOM_V_ADV_WV( |
| 515 |
I bi,bj,k+1,vVel,wVel,rTransV, |
| 516 |
O fVerV(1-OLx,1-OLy,kDown), myThid ) |
| 517 |
|
| 518 |
C-- Tendency is minus divergence of the fluxes + coriolis + pressure term |
| 519 |
DO j=jMin,jMax |
| 520 |
DO i=iMin,iMax |
| 521 |
gV(i,j,k,bi,bj) = |
| 522 |
#ifdef OLD_UV_GEOM |
| 523 |
& -_recip_hFacS(i,j,k,bi,bj)*recip_drF(k)/ |
| 524 |
& ( 0.5 _d 0*(_rA(i,j,bi,bj)+_rA(i,j-1,bi,bj)) ) |
| 525 |
#else |
| 526 |
& -_recip_hFacS(i,j,k,bi,bj)*recip_drF(k) |
| 527 |
& *recip_rAs(i,j,bi,bj) |
| 528 |
#endif |
| 529 |
& *( ( fZon(i+1,j) - fZon(i,j ) )*uDvdxFac |
| 530 |
& +( fMer(i, j) - fMer(i,j-1) )*vDvdyFac |
| 531 |
& +(fVerV(i,j,kDown) - fVerV(i,j,kUp))*rkSign*rVelDvdrFac |
| 532 |
& ) |
| 533 |
ENDDO |
| 534 |
ENDDO |
| 535 |
|
| 536 |
#ifdef ALLOW_DIAGNOSTICS |
| 537 |
IF ( useDiagnostics ) THEN |
| 538 |
CALL DIAGNOSTICS_FILL(fZon,'ADVx_Vm ',k,1,2,bi,bj,myThid) |
| 539 |
CALL DIAGNOSTICS_FILL(fMer,'ADVy_Vm ',k,1,2,bi,bj,myThid) |
| 540 |
CALL DIAGNOSTICS_FILL(fVerV(1-Olx,1-Oly,kUp), |
| 541 |
& 'ADVrE_Vm',k,1,2,bi,bj,myThid) |
| 542 |
ENDIF |
| 543 |
#endif |
| 544 |
|
| 545 |
#ifdef NONLIN_FRSURF |
| 546 |
C-- account for 3.D divergence of the flow in rStar coordinate: |
| 547 |
# ifndef DISABLE_RSTAR_CODE |
| 548 |
IF ( select_rStar.GT.0 ) THEN |
| 549 |
DO j=jMin,jMax |
| 550 |
DO i=iMin,iMax |
| 551 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj) |
| 552 |
& - (rStarExpS(i,j,bi,bj) - 1. _d 0)/deltaTfreesurf |
| 553 |
& *vVel(i,j,k,bi,bj) |
| 554 |
ENDDO |
| 555 |
ENDDO |
| 556 |
ENDIF |
| 557 |
IF ( select_rStar.LT.0 ) THEN |
| 558 |
DO j=jMin,jMax |
| 559 |
DO i=iMin,iMax |
| 560 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj) |
| 561 |
& - rStarDhSDt(i,j,bi,bj)*vVel(i,j,k,bi,bj) |
| 562 |
ENDDO |
| 563 |
ENDDO |
| 564 |
ENDIF |
| 565 |
# endif /* DISABLE_RSTAR_CODE */ |
| 566 |
#endif /* NONLIN_FRSURF */ |
| 567 |
|
| 568 |
ELSE |
| 569 |
C- if momAdvection / else |
| 570 |
DO j=1-OLy,sNy+OLy |
| 571 |
DO i=1-OLx,sNx+OLx |
| 572 |
gV(i,j,k,bi,bj) = 0. _d 0 |
| 573 |
ENDDO |
| 574 |
ENDDO |
| 575 |
|
| 576 |
C- endif momAdvection. |
| 577 |
ENDIF |
| 578 |
|
| 579 |
IF (momViscosity) THEN |
| 580 |
C--- Calculate eddy fluxes (dissipation) between cells for meridional flow. |
| 581 |
C Bi-harmonic term del^2 V -> v4F |
| 582 |
IF (biharmonic) |
| 583 |
& CALL MOM_V_DEL2V(bi,bj,k,vFld,hFacZ,v4f,myThid) |
| 584 |
|
| 585 |
C Laplacian and bi-harmonic terms, Zonal Fluxes -> fZon |
| 586 |
CALL MOM_V_XVISCFLUX(bi,bj,k,vFld,v4f,hFacZ,fZon, |
| 587 |
I viscAh_Z,viscA4_Z,myThid) |
| 588 |
|
| 589 |
C Laplacian and bi-harmonic termis, Merid Fluxes -> fMer |
| 590 |
CALL MOM_V_YVISCFLUX(bi,bj,k,vFld,v4f,fMer, |
| 591 |
I viscAh_D,viscA4_D,myThid) |
| 592 |
|
| 593 |
C Eddy component of vertical flux (interior component only) -> fVrUp & fVrDw |
| 594 |
IF (.NOT.implicitViscosity) THEN |
| 595 |
CALL MOM_V_RVISCFLUX(bi,bj, k, vVel,KappaRV,fVrUp,myThid) |
| 596 |
CALL MOM_V_RVISCFLUX(bi,bj,k+1,vVel,KappaRV,fVrDw,myThid) |
| 597 |
ENDIF |
| 598 |
|
| 599 |
C-- Tendency is minus divergence of the fluxes + coriolis + pressure term |
| 600 |
DO j=jMin,jMax |
| 601 |
DO i=iMin,iMax |
| 602 |
gvDiss(i,j) = |
| 603 |
#ifdef OLD_UV_GEOM |
| 604 |
& -_recip_hFacS(i,j,k,bi,bj)*recip_drF(k)/ |
| 605 |
& ( 0.5 _d 0*(_rA(i,j,bi,bj)+_rA(i,j-1,bi,bj)) ) |
| 606 |
#else |
| 607 |
& -_recip_hFacS(i,j,k,bi,bj)*recip_drF(k) |
| 608 |
& *recip_rAs(i,j,bi,bj) |
| 609 |
#endif |
| 610 |
& *( ( fZon(i+1,j) - fZon(i,j ) )*AhDvdxFac |
| 611 |
& +( fMer(i, j) - fMer(i,j-1) )*AhDvdyFac |
| 612 |
& +( fVrDw(i,j) - fVrUp(i,j) )*rkSign*ArDvdrFac |
| 613 |
& ) |
| 614 |
ENDDO |
| 615 |
ENDDO |
| 616 |
|
| 617 |
#ifdef ALLOW_DIAGNOSTICS |
| 618 |
IF ( useDiagnostics ) THEN |
| 619 |
CALL DIAGNOSTICS_FILL(fZon, 'VISCx_Vm',k,1,2,bi,bj,myThid) |
| 620 |
CALL DIAGNOSTICS_FILL(fMer, 'VISCy_Vm',k,1,2,bi,bj,myThid) |
| 621 |
IF (.NOT.implicitViscosity) |
| 622 |
& CALL DIAGNOSTICS_FILL(fVrUp,'VISrE_Vm',k,1,2,bi,bj,myThid) |
| 623 |
ENDIF |
| 624 |
#endif |
| 625 |
|
| 626 |
C-- No-slip and drag BCs appear as body forces in cell abutting topography |
| 627 |
IF (no_slip_sides) THEN |
| 628 |
C- No-slip BCs impose a drag at walls... |
| 629 |
CALL MOM_V_SIDEDRAG( |
| 630 |
I bi,bj,k, |
| 631 |
I vFld, v4f, hFacZ, |
| 632 |
I viscAh_Z,viscA4_Z, |
| 633 |
I harmonic,biharmonic,useVariableViscosity, |
| 634 |
O vF, |
| 635 |
I myThid) |
| 636 |
DO j=jMin,jMax |
| 637 |
DO i=iMin,iMax |
| 638 |
gvDiss(i,j) = gvDiss(i,j) + vF(i,j) |
| 639 |
ENDDO |
| 640 |
ENDDO |
| 641 |
ENDIF |
| 642 |
C- No-slip BCs impose a drag at bottom |
| 643 |
IF (bottomDragTerms) THEN |
| 644 |
CALL MOM_V_BOTTOMDRAG(bi,bj,k,vFld,KE,KappaRV,vF,myThid) |
| 645 |
DO j=jMin,jMax |
| 646 |
DO i=iMin,iMax |
| 647 |
gvDiss(i,j) = gvDiss(i,j) + vF(i,j) |
| 648 |
ENDDO |
| 649 |
ENDDO |
| 650 |
ENDIF |
| 651 |
|
| 652 |
C- endif momViscosity |
| 653 |
ENDIF |
| 654 |
|
| 655 |
C-- Forcing term (moved to timestep.F) |
| 656 |
c IF (momForcing) |
| 657 |
c & CALL EXTERNAL_FORCING_V( |
| 658 |
c I iMin,iMax,jMin,jMax,bi,bj,k, |
| 659 |
c I myTime,myThid) |
| 660 |
|
| 661 |
C-- Metric terms for curvilinear grid systems |
| 662 |
IF (useNHMTerms) THEN |
| 663 |
C o Spherical polar grid metric terms |
| 664 |
CALL MOM_V_METRIC_NH(bi,bj,k,vFld,wVel,mT,myThid) |
| 665 |
DO j=jMin,jMax |
| 666 |
DO i=iMin,iMax |
| 667 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj)+mTFacV*mT(i,j) |
| 668 |
ENDDO |
| 669 |
ENDDO |
| 670 |
ENDIF |
| 671 |
IF (usingSphericalPolarMTerms) THEN |
| 672 |
CALL MOM_V_METRIC_SPHERE(bi,bj,k,uFld,mT,myThid) |
| 673 |
DO j=jMin,jMax |
| 674 |
DO i=iMin,iMax |
| 675 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj)+mTFacV*mT(i,j) |
| 676 |
ENDDO |
| 677 |
ENDDO |
| 678 |
ENDIF |
| 679 |
IF (usingCylindricalGrid) THEN |
| 680 |
CALL MOM_V_METRIC_CYLINDER(bi,bj,k,uFld,vFld,mT,myThid) |
| 681 |
DO j=jMin,jMax |
| 682 |
DO i=iMin,iMax |
| 683 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj)+mTFacV*mT(i,j) |
| 684 |
ENDDO |
| 685 |
ENDDO |
| 686 |
ENDIF |
| 687 |
|
| 688 |
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7-|--+----| |
| 689 |
|
| 690 |
C-- Coriolis term |
| 691 |
C Note. As coded here, coriolis will not work with "thin walls" |
| 692 |
c IF (useCDscheme) THEN |
| 693 |
c CALL MOM_CDSCHEME(bi,bj,k,dPhiHydX,dPhiHydY,myThid) |
| 694 |
c ELSE |
| 695 |
IF (.NOT.useCDscheme) THEN |
| 696 |
CALL MOM_U_CORIOLIS(bi,bj,k,vFld,cf,myThid) |
| 697 |
DO j=jMin,jMax |
| 698 |
DO i=iMin,iMax |
| 699 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)+fuFac*cf(i,j) |
| 700 |
ENDDO |
| 701 |
ENDDO |
| 702 |
#ifdef ALLOW_DIAGNOSTICS |
| 703 |
IF ( useDiagnostics ) |
| 704 |
& CALL DIAGNOSTICS_FILL(cf,'Um_Cori ',k,1,2,bi,bj,myThid) |
| 705 |
#endif |
| 706 |
CALL MOM_V_CORIOLIS(bi,bj,k,uFld,cf,myThid) |
| 707 |
DO j=jMin,jMax |
| 708 |
DO i=iMin,iMax |
| 709 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj)+fvFac*cf(i,j) |
| 710 |
ENDDO |
| 711 |
ENDDO |
| 712 |
#ifdef ALLOW_DIAGNOSTICS |
| 713 |
IF ( useDiagnostics ) |
| 714 |
& CALL DIAGNOSTICS_FILL(cf,'Vm_Cori ',k,1,2,bi,bj,myThid) |
| 715 |
#endif |
| 716 |
ENDIF |
| 717 |
|
| 718 |
IF (nonHydrostatic.OR.quasiHydrostatic) THEN |
| 719 |
CALL MOM_U_CORIOLIS_NH(bi,bj,k,wVel,cf,myThid) |
| 720 |
DO j=jMin,jMax |
| 721 |
DO i=iMin,iMax |
| 722 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)+fuFac*cf(i,j) |
| 723 |
ENDDO |
| 724 |
ENDDO |
| 725 |
ENDIF |
| 726 |
|
| 727 |
C-- Set du/dt & dv/dt on boundaries to zero |
| 728 |
DO j=jMin,jMax |
| 729 |
DO i=iMin,iMax |
| 730 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)*_maskW(i,j,k,bi,bj) |
| 731 |
guDiss(i,j) = guDiss(i,j) *_maskW(i,j,k,bi,bj) |
| 732 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj)*_maskS(i,j,k,bi,bj) |
| 733 |
gvDiss(i,j) = gvDiss(i,j) *_maskS(i,j,k,bi,bj) |
| 734 |
ENDDO |
| 735 |
ENDDO |
| 736 |
|
| 737 |
#ifdef ALLOW_DIAGNOSTICS |
| 738 |
IF ( useDiagnostics ) THEN |
| 739 |
CALL DIAGNOSTICS_FILL(KE, 'momKE ',k,1,2,bi,bj,myThid) |
| 740 |
CALL DIAGNOSTICS_FILL(gU(1-Olx,1-Oly,k,bi,bj), |
| 741 |
& 'Um_Advec',k,1,2,bi,bj,myThid) |
| 742 |
CALL DIAGNOSTICS_FILL(gV(1-Olx,1-Oly,k,bi,bj), |
| 743 |
& 'Vm_Advec',k,1,2,bi,bj,myThid) |
| 744 |
IF (momViscosity) THEN |
| 745 |
CALL DIAGNOSTICS_FILL(guDiss,'Um_Diss ',k,1,2,bi,bj,myThid) |
| 746 |
CALL DIAGNOSTICS_FILL(gvDiss,'Vm_Diss ',k,1,2,bi,bj,myThid) |
| 747 |
ENDIF |
| 748 |
ENDIF |
| 749 |
#endif /* ALLOW_DIAGNOSTICS */ |
| 750 |
|
| 751 |
RETURN |
| 752 |
END |
Parent Directory
| 
Revision Log
| 
Revision Graph