1 |
C $Header: /u/gcmpack/MITgcm/pkg/generic_advdiff/gad_u3_adv_x.F,v 1.5 2008/02/29 01:31:00 mlosch Exp $ |
2 |
C $Name: $ |
3 |
|
4 |
#include "GAD_OPTIONS.h" |
5 |
|
6 |
CBOP |
7 |
C !ROUTINE: GAD_U3_ADV_X |
8 |
|
9 |
C !INTERFACE: ========================================================== |
10 |
SUBROUTINE GAD_U3_ADV_X( |
11 |
I bi,bj,k, |
12 |
I uTrans, maskLocW, |
13 |
I tracer, |
14 |
O uT, |
15 |
I myThid ) |
16 |
|
17 |
C !DESCRIPTION: |
18 |
C Calculates the area integrated zonal flux due to advection of a tracer |
19 |
C using upwind biased third-order interpolation (or the $\kappa=1/3$ scheme): |
20 |
C \begin{equation*} |
21 |
C F^x_{adv} = U \overline{ \theta - \frac{1}{6} \delta_{ii} \theta }^i |
22 |
C + \frac{1}{12} |U| \delta_{iii} \theta |
23 |
C \end{equation*} |
24 |
C Near boundaries, mask all the gradients ==> still 3rd O. |
25 |
|
26 |
C !USES: =============================================================== |
27 |
IMPLICIT NONE |
28 |
#include "SIZE.h" |
29 |
c#include "GRID.h" |
30 |
#include "GAD.h" |
31 |
|
32 |
C !INPUT PARAMETERS: =================================================== |
33 |
C bi,bj :: tile indices |
34 |
C k :: vertical level |
35 |
C uTrans :: zonal volume transport |
36 |
C maskLocW :: mask (either 0 or 1) at grid-cell western edge |
37 |
C tracer :: tracer field |
38 |
C myThid :: my thread Id number |
39 |
INTEGER bi,bj,k |
40 |
_RL uTrans (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
41 |
_RS maskLocW(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
42 |
_RL tracer (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
43 |
INTEGER myThid |
44 |
|
45 |
C !OUTPUT PARAMETERS: ================================================== |
46 |
C uT :: zonal advective flux |
47 |
_RL uT (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
48 |
|
49 |
C !LOCAL VARIABLES: ==================================================== |
50 |
C i,j :: loop indices |
51 |
C Rjm,Rj,Rjp :: differences at i-1,i,i+1 |
52 |
C Rjjm,Rjjp :: second differences at i-1,i |
53 |
INTEGER i,j |
54 |
_RL Rjm,Rj,Rjp,Rjjm,Rjjp |
55 |
CEOP |
56 |
|
57 |
DO j=1-Oly,sNy+Oly |
58 |
uT(1-Olx,j)=0. |
59 |
uT(2-Olx,j)=0. |
60 |
uT(sNx+Olx,j)=0. |
61 |
ENDDO |
62 |
DO j=1-Oly,sNy+Oly |
63 |
DO i=1-Olx+2,sNx+Olx-1 |
64 |
Rjp = (tracer(i+1,j)-tracer( i ,j))*maskLocW(i+1,j) |
65 |
Rj = (tracer( i ,j)-tracer(i-1,j))*maskLocW( i ,j) |
66 |
Rjm = (tracer(i-1,j)-tracer(i-2,j))*maskLocW(i-1,j) |
67 |
Rjjp=Rjp-Rj |
68 |
Rjjm=Rj-Rjm |
69 |
uT(i,j) = |
70 |
& uTrans(i,j)*( |
71 |
& Tracer(i,j)+Tracer(i-1,j)-oneSixth*( Rjjp+Rjjm ) |
72 |
& )*0.5 _d 0 |
73 |
& +ABS( uTrans(i,j) )*0.5 _d 0*oneSixth*( Rjjp-Rjjm ) |
74 |
ENDDO |
75 |
ENDDO |
76 |
|
77 |
RETURN |
78 |
END |