| 1 |
C $Header: /u/gcmpack/MITgcm/pkg/mom_fluxform/mom_fluxform.F,v 1.32 2006/02/07 11:46:18 mlosch Exp $ |
| 2 |
C $Name: $ |
| 3 |
|
| 4 |
CBOI |
| 5 |
C !TITLE: pkg/mom\_advdiff |
| 6 |
C !AUTHORS: adcroft@mit.edu |
| 7 |
C !INTRODUCTION: Flux-form Momentum Equations Package |
| 8 |
C |
| 9 |
C Package "mom\_fluxform" provides methods for calculating explicit terms |
| 10 |
C in the momentum equation cast in flux-form: |
| 11 |
C \begin{eqnarray*} |
| 12 |
C G^u & = & -\frac{1}{\rho} \partial_x \phi_h |
| 13 |
C -\nabla \cdot {\bf v} u |
| 14 |
C -fv |
| 15 |
C +\frac{1}{\rho} \nabla \cdot {\bf \tau}^x |
| 16 |
C + \mbox{metrics} |
| 17 |
C \\ |
| 18 |
C G^v & = & -\frac{1}{\rho} \partial_y \phi_h |
| 19 |
C -\nabla \cdot {\bf v} v |
| 20 |
C +fu |
| 21 |
C +\frac{1}{\rho} \nabla \cdot {\bf \tau}^y |
| 22 |
C + \mbox{metrics} |
| 23 |
C \end{eqnarray*} |
| 24 |
C where ${\bf v}=(u,v,w)$ and $\tau$, the stress tensor, includes surface |
| 25 |
C stresses as well as internal viscous stresses. |
| 26 |
CEOI |
| 27 |
|
| 28 |
#include "MOM_FLUXFORM_OPTIONS.h" |
| 29 |
|
| 30 |
CBOP |
| 31 |
C !ROUTINE: MOM_FLUXFORM |
| 32 |
|
| 33 |
C !INTERFACE: ========================================================== |
| 34 |
SUBROUTINE MOM_FLUXFORM( |
| 35 |
I bi,bj,iMin,iMax,jMin,jMax,k,kUp,kDown, |
| 36 |
I KappaRU, KappaRV, |
| 37 |
U fVerU, fVerV, |
| 38 |
O guDiss, gvDiss, |
| 39 |
I myTime, myIter, myThid) |
| 40 |
|
| 41 |
C !DESCRIPTION: |
| 42 |
C Calculates all the horizontal accelerations except for the implicit surface |
| 43 |
C pressure gradient and implciit vertical viscosity. |
| 44 |
|
| 45 |
C !USES: =============================================================== |
| 46 |
C == Global variables == |
| 47 |
IMPLICIT NONE |
| 48 |
#include "SIZE.h" |
| 49 |
#include "DYNVARS.h" |
| 50 |
#include "FFIELDS.h" |
| 51 |
#include "EEPARAMS.h" |
| 52 |
#include "PARAMS.h" |
| 53 |
#include "GRID.h" |
| 54 |
#include "SURFACE.h" |
| 55 |
|
| 56 |
C !INPUT PARAMETERS: =================================================== |
| 57 |
C bi,bj :: tile indices |
| 58 |
C iMin,iMax,jMin,jMAx :: loop ranges |
| 59 |
C k :: vertical level |
| 60 |
C kUp :: =1 or 2 for consecutive k |
| 61 |
C kDown :: =2 or 1 for consecutive k |
| 62 |
C KappaRU :: vertical viscosity |
| 63 |
C KappaRV :: vertical viscosity |
| 64 |
C fVerU :: vertical flux of U, 2 1/2 dim for pipe-lining |
| 65 |
C fVerV :: vertical flux of V, 2 1/2 dim for pipe-lining |
| 66 |
C guDiss :: dissipation tendency (all explicit terms), u component |
| 67 |
C gvDiss :: dissipation tendency (all explicit terms), v component |
| 68 |
C myTime :: current time |
| 69 |
C myIter :: current time-step number |
| 70 |
C myThid :: thread number |
| 71 |
INTEGER bi,bj,iMin,iMax,jMin,jMax |
| 72 |
INTEGER k,kUp,kDown |
| 73 |
_RL KappaRU(1-OLx:sNx+OLx,1-OLy:sNy+OLy,Nr) |
| 74 |
_RL KappaRV(1-OLx:sNx+OLx,1-OLy:sNy+OLy,Nr) |
| 75 |
_RL fVerU(1-OLx:sNx+OLx,1-OLy:sNy+OLy,2) |
| 76 |
_RL fVerV(1-OLx:sNx+OLx,1-OLy:sNy+OLy,2) |
| 77 |
_RL guDiss(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 78 |
_RL gvDiss(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 79 |
_RL myTime |
| 80 |
INTEGER myIter |
| 81 |
INTEGER myThid |
| 82 |
|
| 83 |
C !OUTPUT PARAMETERS: ================================================== |
| 84 |
C None - updates gU() and gV() in common blocks |
| 85 |
|
| 86 |
C !LOCAL VARIABLES: ==================================================== |
| 87 |
C i,j :: loop indices |
| 88 |
C vF :: viscous flux |
| 89 |
C v4F :: bi-harmonic viscous flux |
| 90 |
C cF :: Coriolis acceleration |
| 91 |
C mT :: Metric terms |
| 92 |
C fZon :: zonal fluxes |
| 93 |
C fMer :: meridional fluxes |
| 94 |
C fVrUp,fVrDw :: vertical viscous fluxes at interface k-1 & k |
| 95 |
INTEGER i,j |
| 96 |
_RL vF(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 97 |
_RL v4F(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 98 |
_RL cF(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 99 |
_RL mT(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 100 |
_RL fZon(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 101 |
_RL fMer(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 102 |
_RL fVrUp(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 103 |
_RL fVrDw(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 104 |
C afFacMom :: Tracer parameters for turning terms on and off. |
| 105 |
C vfFacMom |
| 106 |
C pfFacMom afFacMom - Advective terms |
| 107 |
C cfFacMom vfFacMom - Eddy viscosity terms |
| 108 |
C mtFacMom pfFacMom - Pressure terms |
| 109 |
C cfFacMom - Coriolis terms |
| 110 |
C foFacMom - Forcing |
| 111 |
C mtFacMom - Metric term |
| 112 |
C uDudxFac, AhDudxFac, etc ... individual term parameters for switching terms off |
| 113 |
_RS hFacZ(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 114 |
_RS r_hFacZ(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 115 |
_RS xA(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 116 |
_RS yA(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 117 |
_RL uTrans(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 118 |
_RL vTrans(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 119 |
_RL uFld(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 120 |
_RL vFld(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 121 |
_RL rTransU(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 122 |
_RL rTransV(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 123 |
_RL KE(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 124 |
_RL viscAh_D(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 125 |
_RL viscAh_Z(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 126 |
_RL viscA4_D(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 127 |
_RL viscA4_Z(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 128 |
_RL vort3(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 129 |
_RL hDiv(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 130 |
_RL strain(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 131 |
_RL tension(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
| 132 |
_RL uDudxFac |
| 133 |
_RL AhDudxFac |
| 134 |
_RL vDudyFac |
| 135 |
_RL AhDudyFac |
| 136 |
_RL rVelDudrFac |
| 137 |
_RL ArDudrFac |
| 138 |
_RL fuFac |
| 139 |
_RL mtFacU |
| 140 |
_RL mtNHFacU |
| 141 |
_RL uDvdxFac |
| 142 |
_RL AhDvdxFac |
| 143 |
_RL vDvdyFac |
| 144 |
_RL AhDvdyFac |
| 145 |
_RL rVelDvdrFac |
| 146 |
_RL ArDvdrFac |
| 147 |
_RL fvFac |
| 148 |
_RL mtFacV |
| 149 |
_RL mtNHFacV |
| 150 |
_RL sideMaskFac |
| 151 |
LOGICAL bottomDragTerms,harmonic,biharmonic,useVariableViscosity |
| 152 |
CEOP |
| 153 |
|
| 154 |
C Initialise intermediate terms |
| 155 |
DO j=1-OLy,sNy+OLy |
| 156 |
DO i=1-OLx,sNx+OLx |
| 157 |
vF(i,j) = 0. |
| 158 |
v4F(i,j) = 0. |
| 159 |
cF(i,j) = 0. |
| 160 |
mT(i,j) = 0. |
| 161 |
fZon(i,j) = 0. |
| 162 |
fMer(i,j) = 0. |
| 163 |
fVrUp(i,j)= 0. |
| 164 |
fVrDw(i,j)= 0. |
| 165 |
rTransU(i,j)= 0. |
| 166 |
rTransV(i,j)= 0. |
| 167 |
strain(i,j) = 0. |
| 168 |
tension(i,j)= 0. |
| 169 |
guDiss(i,j) = 0. |
| 170 |
gvDiss(i,j) = 0. |
| 171 |
#ifdef ALLOW_AUTODIFF_TAMC |
| 172 |
vort3(i,j) = 0. _d 0 |
| 173 |
strain(i,j) = 0. _d 0 |
| 174 |
tension(i,j) = 0. _d 0 |
| 175 |
#endif |
| 176 |
ENDDO |
| 177 |
ENDDO |
| 178 |
|
| 179 |
C-- Term by term tracer parmeters |
| 180 |
C o U momentum equation |
| 181 |
uDudxFac = afFacMom*1. |
| 182 |
AhDudxFac = vfFacMom*1. |
| 183 |
vDudyFac = afFacMom*1. |
| 184 |
AhDudyFac = vfFacMom*1. |
| 185 |
rVelDudrFac = afFacMom*1. |
| 186 |
ArDudrFac = vfFacMom*1. |
| 187 |
mtFacU = mtFacMom*1. |
| 188 |
mtNHFacU = 1. |
| 189 |
fuFac = cfFacMom*1. |
| 190 |
C o V momentum equation |
| 191 |
uDvdxFac = afFacMom*1. |
| 192 |
AhDvdxFac = vfFacMom*1. |
| 193 |
vDvdyFac = afFacMom*1. |
| 194 |
AhDvdyFac = vfFacMom*1. |
| 195 |
rVelDvdrFac = afFacMom*1. |
| 196 |
ArDvdrFac = vfFacMom*1. |
| 197 |
mtFacV = mtFacMom*1. |
| 198 |
mtNHFacV = 1. |
| 199 |
fvFac = cfFacMom*1. |
| 200 |
|
| 201 |
IF (implicitViscosity) THEN |
| 202 |
ArDudrFac = 0. |
| 203 |
ArDvdrFac = 0. |
| 204 |
ENDIF |
| 205 |
|
| 206 |
C note: using standard stencil (no mask) results in under-estimating |
| 207 |
C vorticity at a no-slip boundary by a factor of 2 = sideDragFactor |
| 208 |
IF ( no_slip_sides ) THEN |
| 209 |
sideMaskFac = sideDragFactor |
| 210 |
ELSE |
| 211 |
sideMaskFac = 0. _d 0 |
| 212 |
ENDIF |
| 213 |
|
| 214 |
IF ( no_slip_bottom |
| 215 |
& .OR. bottomDragQuadratic.NE.0. |
| 216 |
& .OR. bottomDragLinear.NE.0.) THEN |
| 217 |
bottomDragTerms=.TRUE. |
| 218 |
ELSE |
| 219 |
bottomDragTerms=.FALSE. |
| 220 |
ENDIF |
| 221 |
|
| 222 |
C-- Calculate open water fraction at vorticity points |
| 223 |
CALL MOM_CALC_HFACZ(bi,bj,k,hFacZ,r_hFacZ,myThid) |
| 224 |
|
| 225 |
C---- Calculate common quantities used in both U and V equations |
| 226 |
C Calculate tracer cell face open areas |
| 227 |
DO j=1-OLy,sNy+OLy |
| 228 |
DO i=1-OLx,sNx+OLx |
| 229 |
xA(i,j) = _dyG(i,j,bi,bj) |
| 230 |
& *drF(k)*_hFacW(i,j,k,bi,bj) |
| 231 |
yA(i,j) = _dxG(i,j,bi,bj) |
| 232 |
& *drF(k)*_hFacS(i,j,k,bi,bj) |
| 233 |
ENDDO |
| 234 |
ENDDO |
| 235 |
|
| 236 |
C Make local copies of horizontal flow field |
| 237 |
DO j=1-OLy,sNy+OLy |
| 238 |
DO i=1-OLx,sNx+OLx |
| 239 |
uFld(i,j) = uVel(i,j,k,bi,bj) |
| 240 |
vFld(i,j) = vVel(i,j,k,bi,bj) |
| 241 |
ENDDO |
| 242 |
ENDDO |
| 243 |
|
| 244 |
C Calculate velocity field "volume transports" through tracer cell faces. |
| 245 |
DO j=1-OLy,sNy+OLy |
| 246 |
DO i=1-OLx,sNx+OLx |
| 247 |
uTrans(i,j) = uFld(i,j)*xA(i,j) |
| 248 |
vTrans(i,j) = vFld(i,j)*yA(i,j) |
| 249 |
ENDDO |
| 250 |
ENDDO |
| 251 |
|
| 252 |
CALL MOM_CALC_KE(bi,bj,k,2,uFld,vFld,KE,myThid) |
| 253 |
IF ( momViscosity) THEN |
| 254 |
CALL MOM_CALC_HDIV(bi,bj,k,2,uFld,vFld,hDiv,myThid) |
| 255 |
CALL MOM_CALC_RELVORT3(bi,bj,k,uFld,vFld,hFacZ,vort3,myThid) |
| 256 |
CALL MOM_CALC_TENSION(bi,bj,k,uFld,vFld,tension,myThid) |
| 257 |
CALL MOM_CALC_STRAIN(bi,bj,k,uFld,vFld,hFacZ,strain,myThid) |
| 258 |
DO j=1-Oly,sNy+Oly |
| 259 |
DO i=1-Olx,sNx+Olx |
| 260 |
IF ( hFacZ(i,j).EQ.0. ) THEN |
| 261 |
vort3(i,j) = sideMaskFac*vort3(i,j) |
| 262 |
strain(i,j) = sideMaskFac*strain(i,j) |
| 263 |
ENDIF |
| 264 |
ENDDO |
| 265 |
ENDDO |
| 266 |
#ifdef ALLOW_DIAGNOSTICS |
| 267 |
IF ( useDiagnostics ) THEN |
| 268 |
CALL DIAGNOSTICS_FILL(hDiv, 'momHDiv ',k,1,2,bi,bj,myThid) |
| 269 |
CALL DIAGNOSTICS_FILL(vort3, 'momVort3',k,1,2,bi,bj,myThid) |
| 270 |
CALL DIAGNOSTICS_FILL(tension,'Tension ',k,1,2,bi,bj,myThid) |
| 271 |
CALL DIAGNOSTICS_FILL(strain, 'Strain ',k,1,2,bi,bj,myThid) |
| 272 |
ENDIF |
| 273 |
#endif |
| 274 |
ENDIF |
| 275 |
|
| 276 |
C--- First call (k=1): compute vertical adv. flux fVerU(kUp) & fVerV(kUp) |
| 277 |
IF (momAdvection.AND.k.EQ.1) THEN |
| 278 |
|
| 279 |
C- Calculate vertical transports above U & V points (West & South face): |
| 280 |
CALL MOM_CALC_RTRANS( k, bi, bj, |
| 281 |
O rTransU, rTransV, |
| 282 |
I myTime, myIter, myThid) |
| 283 |
|
| 284 |
C- Free surface correction term (flux at k=1) |
| 285 |
CALL MOM_U_ADV_WU( bi,bj,k,uVel,wVel,rTransU, |
| 286 |
O fVerU(1-OLx,1-OLy,kUp), myThid ) |
| 287 |
|
| 288 |
CALL MOM_V_ADV_WV( bi,bj,k,vVel,wVel,rTransV, |
| 289 |
O fVerV(1-OLx,1-OLy,kUp), myThid ) |
| 290 |
|
| 291 |
C--- endif momAdvection & k=1 |
| 292 |
ENDIF |
| 293 |
|
| 294 |
|
| 295 |
C--- Calculate vertical transports (at k+1) below U & V points : |
| 296 |
IF (momAdvection) THEN |
| 297 |
CALL MOM_CALC_RTRANS( k+1, bi, bj, |
| 298 |
O rTransU, rTransV, |
| 299 |
I myTime, myIter, myThid) |
| 300 |
ENDIF |
| 301 |
|
| 302 |
IF (momViscosity) THEN |
| 303 |
CALL MOM_CALC_VISC( |
| 304 |
I bi,bj,k, |
| 305 |
O viscAh_Z,viscAh_D,viscA4_Z,viscA4_D, |
| 306 |
O harmonic,biharmonic,useVariableViscosity, |
| 307 |
I hDiv,vort3,tension,strain,KE,hFacZ, |
| 308 |
I myThid) |
| 309 |
ENDIF |
| 310 |
|
| 311 |
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7-|--+----| |
| 312 |
|
| 313 |
C---- Zonal momentum equation starts here |
| 314 |
|
| 315 |
IF (momAdvection) THEN |
| 316 |
C--- Calculate mean fluxes (advection) between cells for zonal flow. |
| 317 |
|
| 318 |
C-- Zonal flux (fZon is at east face of "u" cell) |
| 319 |
C Mean flow component of zonal flux -> fZon |
| 320 |
CALL MOM_U_ADV_UU(bi,bj,k,uTrans,uFld,fZon,myThid) |
| 321 |
|
| 322 |
C-- Meridional flux (fMer is at south face of "u" cell) |
| 323 |
C Mean flow component of meridional flux -> fMer |
| 324 |
CALL MOM_U_ADV_VU(bi,bj,k,vTrans,uFld,fMer,myThid) |
| 325 |
|
| 326 |
C-- Vertical flux (fVer is at upper face of "u" cell) |
| 327 |
C Mean flow component of vertical flux (at k+1) -> fVer |
| 328 |
CALL MOM_U_ADV_WU( |
| 329 |
I bi,bj,k+1,uVel,wVel,rTransU, |
| 330 |
O fVerU(1-OLx,1-OLy,kDown), myThid ) |
| 331 |
|
| 332 |
C-- Tendency is minus divergence of the fluxes + coriolis + pressure term |
| 333 |
DO j=jMin,jMax |
| 334 |
DO i=iMin,iMax |
| 335 |
gU(i,j,k,bi,bj) = |
| 336 |
#ifdef OLD_UV_GEOM |
| 337 |
& -_recip_hFacW(i,j,k,bi,bj)*recip_drF(k)/ |
| 338 |
& ( 0.5 _d 0*(rA(i,j,bi,bj)+rA(i-1,j,bi,bj)) ) |
| 339 |
#else |
| 340 |
& -_recip_hFacW(i,j,k,bi,bj)*recip_drF(k) |
| 341 |
& *recip_rAw(i,j,bi,bj) |
| 342 |
#endif |
| 343 |
& *( ( fZon(i,j ) - fZon(i-1,j) )*uDudxFac |
| 344 |
& +( fMer(i,j+1) - fMer(i, j) )*vDudyFac |
| 345 |
& +(fVerU(i,j,kDown) - fVerU(i,j,kUp))*rkSign*rVelDudrFac |
| 346 |
& ) |
| 347 |
ENDDO |
| 348 |
ENDDO |
| 349 |
|
| 350 |
#ifdef ALLOW_DIAGNOSTICS |
| 351 |
IF ( useDiagnostics ) THEN |
| 352 |
CALL DIAGNOSTICS_FILL(fZon,'ADVx_Um ',k,1,2,bi,bj,myThid) |
| 353 |
CALL DIAGNOSTICS_FILL(fMer,'ADVy_Um ',k,1,2,bi,bj,myThid) |
| 354 |
CALL DIAGNOSTICS_FILL(fVerU(1-Olx,1-Oly,kUp), |
| 355 |
& 'ADVrE_Um',k,1,2,bi,bj,myThid) |
| 356 |
ENDIF |
| 357 |
#endif |
| 358 |
|
| 359 |
#ifdef NONLIN_FRSURF |
| 360 |
C-- account for 3.D divergence of the flow in rStar coordinate: |
| 361 |
# ifndef DISABLE_RSTAR_CODE |
| 362 |
IF ( select_rStar.GT.0 ) THEN |
| 363 |
DO j=jMin,jMax |
| 364 |
DO i=iMin,iMax |
| 365 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj) |
| 366 |
& - (rStarExpW(i,j,bi,bj) - 1. _d 0)/deltaTfreesurf |
| 367 |
& *uVel(i,j,k,bi,bj) |
| 368 |
ENDDO |
| 369 |
ENDDO |
| 370 |
ENDIF |
| 371 |
IF ( select_rStar.LT.0 ) THEN |
| 372 |
DO j=jMin,jMax |
| 373 |
DO i=iMin,iMax |
| 374 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj) |
| 375 |
& - rStarDhWDt(i,j,bi,bj)*uVel(i,j,k,bi,bj) |
| 376 |
ENDDO |
| 377 |
ENDDO |
| 378 |
ENDIF |
| 379 |
# endif /* DISABLE_RSTAR_CODE */ |
| 380 |
#endif /* NONLIN_FRSURF */ |
| 381 |
|
| 382 |
ELSE |
| 383 |
C- if momAdvection / else |
| 384 |
DO j=1-OLy,sNy+OLy |
| 385 |
DO i=1-OLx,sNx+OLx |
| 386 |
gU(i,j,k,bi,bj) = 0. _d 0 |
| 387 |
ENDDO |
| 388 |
ENDDO |
| 389 |
|
| 390 |
C- endif momAdvection. |
| 391 |
ENDIF |
| 392 |
|
| 393 |
IF (momViscosity) THEN |
| 394 |
C--- Calculate eddy fluxes (dissipation) between cells for zonal flow. |
| 395 |
|
| 396 |
C Bi-harmonic term del^2 U -> v4F |
| 397 |
IF (biharmonic) |
| 398 |
& CALL MOM_U_DEL2U(bi,bj,k,uFld,hFacZ,v4f,myThid) |
| 399 |
|
| 400 |
C Laplacian and bi-harmonic terms, Zonal Fluxes -> fZon |
| 401 |
CALL MOM_U_XVISCFLUX(bi,bj,k,uFld,v4F,fZon, |
| 402 |
I viscAh_D,viscA4_D,myThid) |
| 403 |
|
| 404 |
C Laplacian and bi-harmonic termis, Merid Fluxes -> fMer |
| 405 |
CALL MOM_U_YVISCFLUX(bi,bj,k,uFld,v4F,hFacZ,fMer, |
| 406 |
I viscAh_Z,viscA4_Z,myThid) |
| 407 |
|
| 408 |
C Eddy component of vertical flux (interior component only) -> fVrUp & fVrDw |
| 409 |
IF (.NOT.implicitViscosity) THEN |
| 410 |
CALL MOM_U_RVISCFLUX(bi,bj, k, uVel,KappaRU,fVrUp,myThid) |
| 411 |
CALL MOM_U_RVISCFLUX(bi,bj,k+1,uVel,KappaRU,fVrDw,myThid) |
| 412 |
ENDIF |
| 413 |
|
| 414 |
C-- Tendency is minus divergence of the fluxes |
| 415 |
DO j=jMin,jMax |
| 416 |
DO i=iMin,iMax |
| 417 |
guDiss(i,j) = |
| 418 |
#ifdef OLD_UV_GEOM |
| 419 |
& -_recip_hFacW(i,j,k,bi,bj)*recip_drF(k)/ |
| 420 |
& ( 0.5 _d 0*(rA(i,j,bi,bj)+rA(i-1,j,bi,bj)) ) |
| 421 |
#else |
| 422 |
& -_recip_hFacW(i,j,k,bi,bj)*recip_drF(k) |
| 423 |
& *recip_rAw(i,j,bi,bj) |
| 424 |
#endif |
| 425 |
& *( ( fZon(i,j ) - fZon(i-1,j) )*AhDudxFac |
| 426 |
& +( fMer(i,j+1) - fMer(i, j) )*AhDudyFac |
| 427 |
& +( fVrDw(i,j) - fVrUp(i,j) )*rkSign*ArDudrFac |
| 428 |
& ) |
| 429 |
ENDDO |
| 430 |
ENDDO |
| 431 |
|
| 432 |
#ifdef ALLOW_DIAGNOSTICS |
| 433 |
IF ( useDiagnostics ) THEN |
| 434 |
CALL DIAGNOSTICS_FILL(fZon, 'VISCx_Um',k,1,2,bi,bj,myThid) |
| 435 |
CALL DIAGNOSTICS_FILL(fMer, 'VISCy_Um',k,1,2,bi,bj,myThid) |
| 436 |
IF (.NOT.implicitViscosity) |
| 437 |
& CALL DIAGNOSTICS_FILL(fVrUp,'VISrE_Um',k,1,2,bi,bj,myThid) |
| 438 |
ENDIF |
| 439 |
#endif |
| 440 |
|
| 441 |
C-- No-slip and drag BCs appear as body forces in cell abutting topography |
| 442 |
IF (no_slip_sides) THEN |
| 443 |
C- No-slip BCs impose a drag at walls... |
| 444 |
CALL MOM_U_SIDEDRAG( |
| 445 |
I bi,bj,k, |
| 446 |
I uFld, v4f, hFacZ, |
| 447 |
I viscAh_Z,viscA4_Z, |
| 448 |
I harmonic,biharmonic,useVariableViscosity, |
| 449 |
O vF, |
| 450 |
I myThid) |
| 451 |
DO j=jMin,jMax |
| 452 |
DO i=iMin,iMax |
| 453 |
gUdiss(i,j) = gUdiss(i,j) + vF(i,j) |
| 454 |
ENDDO |
| 455 |
ENDDO |
| 456 |
ENDIF |
| 457 |
C- No-slip BCs impose a drag at bottom |
| 458 |
IF (bottomDragTerms) THEN |
| 459 |
CALL MOM_U_BOTTOMDRAG(bi,bj,k,uFld,KE,KappaRU,vF,myThid) |
| 460 |
DO j=jMin,jMax |
| 461 |
DO i=iMin,iMax |
| 462 |
gUdiss(i,j) = gUdiss(i,j) + vF(i,j) |
| 463 |
ENDDO |
| 464 |
ENDDO |
| 465 |
ENDIF |
| 466 |
|
| 467 |
#ifdef ALLOW_SHELFICE |
| 468 |
IF (useShelfIce) THEN |
| 469 |
CALL SHELFICE_U_DRAG(bi,bj,k,uFld,KE,KappaRU,vF,myThid) |
| 470 |
DO j=jMin,jMax |
| 471 |
DO i=iMin,iMax |
| 472 |
gUdiss(i,j) = gUdiss(i,j) + vF(i,j) |
| 473 |
ENDDO |
| 474 |
ENDDO |
| 475 |
ENDIF |
| 476 |
#endif /* ALLOW_SHELFICE */ |
| 477 |
|
| 478 |
C- endif momViscosity |
| 479 |
ENDIF |
| 480 |
|
| 481 |
C-- Forcing term (moved to timestep.F) |
| 482 |
c IF (momForcing) |
| 483 |
c & CALL EXTERNAL_FORCING_U( |
| 484 |
c I iMin,iMax,jMin,jMax,bi,bj,k, |
| 485 |
c I myTime,myThid) |
| 486 |
|
| 487 |
C-- Metric terms for curvilinear grid systems |
| 488 |
IF (useNHMTerms) THEN |
| 489 |
C o Non-Hydrostatic (spherical) metric terms |
| 490 |
CALL MOM_U_METRIC_NH(bi,bj,k,uFld,wVel,mT,myThid) |
| 491 |
DO j=jMin,jMax |
| 492 |
DO i=iMin,iMax |
| 493 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)+mtNHFacU*mT(i,j) |
| 494 |
ENDDO |
| 495 |
ENDDO |
| 496 |
ENDIF |
| 497 |
IF ( usingSphericalPolarGrid .AND. metricTerms ) THEN |
| 498 |
C o Spherical polar grid metric terms |
| 499 |
CALL MOM_U_METRIC_SPHERE(bi,bj,k,uFld,vFld,mT,myThid) |
| 500 |
DO j=jMin,jMax |
| 501 |
DO i=iMin,iMax |
| 502 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)+mtFacU*mT(i,j) |
| 503 |
ENDDO |
| 504 |
ENDDO |
| 505 |
ENDIF |
| 506 |
IF ( usingCylindricalGrid .AND. metricTerms ) THEN |
| 507 |
C o Cylindrical grid metric terms |
| 508 |
CALL MOM_U_METRIC_CYLINDER(bi,bj,k,uFld,vFld,mT,myThid) |
| 509 |
DO j=jMin,jMax |
| 510 |
DO i=iMin,iMax |
| 511 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)+mtFacU*mT(i,j) |
| 512 |
ENDDO |
| 513 |
ENDDO |
| 514 |
ENDIF |
| 515 |
|
| 516 |
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7-|--+----| |
| 517 |
|
| 518 |
C---- Meridional momentum equation starts here |
| 519 |
|
| 520 |
IF (momAdvection) THEN |
| 521 |
C--- Calculate mean fluxes (advection) between cells for meridional flow. |
| 522 |
C Mean flow component of zonal flux -> fZon |
| 523 |
CALL MOM_V_ADV_UV(bi,bj,k,uTrans,vFld,fZon,myThid) |
| 524 |
|
| 525 |
C-- Meridional flux (fMer is at north face of "v" cell) |
| 526 |
C Mean flow component of meridional flux -> fMer |
| 527 |
CALL MOM_V_ADV_VV(bi,bj,k,vTrans,vFld,fMer,myThid) |
| 528 |
|
| 529 |
C-- Vertical flux (fVer is at upper face of "v" cell) |
| 530 |
C Mean flow component of vertical flux (at k+1) -> fVerV |
| 531 |
CALL MOM_V_ADV_WV( |
| 532 |
I bi,bj,k+1,vVel,wVel,rTransV, |
| 533 |
O fVerV(1-OLx,1-OLy,kDown), myThid ) |
| 534 |
|
| 535 |
C-- Tendency is minus divergence of the fluxes + coriolis + pressure term |
| 536 |
DO j=jMin,jMax |
| 537 |
DO i=iMin,iMax |
| 538 |
gV(i,j,k,bi,bj) = |
| 539 |
#ifdef OLD_UV_GEOM |
| 540 |
& -_recip_hFacS(i,j,k,bi,bj)*recip_drF(k)/ |
| 541 |
& ( 0.5 _d 0*(_rA(i,j,bi,bj)+_rA(i,j-1,bi,bj)) ) |
| 542 |
#else |
| 543 |
& -_recip_hFacS(i,j,k,bi,bj)*recip_drF(k) |
| 544 |
& *recip_rAs(i,j,bi,bj) |
| 545 |
#endif |
| 546 |
& *( ( fZon(i+1,j) - fZon(i,j ) )*uDvdxFac |
| 547 |
& +( fMer(i, j) - fMer(i,j-1) )*vDvdyFac |
| 548 |
& +(fVerV(i,j,kDown) - fVerV(i,j,kUp))*rkSign*rVelDvdrFac |
| 549 |
& ) |
| 550 |
ENDDO |
| 551 |
ENDDO |
| 552 |
|
| 553 |
#ifdef ALLOW_DIAGNOSTICS |
| 554 |
IF ( useDiagnostics ) THEN |
| 555 |
CALL DIAGNOSTICS_FILL(fZon,'ADVx_Vm ',k,1,2,bi,bj,myThid) |
| 556 |
CALL DIAGNOSTICS_FILL(fMer,'ADVy_Vm ',k,1,2,bi,bj,myThid) |
| 557 |
CALL DIAGNOSTICS_FILL(fVerV(1-Olx,1-Oly,kUp), |
| 558 |
& 'ADVrE_Vm',k,1,2,bi,bj,myThid) |
| 559 |
ENDIF |
| 560 |
#endif |
| 561 |
|
| 562 |
#ifdef NONLIN_FRSURF |
| 563 |
C-- account for 3.D divergence of the flow in rStar coordinate: |
| 564 |
# ifndef DISABLE_RSTAR_CODE |
| 565 |
IF ( select_rStar.GT.0 ) THEN |
| 566 |
DO j=jMin,jMax |
| 567 |
DO i=iMin,iMax |
| 568 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj) |
| 569 |
& - (rStarExpS(i,j,bi,bj) - 1. _d 0)/deltaTfreesurf |
| 570 |
& *vVel(i,j,k,bi,bj) |
| 571 |
ENDDO |
| 572 |
ENDDO |
| 573 |
ENDIF |
| 574 |
IF ( select_rStar.LT.0 ) THEN |
| 575 |
DO j=jMin,jMax |
| 576 |
DO i=iMin,iMax |
| 577 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj) |
| 578 |
& - rStarDhSDt(i,j,bi,bj)*vVel(i,j,k,bi,bj) |
| 579 |
ENDDO |
| 580 |
ENDDO |
| 581 |
ENDIF |
| 582 |
# endif /* DISABLE_RSTAR_CODE */ |
| 583 |
#endif /* NONLIN_FRSURF */ |
| 584 |
|
| 585 |
ELSE |
| 586 |
C- if momAdvection / else |
| 587 |
DO j=1-OLy,sNy+OLy |
| 588 |
DO i=1-OLx,sNx+OLx |
| 589 |
gV(i,j,k,bi,bj) = 0. _d 0 |
| 590 |
ENDDO |
| 591 |
ENDDO |
| 592 |
|
| 593 |
C- endif momAdvection. |
| 594 |
ENDIF |
| 595 |
|
| 596 |
IF (momViscosity) THEN |
| 597 |
C--- Calculate eddy fluxes (dissipation) between cells for meridional flow. |
| 598 |
C Bi-harmonic term del^2 V -> v4F |
| 599 |
IF (biharmonic) |
| 600 |
& CALL MOM_V_DEL2V(bi,bj,k,vFld,hFacZ,v4f,myThid) |
| 601 |
|
| 602 |
C Laplacian and bi-harmonic terms, Zonal Fluxes -> fZon |
| 603 |
CALL MOM_V_XVISCFLUX(bi,bj,k,vFld,v4f,hFacZ,fZon, |
| 604 |
I viscAh_Z,viscA4_Z,myThid) |
| 605 |
|
| 606 |
C Laplacian and bi-harmonic termis, Merid Fluxes -> fMer |
| 607 |
CALL MOM_V_YVISCFLUX(bi,bj,k,vFld,v4f,fMer, |
| 608 |
I viscAh_D,viscA4_D,myThid) |
| 609 |
|
| 610 |
C Eddy component of vertical flux (interior component only) -> fVrUp & fVrDw |
| 611 |
IF (.NOT.implicitViscosity) THEN |
| 612 |
CALL MOM_V_RVISCFLUX(bi,bj, k, vVel,KappaRV,fVrUp,myThid) |
| 613 |
CALL MOM_V_RVISCFLUX(bi,bj,k+1,vVel,KappaRV,fVrDw,myThid) |
| 614 |
ENDIF |
| 615 |
|
| 616 |
C-- Tendency is minus divergence of the fluxes + coriolis + pressure term |
| 617 |
DO j=jMin,jMax |
| 618 |
DO i=iMin,iMax |
| 619 |
gvDiss(i,j) = |
| 620 |
#ifdef OLD_UV_GEOM |
| 621 |
& -_recip_hFacS(i,j,k,bi,bj)*recip_drF(k)/ |
| 622 |
& ( 0.5 _d 0*(_rA(i,j,bi,bj)+_rA(i,j-1,bi,bj)) ) |
| 623 |
#else |
| 624 |
& -_recip_hFacS(i,j,k,bi,bj)*recip_drF(k) |
| 625 |
& *recip_rAs(i,j,bi,bj) |
| 626 |
#endif |
| 627 |
& *( ( fZon(i+1,j) - fZon(i,j ) )*AhDvdxFac |
| 628 |
& +( fMer(i, j) - fMer(i,j-1) )*AhDvdyFac |
| 629 |
& +( fVrDw(i,j) - fVrUp(i,j) )*rkSign*ArDvdrFac |
| 630 |
& ) |
| 631 |
ENDDO |
| 632 |
ENDDO |
| 633 |
|
| 634 |
#ifdef ALLOW_DIAGNOSTICS |
| 635 |
IF ( useDiagnostics ) THEN |
| 636 |
CALL DIAGNOSTICS_FILL(fZon, 'VISCx_Vm',k,1,2,bi,bj,myThid) |
| 637 |
CALL DIAGNOSTICS_FILL(fMer, 'VISCy_Vm',k,1,2,bi,bj,myThid) |
| 638 |
IF (.NOT.implicitViscosity) |
| 639 |
& CALL DIAGNOSTICS_FILL(fVrUp,'VISrE_Vm',k,1,2,bi,bj,myThid) |
| 640 |
ENDIF |
| 641 |
#endif |
| 642 |
|
| 643 |
C-- No-slip and drag BCs appear as body forces in cell abutting topography |
| 644 |
IF (no_slip_sides) THEN |
| 645 |
C- No-slip BCs impose a drag at walls... |
| 646 |
CALL MOM_V_SIDEDRAG( |
| 647 |
I bi,bj,k, |
| 648 |
I vFld, v4f, hFacZ, |
| 649 |
I viscAh_Z,viscA4_Z, |
| 650 |
I harmonic,biharmonic,useVariableViscosity, |
| 651 |
O vF, |
| 652 |
I myThid) |
| 653 |
DO j=jMin,jMax |
| 654 |
DO i=iMin,iMax |
| 655 |
gvDiss(i,j) = gvDiss(i,j) + vF(i,j) |
| 656 |
ENDDO |
| 657 |
ENDDO |
| 658 |
ENDIF |
| 659 |
C- No-slip BCs impose a drag at bottom |
| 660 |
IF (bottomDragTerms) THEN |
| 661 |
CALL MOM_V_BOTTOMDRAG(bi,bj,k,vFld,KE,KappaRV,vF,myThid) |
| 662 |
DO j=jMin,jMax |
| 663 |
DO i=iMin,iMax |
| 664 |
gvDiss(i,j) = gvDiss(i,j) + vF(i,j) |
| 665 |
ENDDO |
| 666 |
ENDDO |
| 667 |
ENDIF |
| 668 |
|
| 669 |
#ifdef ALLOW_SHELFICE |
| 670 |
IF (useShelfIce) THEN |
| 671 |
CALL SHELFICE_V_DRAG(bi,bj,k,vFld,KE,KappaRU,vF,myThid) |
| 672 |
DO j=jMin,jMax |
| 673 |
DO i=iMin,iMax |
| 674 |
gvDiss(i,j) = gvDiss(i,j) + vF(i,j) |
| 675 |
ENDDO |
| 676 |
ENDDO |
| 677 |
ENDIF |
| 678 |
#endif /* ALLOW_SHELFICE */ |
| 679 |
|
| 680 |
C- endif momViscosity |
| 681 |
ENDIF |
| 682 |
|
| 683 |
C-- Forcing term (moved to timestep.F) |
| 684 |
c IF (momForcing) |
| 685 |
c & CALL EXTERNAL_FORCING_V( |
| 686 |
c I iMin,iMax,jMin,jMax,bi,bj,k, |
| 687 |
c I myTime,myThid) |
| 688 |
|
| 689 |
C-- Metric terms for curvilinear grid systems |
| 690 |
IF (useNHMTerms) THEN |
| 691 |
C o Non-Hydrostatic (spherical) metric terms |
| 692 |
CALL MOM_V_METRIC_NH(bi,bj,k,vFld,wVel,mT,myThid) |
| 693 |
DO j=jMin,jMax |
| 694 |
DO i=iMin,iMax |
| 695 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj)+mtNHFacV*mT(i,j) |
| 696 |
ENDDO |
| 697 |
ENDDO |
| 698 |
ENDIF |
| 699 |
IF ( usingSphericalPolarGrid .AND. metricTerms ) THEN |
| 700 |
C o Spherical polar grid metric terms |
| 701 |
CALL MOM_V_METRIC_SPHERE(bi,bj,k,uFld,mT,myThid) |
| 702 |
DO j=jMin,jMax |
| 703 |
DO i=iMin,iMax |
| 704 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj)+mtFacV*mT(i,j) |
| 705 |
ENDDO |
| 706 |
ENDDO |
| 707 |
ENDIF |
| 708 |
IF ( usingCylindricalGrid .AND. metricTerms ) THEN |
| 709 |
C o Cylindrical grid metric terms |
| 710 |
CALL MOM_V_METRIC_CYLINDER(bi,bj,k,uFld,vFld,mT,myThid) |
| 711 |
DO j=jMin,jMax |
| 712 |
DO i=iMin,iMax |
| 713 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj)+mtFacV*mT(i,j) |
| 714 |
ENDDO |
| 715 |
ENDDO |
| 716 |
ENDIF |
| 717 |
|
| 718 |
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7-|--+----| |
| 719 |
|
| 720 |
C-- Coriolis term |
| 721 |
C Note. As coded here, coriolis will not work with "thin walls" |
| 722 |
c IF (useCDscheme) THEN |
| 723 |
c CALL MOM_CDSCHEME(bi,bj,k,dPhiHydX,dPhiHydY,myThid) |
| 724 |
c ELSE |
| 725 |
IF (.NOT.useCDscheme) THEN |
| 726 |
CALL MOM_U_CORIOLIS(bi,bj,k,vFld,cf,myThid) |
| 727 |
DO j=jMin,jMax |
| 728 |
DO i=iMin,iMax |
| 729 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)+fuFac*cf(i,j) |
| 730 |
ENDDO |
| 731 |
ENDDO |
| 732 |
#ifdef ALLOW_DIAGNOSTICS |
| 733 |
IF ( useDiagnostics ) |
| 734 |
& CALL DIAGNOSTICS_FILL(cf,'Um_Cori ',k,1,2,bi,bj,myThid) |
| 735 |
#endif |
| 736 |
CALL MOM_V_CORIOLIS(bi,bj,k,uFld,cf,myThid) |
| 737 |
DO j=jMin,jMax |
| 738 |
DO i=iMin,iMax |
| 739 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj)+fvFac*cf(i,j) |
| 740 |
ENDDO |
| 741 |
ENDDO |
| 742 |
#ifdef ALLOW_DIAGNOSTICS |
| 743 |
IF ( useDiagnostics ) |
| 744 |
& CALL DIAGNOSTICS_FILL(cf,'Vm_Cori ',k,1,2,bi,bj,myThid) |
| 745 |
#endif |
| 746 |
ENDIF |
| 747 |
|
| 748 |
IF (nonHydrostatic.OR.quasiHydrostatic) THEN |
| 749 |
CALL MOM_U_CORIOLIS_NH(bi,bj,k,wVel,cf,myThid) |
| 750 |
DO j=jMin,jMax |
| 751 |
DO i=iMin,iMax |
| 752 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)+fuFac*cf(i,j) |
| 753 |
ENDDO |
| 754 |
ENDDO |
| 755 |
ENDIF |
| 756 |
|
| 757 |
C-- Set du/dt & dv/dt on boundaries to zero |
| 758 |
DO j=jMin,jMax |
| 759 |
DO i=iMin,iMax |
| 760 |
gU(i,j,k,bi,bj) = gU(i,j,k,bi,bj)*_maskW(i,j,k,bi,bj) |
| 761 |
guDiss(i,j) = guDiss(i,j) *_maskW(i,j,k,bi,bj) |
| 762 |
gV(i,j,k,bi,bj) = gV(i,j,k,bi,bj)*_maskS(i,j,k,bi,bj) |
| 763 |
gvDiss(i,j) = gvDiss(i,j) *_maskS(i,j,k,bi,bj) |
| 764 |
ENDDO |
| 765 |
ENDDO |
| 766 |
|
| 767 |
#ifdef ALLOW_DIAGNOSTICS |
| 768 |
IF ( useDiagnostics ) THEN |
| 769 |
CALL DIAGNOSTICS_FILL(KE, 'momKE ',k,1,2,bi,bj,myThid) |
| 770 |
CALL DIAGNOSTICS_FILL(gU(1-Olx,1-Oly,k,bi,bj), |
| 771 |
& 'Um_Advec',k,1,2,bi,bj,myThid) |
| 772 |
CALL DIAGNOSTICS_FILL(gV(1-Olx,1-Oly,k,bi,bj), |
| 773 |
& 'Vm_Advec',k,1,2,bi,bj,myThid) |
| 774 |
IF (momViscosity) THEN |
| 775 |
CALL DIAGNOSTICS_FILL(guDiss,'Um_Diss ',k,1,2,bi,bj,myThid) |
| 776 |
CALL DIAGNOSTICS_FILL(gvDiss,'Vm_Diss ',k,1,2,bi,bj,myThid) |
| 777 |
ENDIF |
| 778 |
ENDIF |
| 779 |
#endif /* ALLOW_DIAGNOSTICS */ |
| 780 |
|
| 781 |
RETURN |
| 782 |
END |
Parent Directory
| 
Revision Log
| 
Revision Graph