1 |
C $Header: /u/gcmpack/MITgcm/pkg/generic_advdiff/gad_som_adv_y.F,v 1.2 2007/08/22 00:26:01 jmc Exp $ |
2 |
C $Name: $ |
3 |
|
4 |
#include "GAD_OPTIONS.h" |
5 |
|
6 |
CBOP |
7 |
C !ROUTINE: GAD_SOM_ADV_Y |
8 |
|
9 |
C !INTERFACE: ========================================================== |
10 |
SUBROUTINE GAD_SOM_ADV_Y( |
11 |
I bi,bj,k, limiter, |
12 |
I deltaTloc, vTrans, |
13 |
U sm_v, sm_o, sm_x, sm_y, sm_z, |
14 |
U sm_xx, sm_yy, sm_zz, sm_xy, sm_xz, sm_yz, |
15 |
O vT, |
16 |
I myThid ) |
17 |
|
18 |
C !DESCRIPTION: |
19 |
C Calculates the area integrated meridional flux due to advection |
20 |
C of a tracer using |
21 |
C-- |
22 |
C Second-Order Moments Advection of tracer in Y-direction |
23 |
C ref: M.J.Prather, 1986, JGR, 91, D6, pp 6671-6681. |
24 |
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7-|--+----| |
25 |
C The 3-D grid has dimension (Nx,Ny,Nz) with corresponding |
26 |
C velocity field (U,V,W). Parallel subroutine calculate |
27 |
C advection in the X- and Z- directions. |
28 |
C The moment [Si] are as defined in the text, Sm refers to |
29 |
C the total mass in each grid box |
30 |
C the moments [Fi] are similarly defined and used as temporary |
31 |
C storage for portions of the grid boxes in transit. |
32 |
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7-|--+----| |
33 |
|
34 |
C !USES: =============================================================== |
35 |
IMPLICIT NONE |
36 |
#include "SIZE.h" |
37 |
c #include "GRID.h" |
38 |
#include "GAD.h" |
39 |
|
40 |
C !INPUT PARAMETERS: =================================================== |
41 |
C bi,bj :: tile indices |
42 |
C k :: vertical level |
43 |
C limiter :: 0: no limiter ; 1: Prather, 1986 limiter |
44 |
C vTrans :: zonal volume transport |
45 |
C myThid :: my Thread Id. number |
46 |
INTEGER bi,bj,k |
47 |
INTEGER limiter |
48 |
_RL deltaTloc |
49 |
_RL vTrans(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
50 |
c _RL tracer(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
51 |
INTEGER myThid |
52 |
|
53 |
C !OUTPUT PARAMETERS: ================================================== |
54 |
C sm_v :: volume of grid cell |
55 |
C sm_o :: tracer content of grid cell (zero order moment) |
56 |
C sm_x,y,z :: 1rst order moment of tracer distribution, in x,y,z direction |
57 |
C sm_xx,yy,zz :: 2nd order moment of tracer distribution, in x,y,z direction |
58 |
C sm_xy,xz,yz :: 2nd order moment of tracer distr., in cross direction xy,xz,yz |
59 |
C vT :: meridional advective flux |
60 |
_RL sm_v (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
61 |
_RL sm_o (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
62 |
_RL sm_x (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
63 |
_RL sm_y (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
64 |
_RL sm_z (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
65 |
_RL sm_xx (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
66 |
_RL sm_yy (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
67 |
_RL sm_zz (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
68 |
_RL sm_xy (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
69 |
_RL sm_xz (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
70 |
_RL sm_yz (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
71 |
_RL vT (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
72 |
|
73 |
#ifdef GAD_ALLOW_SOM_ADVECT |
74 |
C !LOCAL VARIABLES: ==================================================== |
75 |
C i,j :: loop indices |
76 |
C vLoc :: volume transported (per time step) |
77 |
_RL two, three |
78 |
PARAMETER( two = 2. _d 0 ) |
79 |
PARAMETER( three = 3. _d 0 ) |
80 |
INTEGER i,j |
81 |
_RL recip_dT |
82 |
_RL slpmax, s1max, s1new, s2new |
83 |
_RL vLoc, alf1, alf1q, alpmn |
84 |
_RL alfp, alpq, alp1, locTp |
85 |
_RL alfn, alnq, aln1, locTn |
86 |
_RL alp (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
87 |
_RL aln (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
88 |
_RL fp_v (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
89 |
_RL fn_v (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
90 |
_RL fp_o (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
91 |
_RL fn_o (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
92 |
_RL fp_x (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
93 |
_RL fn_x (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
94 |
_RL fp_y (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
95 |
_RL fn_y (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
96 |
_RL fp_z (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
97 |
_RL fn_z (1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
98 |
_RL fp_xx(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
99 |
_RL fn_xx(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
100 |
_RL fp_yy(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
101 |
_RL fn_yy(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
102 |
_RL fp_zz(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
103 |
_RL fn_zz(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
104 |
_RL fp_xy(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
105 |
_RL fn_xy(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
106 |
_RL fp_xz(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
107 |
_RL fn_xz(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
108 |
_RL fp_yz(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
109 |
_RL fn_yz(1-OLx:sNx+OLx,1-OLy:sNy+OLy) |
110 |
CEOP |
111 |
|
112 |
recip_dT = 0. |
113 |
IF ( deltaTloc.GT.0. _d 0 ) recip_dT = 1.0 _d 0 / deltaTloc |
114 |
|
115 |
IF ( limiter.EQ.1 ) THEN |
116 |
DO j=1-OLy,sNy+OLy |
117 |
DO i=1-OLx,sNx+OLx |
118 |
C If flux-limiting transport is to be applied, place limits on |
119 |
C appropriate moments before transport. |
120 |
slpmax = 0. |
121 |
IF ( sm_o(i,j).GT.0. ) slpmax = sm_o(i,j) |
122 |
s1max = slpmax*1.5 _d 0 |
123 |
s1new = MIN( s1max, MAX(-s1max,sm_y(i,j)) ) |
124 |
s2new = MIN( (slpmax+slpmax-ABS(s1new)/three), |
125 |
& MAX(ABS(s1new)-slpmax,sm_yy(i,j)) ) |
126 |
sm_xy(i,j) = MIN( slpmax, MAX(-slpmax,sm_xy(i,j)) ) |
127 |
sm_yz(i,j) = MIN( slpmax, MAX(-slpmax,sm_yz(i,j)) ) |
128 |
sm_y (i,j) = s1new |
129 |
sm_yy(i,j) = s2new |
130 |
ENDDO |
131 |
ENDDO |
132 |
ENDIF |
133 |
|
134 |
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7-|--+----| |
135 |
C--- part.1 : calculate flux for all moments |
136 |
DO i=1-OLx,sNx+OLx |
137 |
vT(i,1-OLy)=0. |
138 |
ENDDO |
139 |
DO j=1-OLy+1,sNy+OLy |
140 |
DO i=1-OLx,sNx+OLx |
141 |
vLoc = vTrans(i,j)*deltaTloc |
142 |
C-- Flux from (j-1) to (j) when V>0 (i.e., take right side of box j-1) |
143 |
fp_v (i,j) = MAX( 0. _d 0, vLoc ) |
144 |
alp (i,j) = fp_v(i,j)/sm_v(i,j-1) |
145 |
alpq = alp(i,j)*alp(i,j) |
146 |
alp1 = 1. _d 0 - alp(i,j) |
147 |
C- Create temporary moments/masses for partial boxes in transit |
148 |
C use same indexing as velocity, "p" for positive V |
149 |
fp_o (i,j) = alp(i,j)*( sm_o(i,j-1) + alp1*sm_y(i,j-1) |
150 |
& + alp1*(alp1-alp(i,j))*sm_yy(i,j-1) |
151 |
& ) |
152 |
fp_y (i,j) = alpq *( sm_y(i,j-1) + three*alp1*sm_yy(i,j-1) ) |
153 |
fp_yy(i,j) = alp(i,j)*alpq*sm_yy(i,j-1) |
154 |
fp_x (i,j) = alp(i,j)*( sm_x(i,j-1) + alp1*sm_xy(i,j-1) ) |
155 |
fp_z (i,j) = alp(i,j)*( sm_z(i,j-1) + alp1*sm_yz(i,j-1) ) |
156 |
|
157 |
fp_xy(i,j) = alpq *sm_xy(i,j-1) |
158 |
fp_yz(i,j) = alpq *sm_yz(i,j-1) |
159 |
fp_xx(i,j) = alp(i,j)*sm_xx(i,j-1) |
160 |
fp_zz(i,j) = alp(i,j)*sm_zz(i,j-1) |
161 |
fp_xz(i,j) = alp(i,j)*sm_xz(i,j-1) |
162 |
C-- Flux from (j) to (j-1) when V<0 (i.e., take left side of box j) |
163 |
fn_v (i,j) = MAX( 0. _d 0, -vLoc ) |
164 |
aln (i,j) = fn_v(i,j)/sm_v(i, j ) |
165 |
alnq = aln(i,j)*aln(i,j) |
166 |
aln1 = 1. _d 0 - aln(i,j) |
167 |
C- Create temporary moments/masses for partial boxes in transit |
168 |
C use same indexing as velocity, "n" for negative V |
169 |
fn_o (i,j) = aln(i,j)*( sm_o(i, j ) - aln1*sm_y(i, j ) |
170 |
& + aln1*(aln1-aln(i,j))*sm_yy(i, j ) |
171 |
& ) |
172 |
fn_y (i,j) = alnq *( sm_y(i, j ) - three*aln1*sm_yy(i, j ) ) |
173 |
fn_yy(i,j) = aln(i,j)*alnq*sm_yy(i, j ) |
174 |
fn_x (i,j) = aln(i,j)*( sm_x(i, j ) - aln1*sm_xy(i, j ) ) |
175 |
fn_z (i,j) = aln(i,j)*( sm_z(i, j ) - aln1*sm_yz(i, j ) ) |
176 |
fn_xy(i,j) = alnq *sm_xy(i, j ) |
177 |
fn_yz(i,j) = alnq *sm_yz(i, j ) |
178 |
fn_xx(i,j) = aln(i,j)*sm_xx(i, j ) |
179 |
fn_zz(i,j) = aln(i,j)*sm_zz(i, j ) |
180 |
fn_xz(i,j) = aln(i,j)*sm_xz(i, j ) |
181 |
C-- Save zero-order flux: |
182 |
vT(i,j) = ( fp_o(i,j) - fn_o(i,j) )*recip_dT |
183 |
ENDDO |
184 |
ENDDO |
185 |
|
186 |
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7-|--+----| |
187 |
C--- part.2 : re-adjust moments remaining in the box |
188 |
C take off from grid box (j): negative V(j) and positive V(j+1) |
189 |
DO j=1-OLy+1,sNy+OLy-1 |
190 |
DO i=1-OLx,sNx+OLx |
191 |
alf1 = 1. _d 0 - aln(i,j) - alp(i,j+1) |
192 |
alf1q = alf1*alf1 |
193 |
alpmn = alp(i,j+1) - aln(i,j) |
194 |
sm_v (i,j) = sm_v (i,j) - fn_v (i,j) - fp_v (i,j+1) |
195 |
sm_o (i,j) = sm_o (i,j) - fn_o (i,j) - fp_o (i,j+1) |
196 |
sm_y (i,j) = alf1q*( sm_y(i,j) - three*alpmn*sm_yy(i,j) ) |
197 |
sm_yy(i,j) = alf1*alf1q*sm_yy(i,j) |
198 |
sm_xy(i,j) = alf1q*sm_xy(i,j) |
199 |
sm_yz(i,j) = alf1q*sm_yz(i,j) |
200 |
sm_x (i,j) = sm_x (i,j) - fn_x (i,j) - fp_x (i,j+1) |
201 |
sm_xx(i,j) = sm_xx(i,j) - fn_xx(i,j) - fp_xx(i,j+1) |
202 |
sm_z (i,j) = sm_z (i,j) - fn_z (i,j) - fp_z (i,j+1) |
203 |
sm_zz(i,j) = sm_zz(i,j) - fn_zz(i,j) - fp_zz(i,j+1) |
204 |
sm_xz(i,j) = sm_xz(i,j) - fn_xz(i,j) - fp_xz(i,j+1) |
205 |
ENDDO |
206 |
ENDDO |
207 |
|
208 |
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7-|--+----| |
209 |
C--- part.3 : Put the temporary moments into appropriate neighboring boxes |
210 |
C add into grid box (j): positive V(j) and negative V(j+1) |
211 |
DO j=1-OLy+1,sNy+OLy-1 |
212 |
DO i=1-OLx,sNx+OLx |
213 |
sm_v (i,j) = sm_v (i,j) + fp_v (i,j) + fn_v (i,j+1) |
214 |
alfp = fp_v(i, j )/sm_v(i,j) |
215 |
alfn = fn_v(i,j+1)/sm_v(i,j) |
216 |
alf1 = 1. _d 0 - alfp - alfn |
217 |
alp1 = 1. _d 0 - alfp |
218 |
aln1 = 1. _d 0 - alfn |
219 |
alpmn = alfp - alfn |
220 |
locTp = alfp*sm_o(i,j) - alp1*fp_o(i,j) |
221 |
locTn = alfn*sm_o(i,j) - aln1*fn_o(i,j+1) |
222 |
sm_yy(i,j) = alf1*alf1*sm_yy(i,j) + alfp*alfp*fp_yy(i,j) |
223 |
& + alfn*alfn*fn_yy(i,j+1) |
224 |
& - 5. _d 0*(-alpmn*alf1*sm_y(i,j) + alfp*alp1*fp_y(i,j) |
225 |
& - alfn*aln1*fn_y(i,j+1) |
226 |
& + two*alfp*alfn*sm_o(i,j) + (alp1-alfp)*locTp |
227 |
& + (aln1-alfn)*locTn |
228 |
& ) |
229 |
sm_xy(i,j) = alf1*sm_xy(i,j) + alfp*fp_xy(i,j) |
230 |
& + alfn*fn_xy(i,j+1) |
231 |
& + three*( alpmn*sm_x(i,j) - alp1*fp_x(i,j) |
232 |
& + aln1*fn_x(i,j+1) |
233 |
& ) |
234 |
sm_yz(i,j) = alf1*sm_yz(i,j) + alfp*fp_yz(i,j) |
235 |
& + alfn*fn_yz(i,j+1) |
236 |
& + three*( alpmn*sm_z(i,j) - alp1*fp_z(i,j) |
237 |
& + aln1*fn_z(i,j+1) |
238 |
& ) |
239 |
sm_y (i,j) = alf1*sm_y(i,j) + alfp*fp_y(i,j) + alfn*fn_y(i,j+1) |
240 |
& + three*( locTp - locTn ) |
241 |
sm_o (i,j) = sm_o (i,j) + fp_o (i,j) + fn_o (i,j+1) |
242 |
sm_x (i,j) = sm_x (i,j) + fp_x (i,j) + fn_x (i,j+1) |
243 |
sm_xx(i,j) = sm_xx(i,j) + fp_xx(i,j) + fn_xx(i,j+1) |
244 |
sm_z (i,j) = sm_z (i,j) + fp_z (i,j) + fn_z (i,j+1) |
245 |
sm_zz(i,j) = sm_zz(i,j) + fp_zz(i,j) + fn_zz(i,j+1) |
246 |
sm_xz(i,j) = sm_xz(i,j) + fp_xz(i,j) + fn_xz(i,j+1) |
247 |
ENDDO |
248 |
ENDDO |
249 |
|
250 |
#endif /* GAD_ALLOW_SOM_ADVECT */ |
251 |
|
252 |
RETURN |
253 |
END |