pkg/generic_advdiff/gad_c4_adv_r.F

C $Header: /u/gcmpack/MITgcm/pkg/generic_advdiff/gad_c4_adv_r.F,v 1.5 2003/05/01 16:12:36 jmc Exp $
C $Name:  $

#include "GAD_OPTIONS.h"

CBOP
C !ROUTINE: GAD_C4_ADV_R

C !INTERFACE: ==========================================================
      SUBROUTINE GAD_C4_ADV_R(
     I           bi, bj, k,
     I           rTrans,
     I           tracer,
     O           wT,
     I           myThid )

C !DESCRIPTION:
C Calculates the area integrated vertical flux due to advection of a tracer
C using centered fourth-order interpolation:
C \begin{equation*}
C F^r_{adv} = W \overline{ \theta - \frac{1}{6} \delta_{kk} \theta }^k
C \end{equation*}
C Near boundaries, the scheme reduces to a second if the flow is away
C from the boundary and to third order if the flow is towards
C the boundary.

C !USES: ===============================================================
      IMPLICIT NONE
#include "SIZE.h"
#include "GRID.h"
#include "GAD.h"

C !INPUT PARAMETERS: ===================================================
C  bi,bj                :: tile indices
C  k                    :: vertical level
C  rTrans               :: vertical volume transport
C  tracer               :: tracer field
C  myThid               :: thread number
      INTEGER bi,bj,k
      _RL rTrans(1-OLx:sNx+OLx,1-OLy:sNy+OLy)
      _RL tracer(1-OLx:sNx+OLx,1-OLy:sNy+OLy,Nr)
      INTEGER myThid

C !OUTPUT PARAMETERS: ==================================================
C  wT                   :: vertical advective flux
      _RL wT    (1-OLx:sNx+OLx,1-OLy:sNy+OLy)

C !LOCAL VARIABLES: ====================================================
C  i,j                  :: loop indices
C  kp1                  :: =min( k+1 , Nr )
C  km1                  :: =max( k-1 , 1 )
C  km2                  :: =max( k-2 , 1 )
C  Rjm,Rj,Rjp           :: differences at i-1,i,i+1
C  Rjjm,Rjjp            :: second differences at i-1,i
C  maskP1               :: =1 for k<Nr, =0 for k>=Nr
      INTEGER i,j,kp1,km1,km2
      _RL Rjm,Rj,Rjp,Rjjm,Rjjp
      _RL maskPM, maskBound
CEOP

      km2=MAX(1,k-2)
      km1=MAX(1,k-1)
      kp1=MIN(Nr,k+1)
      maskPM = 1.
      IF (k.LE.2 .OR. k.GE.Nr) maskPM = 0.

      IF ( k.EQ.1 .OR. k.GT.Nr) THEN
       DO j=1-OLy,sNy+OLy
        DO i=1-OLx,sNx+OLx
         wT(i,j) = 0.
        ENDDO
       ENDDO
      ELSE
       DO j=1-OLy,sNy+OLy
        DO i=1-OLx,sNx+OLx
         maskBound = maskPM*maskC(i,j,km2,bi,bj)*maskC(i,j,kp1,bi,bj)
         Rjp = (tracer(i,j,kp1)-tracer(i,j, k ))*maskC(i,j,kp1,bi,bj)
         Rj  = (tracer(i,j, k )-tracer(i,j,km1))
         Rjm = (tracer(i,j,km1)-tracer(i,j,km2))*maskC(i,j,km1,bi,bj)
     &
         Rjjp=(Rjp-Rj)
         Rjjm=(Rj-Rjm)
         wT(i,j) = maskC(i,j,km1,bi,bj)*(
     &     rTrans(i,j)*( (tracer(i,j,k)+tracer(i,j,km1))*0.5 _d 0
     &                  -oneSixth*(Rjjm+Rjjp)*0.5 _d 0 )
     &    +ABS(rTrans(i,j))*
     &                   oneSixth*(Rjjm-Rjjp)*0.5 _d 0
     &                     *(1. _d 0 - maskBound)
     &                                  )
        ENDDO
       ENDDO
      ENDIF

      RETURN
      END
