pkg/generic_advdiff/gad_c4_adv_y.F

C $Header: /u/gcmpack/models/MITgcmUV/pkg/generic_advdiff/gad_c4_adv_y.F,v 1.3 2001/08/20 20:45:15 jmc Exp $
C $Name:  $

#include "GAD_OPTIONS.h"

CBOP
C !ROUTINE: GAD_C4_ADV_Y

C !INTERFACE: ==========================================================
      SUBROUTINE GAD_C4_ADV_Y( 
     I           bi,bj,k,
     I           vTrans,
     I           tracer,
     O           vT,
     I           myThid )

C !DESCRIPTION:
C Calculates the area integrated meridional flux due to advection of a tracer
C using centered fourth-order interpolation:
C \begin{equation*}
C F^y_{adv} = V \overline{ \theta - \frac{1}{6} \delta_{jj} \theta }^j
C \end{equation*}
C Near boundaries, the scheme reduces to a second if the flow is away
C from the boundary and to third order if the flow is towards
C the boundary.

C !USES: ===============================================================
      IMPLICIT NONE
#include "SIZE.h"
#include "GRID.h"
#include "GAD.h"

C !INPUT PARAMETERS: ===================================================
C  bi,bj                :: tile indices
C  k                    :: vertical level
C  vTrans               :: meridional volume transport
C  tracer               :: tracer field
C  myThid               :: thread number
      INTEGER bi,bj,k
      _RL vTrans(1-OLx:sNx+OLx,1-OLy:sNy+OLy)
      _RL tracer(1-OLx:sNx+OLx,1-OLy:sNy+OLy)
      INTEGER myThid

C !OUTPUT PARAMETERS: ==================================================
C  uT                   :: zonal advective flux
      _RL vT    (1-OLx:sNx+OLx,1-OLy:sNy+OLy)

C !LOCAL VARIABLES: ====================================================
C  i,j                  :: loop indices
C  Rjm,Rj,Rjp           :: differences at j-1,j,j+1
C  Rjjm,Rjjp            :: second differences at j-1,j
      INTEGER i,j
      _RL Rjm,Rj,Rjp,Rjjm,Rjjp
CEOP

      DO i=1-Olx,sNx+Olx
       vT(i,1-Oly)=0.
       vT(i,2-Oly)=0.
       vT(i,sNy+Oly)=0.
      ENDDO
      DO j=1-Oly+2,sNy+Oly-1
       DO i=1-Olx,sNx+Olx
        Rjp=(tracer(i,j+1)-tracer(i,j))
c    &     *maskS(i,j+1,k,bi,bj)
        Rj =(tracer(i,j)-tracer(i,j-1))
c    &     *maskS(i,j,k,bi,bj)
        Rjm=(tracer(i,j-1)-tracer(i,j-2))
c    &     *maskS(i,j-1,k,bi,bj)
C- jmc: mask not needed here above if Rjjp & Rjjm & vTrans are masked
        Rjjp=(Rjp-Rj)*maskS(i,j+1,k,bi,bj)
        Rjjm=(Rj-Rjm)*maskS(i,j-1,k,bi,bj)
        vT(i,j) =
     &   vTrans(i,j)*(
     &     Tracer(i,j)+Tracer(i,j-1)-oneSixth*( Rjjp+Rjjm )
     &               )*0.5 _d 0
     &  +ABS( vTrans(i,j) )*0.5 _d 0*oneSixth*( Rjjp-Rjjm )
     &    *( 1. _d 0 - maskS(i,j-1,k,bi,bj)*maskS(i,j+1,k,bi,bj) )
       ENDDO
      ENDDO

      RETURN
      END
1	C $Header: /u/gcmpack/models/MITgcmUV/pkg/generic_advdiff/gad_c4_adv_y.F,v 1.3 2001/08/20 20:45:15 jmc Exp $
2	C $Name: $
3
4	#include "GAD_OPTIONS.h"
5
6	CBOP
7	C !ROUTINE: GAD_C4_ADV_Y
8
9	C !INTERFACE: ==========================================================
10	SUBROUTINE GAD_C4_ADV_Y(
11	I bi,bj,k,
12	I vTrans,
13	I tracer,
14	O vT,
15	I myThid )
16
17	C !DESCRIPTION:
18	C Calculates the area integrated meridional flux due to advection of a tracer
19	C using centered fourth-order interpolation:
20	C \begin{equation*}
21	C F^y_{adv} = V \overline{ \theta - \frac{1}{6} \delta_{jj} \theta }^j
22	C \end{equation*}
23	C Near boundaries, the scheme reduces to a second if the flow is away
24	C from the boundary and to third order if the flow is towards
25	C the boundary.
26
27	C !USES: ===============================================================
28	IMPLICIT NONE
29	#include "SIZE.h"
30	#include "GRID.h"
31	#include "GAD.h"
32
33	C !INPUT PARAMETERS: ===================================================
34	C bi,bj :: tile indices
35	C k :: vertical level
36	C vTrans :: meridional volume transport
37	C tracer :: tracer field
38	C myThid :: thread number
39	INTEGER bi,bj,k
40	_RL vTrans(1-OLx:sNx+OLx,1-OLy:sNy+OLy)
41	_RL tracer(1-OLx:sNx+OLx,1-OLy:sNy+OLy)
42	INTEGER myThid
43
44	C !OUTPUT PARAMETERS: ==================================================
45	C uT :: zonal advective flux
46	_RL vT (1-OLx:sNx+OLx,1-OLy:sNy+OLy)
47
48	C !LOCAL VARIABLES: ====================================================
49	C i,j :: loop indices
50	C Rjm,Rj,Rjp :: differences at j-1,j,j+1
51	C Rjjm,Rjjp :: second differences at j-1,j
52	INTEGER i,j
53	_RL Rjm,Rj,Rjp,Rjjm,Rjjp
54	CEOP
55
56	DO i=1-Olx,sNx+Olx
57	vT(i,1-Oly)=0.
58	vT(i,2-Oly)=0.
59	vT(i,sNy+Oly)=0.
60	ENDDO
61	DO j=1-Oly+2,sNy+Oly-1
62	DO i=1-Olx,sNx+Olx
63	Rjp=(tracer(i,j+1)-tracer(i,j))
64	c & *maskS(i,j+1,k,bi,bj)
65	Rj =(tracer(i,j)-tracer(i,j-1))
66	c & *maskS(i,j,k,bi,bj)
67	Rjm=(tracer(i,j-1)-tracer(i,j-2))
68	c & *maskS(i,j-1,k,bi,bj)
69	C- jmc: mask not needed here above if Rjjp & Rjjm & vTrans are masked
70	Rjjp=(Rjp-Rj)*maskS(i,j+1,k,bi,bj)
71	Rjjm=(Rj-Rjm)*maskS(i,j-1,k,bi,bj)
72	vT(i,j) =
73	& vTrans(i,j)*(
74	& Tracer(i,j)+Tracer(i,j-1)-oneSixth*( Rjjp+Rjjm )
75	& )*0.5 _d 0
76	& +ABS( vTrans(i,j) )0.5 _d 0oneSixth*( Rjjp-Rjjm )
77	& ( 1. _d 0 - maskS(i,j-1,k,bi,bj)maskS(i,j+1,k,bi,bj) )
78	ENDDO
79	ENDDO
80
81	RETURN
82	END