1	C $Header: /u/gcmpack/MITgcm/pkg/generic_advdiff/gad_c4_adv_r.F,v 1.5 2003/05/01 16:12:36 jmc Exp $
2	C $Name: $
3
4	#include "GAD_OPTIONS.h"
5
6	CBOP
7	C !ROUTINE: GAD_C4_ADV_R
8
9	C !INTERFACE: ==========================================================
10	SUBROUTINE GAD_C4_ADV_R(
11	I bi, bj, k,
12	I rTrans,
13	I tracer,
14	O wT,
15	I myThid )
16
17	C !DESCRIPTION:
18	C Calculates the area integrated vertical flux due to advection of a tracer
19	C using centered fourth-order interpolation:
20	C \begin{equation*}
21	C F^r_{adv} = W \overline{ \theta - \frac{1}{6} \delta_{kk} \theta }^k
22	C \end{equation*}
23	C Near boundaries, the scheme reduces to a second if the flow is away
24	C from the boundary and to third order if the flow is towards
25	C the boundary.
26
27	C !USES: ===============================================================
28	IMPLICIT NONE
29	#include "SIZE.h"
30	#include "GRID.h"
31	#include "GAD.h"
32
33	C !INPUT PARAMETERS: ===================================================
34	C bi,bj :: tile indices
35	C k :: vertical level
36	C rTrans :: vertical volume transport
37	C tracer :: tracer field
38	C myThid :: thread number
39	INTEGER bi,bj,k
40	_RL rTrans(1-OLx:sNx+OLx,1-OLy:sNy+OLy)
41	_RL tracer(1-OLx:sNx+OLx,1-OLy:sNy+OLy,Nr)
42	INTEGER myThid
43
44	C !OUTPUT PARAMETERS: ==================================================
45	C wT :: vertical advective flux
46	_RL wT (1-OLx:sNx+OLx,1-OLy:sNy+OLy)
47
48	C !LOCAL VARIABLES: ====================================================
49	C i,j :: loop indices
50	C kp1 :: =min( k+1 , Nr )
51	C km1 :: =max( k-1 , 1 )
52	C km2 :: =max( k-2 , 1 )
53	C Rjm,Rj,Rjp :: differences at i-1,i,i+1
54	C Rjjm,Rjjp :: second differences at i-1,i
55	C maskP1 :: =1 for k<Nr, =0 for k>=Nr
56	INTEGER i,j,kp1,km1,km2
57	_RL Rjm,Rj,Rjp,Rjjm,Rjjp
58	_RL maskPM, maskBound
59	CEOP
60
61	km2=MAX(1,k-2)
62	km1=MAX(1,k-1)
63	kp1=MIN(Nr,k+1)
64	maskPM = 1.
65	IF (k.LE.2 .OR. k.GE.Nr) maskPM = 0.
66
67	IF ( k.EQ.1 .OR. k.GT.Nr) THEN
68	DO j=1-OLy,sNy+OLy
69	DO i=1-OLx,sNx+OLx
70	wT(i,j) = 0.
71	ENDDO
72	ENDDO
73	ELSE
74	DO j=1-OLy,sNy+OLy
75	DO i=1-OLx,sNx+OLx
76	maskBound = maskPMmaskC(i,j,km2,bi,bj)maskC(i,j,kp1,bi,bj)
77	Rjp = (tracer(i,j,kp1)-tracer(i,j, k ))*maskC(i,j,kp1,bi,bj)
78	Rj = (tracer(i,j, k )-tracer(i,j,km1))
79	Rjm = (tracer(i,j,km1)-tracer(i,j,km2))*maskC(i,j,km1,bi,bj)
80	&
81	Rjjp=(Rjp-Rj)
82	Rjjm=(Rj-Rjm)
83	wT(i,j) = maskC(i,j,km1,bi,bj)*(
84	& rTrans(i,j)( (tracer(i,j,k)+tracer(i,j,km1))0.5 _d 0
85	& -oneSixth(Rjjm+Rjjp)0.5 _d 0 )
86	& +ABS(rTrans(i,j))*
87	& oneSixth(Rjjm-Rjjp)0.5 _d 0
88	& *(1. _d 0 - maskBound)
89	& )
90	ENDDO
91	ENDDO
92	ENDIF
93
94	RETURN
95	END